image of READY prompt

Wang2200.org

Listing of file='XMAS' on disk='vmedia/2282_graphics_crt_demos.wvd.zip'

# Sector 234, program filename = 'XMAS'
0001 REM %HOLIDAY GREETING PROGRAM - 12/20/78 - by R.L. Droz
0002 COM P$3
0003 DIM S1$64,L(7,2)
0005 PRINT HEX(0D03),,"CHIRSTMAS GREETING PROGRAM."
   : PRINT
0006 LINPUT "GRAPHICS CRT IS AT WHICH ADDRESS?" -P$
0007 MAT SEARCH "13151604", = STR(P$,2,2) TO L$
   : IF STR(L$,,2)=HEX(0000) THEN 5
0008 SELECT PLOT  <P$>
0015 SELECT D
0043 PLOT  <,,HEX(0603E5)>
   : ERRORGOTO 5
0045 GOSUB '60(1000,"MERRY CHRISTMAS")
0050 GOSUB '60(Y9,"from the 2200 Group")
0062 SELECT P9
   : PRINT "2200 Christmas Greeting program running ..."
0063 PRINT "To stop program, $RELEASE TERMINAL TO";#PART
   : PRINT
   : PRINT
   : PRINT
0064 SELECT P
   : $RELEASE TERMINAL
   : $PSTAT="GREETING"
0065 REM % DRAW TREE
   : M=3
0066 PLOT  <,,R>,<400,0,U>,<0,10*M,D>,<-20*M,0,D>,<25*M,50*M,D>,<25*M,-50*M,D>
     ,<-20*M,0,D>,<0,-10*M,D>
0067 REM % BLINK LIGHTS
0068 RESTORE
   : FOR I=1 TO 7
   : READ L
   : L(I,1)=M*L+400
   : READ L
   : L(I,2)=M*L
   : NEXT I
0069 DATA 5,10,  -20,10,  -10,30,  20,30,  5,30,  30,10, 5,60
0070 PLOT  <1,,C>,<10,,S>
0080 L=MOD(7*RND(1),7)
   : PLOT  <,,R>,<L(L+1,1),L(L+1,2),"*">
0085 IF RND(1)>.5 THEN PLOT  <,,HEX(E1)>
   : ELSE PLOT  <,,HEX(E2)>
0090 FOR I=1 TO 10
   : $BREAK 255
   : NEXT I
   : GOTO 80
0099 REM % CENTER WORDS
0100 DEFFN'60(Y9,S1$)
   : C=MIN(INT(80/LEN(S1$)),4)
   : S=MAX(10*C,800/LEN(S1$))
0110 $TRAN (S1$, " ]  ") R
   : PLOT  <,,R>,<C,,C>,<S,,S>,<S/2,MIN(512-S,Y9),S1$>
0120 Y9=MIN(Y9,512)-2.5*S
   : RETURN
1000 DEFFN'31
   : COM CLEAR  P$
   : LOAD DC T "!"