image of READY prompt

Wang2200.org

Listing of file='@FORMAT' on disk='vmedia/701-2294U.wvd.zip'

# Sector 422, program filename = '@FORMAT'
0010 REM % Prog = @FORMAT     By PLS     Date = 02/01/85    Time = 00.00.00 PM
         Rel 2.6
0015 REM % COPYRIGHT WANG LABORATORIES 1985
0020 REM -- STAND ALONE UTILITY FOR FORMATTING 2260C, 2260BC, 2280 DISK DRIVES
      --
0030 REM -- VP/MVP VERSION -- FOR COMPATABLE VP/MVP OPERATING SYSTEM --
0040 REM -------------------------------------------------------
0050    COM D$3,V
0060    DIM A1$1,A2$2,C$(4)64
0070    ON V GOTO 860,280
0080    IF D$ <> " " AND D$ <> "xyy" THEN  280
0090 REM -------------------------------------------------------
0100    V = 0
0110    PRINT HEX(020D0C030F0E);,"***** DISK PLATTER FORMAT UTILITY *****"
0120    PRINT AT(7,0);"1. Do NOT use unless the disk drive is SOFTWARE FORMATT
     ABLE."
0130    PRINT "2. Some examples are the 2260C, 2260BC, and 2280 disk drives."
0140    PRINT "3. Check the manual for the time required to format a disk."
0150    PRINT "4. ALL DATA ON THE DISK WILL BE DESTROYED BY FORMATING."
0155 PRINT AT(23,0,70);"Press 'FN' or 'TAB' to return to menu.";
0160 REM -------------------------------------------------------
0170 REM ENTER ADDRESS AND CHECK VALIDITY
0180    $CLOSE
0190    D$="xyy"
0200    PRINT AT(2,0,60);
0210    LINPUT "Enter device address of the disk platter to format",-D$
0220    MAT SEARCH "310320330350360370B10B20B30B50B60B70D10D11D12D13D14D15D20D
     21D22D23D24D25D30D31D32D33D34D35D50D51D52D53D54D55D60D61D62D63D64D65D70D7
     1D72D73D74D75", = STR(D$,,3) TO A2$ STEP 3
0230    IF A2$ <> HEX(0000) THEN 250
0240    PRINT HEX(07);"RE-ENTER"
   : GOTO 180
0250    SELECT #1<D$>
0260 REM -------------------------------------------------------
0270 REM OPERATOR CHECK / ABORT OPPORTUNITY
0280    PRINT HEX(030E);,"***** DISK PLATTER FORMAT UTILITY *****"
0281 PRINT AT(23,0,79);"Press 'FN' or 'TAB' to return to menu.";
0290    PRINT AT(12,0);,"FORMAT PLATTER /";D$
0300    A1$ = " "
0310    PRINT AT(2,0,60);"Are you sure that you want to format platter /"; D$
     ; " (Y/N)?";
0320    LINPUT A1$
0330    ON POS("YyNn"=A1$) GOTO 370,370,100,100
0340    PRINT HEX(07)
   : GOTO 300
0350 REM -------------------------------------------------------
0360 REM HOG DEVICE
0370    $OPEN 680,#1
   : ERRORX = ERR
   : GOTO 630
0380 REM CHECK FOR PRESENCE OF DEVICE
0390    IF V = 2 THEN 540
   : ELSE V = 1
0400    PRINT AT(2,0,60);"If this message has not been erased within 15 second
     s, disk"
   : PRINT "is not responding properly.  Key 'RESET','RUN', AND 'RETURN'."
0410    DATA LOAD BA T#1,(0) C$()
   : ERRORGOTO 420
0420    DATA LOAD BA T#1,(0) C$()
   : ERRORX = ERR
   : GOTO 740
0430    V = 0
   : PRINT AT(2,0,63);AT(3,0,63);
0440 REM -------------------------------------------------------
0450 REM CHECK FOR DATA ON DISK
0460    IF POS(C$()<>00) = 0 THEN 540
0470    A1$ = " "
0480    PRINT AT(2,0,60);"There is data on disk /"; D$ ; ", do you wish to con
     tinue (Y/N)?";
0490    LINPUT A1$
0500    ON POS("YyNn"=A1$) GOTO 540,540,100,100
0510    PRINT HEX(07)
   : GOTO 480
0520 REM -------------------------------------------------------
0530 REM EXECUTE AND CHECK FORMAT OF PLATTER
0540    V = 0
0550    PRINT AT(2,0,70);,"FORMATTING...";
0560    $FORMAT DISK T#1
   : ERRORX = ERR
   : GOTO 970
0570 REM -------------------------------------------------------
0580    PRINT AT(2,0,60);,"FORMATTING COMPLETE"
0590    COM CLEAR  D$
0600    END
0610 REM -------------------------------------------------------
0620 REM ERROR ATTEMPTING TO HOG DISK
0630    PRINT AT(4,0,60);"Specified disk address is not in the MASTER DEVICE T
     ABLE."
0640    PRINT "ERROR CODE = ";X
0650    GOTO 200
0660 REM -------------------------------------------------------
0670 REM DISK HOGGED WITHIN MVP
0680    PRINT AT(2,0,60);"DISK IS HOGGED BY ANOTHER USER"
0690    INPUT "KEY 'RETURN' TO CONTINUE",X
0700    PRINT AT(2,0,150)
0710    GOTO 370
0720 REM -------------------------------------------------------
0730 REM ERRORS WHILE TRYING TO LOAD SECTOR 0
0740    V =0
0750    IF X = 90 OR X = 91 OR X=92 OR X=94 OR X=95 OR X = 98 THEN 780
0760    PRINT AT(2,0,63);AT(3,0,63)
   : GOTO 540
0770 REM WRONG DISK SPECIFIED
0780    PRINT AT(2,0,160);,"PROBLEM WITH DISK /";D$
0790    PRINT ,"CHECK:"
0800    PRINT ,"1 - drive in 'READY' mode"
0810    PRINT ,"2 - wrong disk may have been specified"
0815    PRINT ,"3 - platter may not be mounted"
0820    PRINT ,"DISK READ ERROR, ERROR CODE = ";X
0830    GOTO 1030
0840 REM -------------------------------------------------------
0850 REM DISK HANGS DURING DATA LOAD
0860    PRINT AT(2,0,160);,"PROBLEM WITH DISK /";D$
0870    PRINT ,"CHECK:"
0880    PRINT ,"1 - drive in 'READY' mode"
0890    PRINT ,"2 - wrong disk may have been specified"
0900    PRINT ,"3 - cable connections may be loose"
0910    PRINT ,"4 - disk may be hogged by another user"
0920    PRINT ,"5 - may be a virgin platter"
0930    V = 2
0940    GOTO 1030
0950 REM -------------------------------------------------------
0960 REM ERRORS WHILE TRYING FORMAT DISK
0970    PRINT AT(2,0,160);,"ERROR DURING FORMAT ATTEMPT"
0980    PRINT ,"CHECK:"
0990    PRINT ,"1 - software formattable disk drives ONLY"
1000    PRINT ,"2 - disk address not in master device table"
1005    PRINT ,"3 - platter write protected"
1010    PRINT ,"ERROR CODE = ";X
1020 REM -------------------------------------------------------
1030    PRINT ,"To try again, key 'RESET','RUN', and 'RETURN'."
1040    STOP
1050 DEFFN '126
1060 DEFFN '127
1070 LOAD RUN