Listing of file='ACPA110D' on disk='vmedia/701-2654C.wvd.zip'
# Sector 516, program filename = 'ACPA110D'
0010 REM ACPA110D, RELEASE 1-0, (01/31/79) THIS PROGRAM IS A COPYRIGHT PRODU
CT OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBIT
ED
0020 REM PROGRAM NAME = ACPA110D
0030 REM RELEASE NUMBER = 01
0040 REM REVISION NUMBER = 00
0050 REM DATE WRITTEN = 1/21/79
0060 REM **************************************************
0070 REM * THIS PROGRAM IS PART OF A GENERALIZED *
0080 REM * APPLICATION. COPYRIGHT WANG LABS INC. 1979 *
0090 REM **************************************************
0110 REM SYSTEM NAME = GBS/MVP ACCOUNTS PAYABLE SYSTEM
0120 REM MODULE NAME = DISTRIBUTION REPORT
0130 REM PROGRAM FUNCTION = PRINTS DETAILED OR SUMMARY J/E DISTRIBUTION REPOR
T
0140 REM **************************************************
0150 REM
0170 DIM K0$8,K$1,K3$45,K4$5,Q5
0198 GOTO 4000
3990 REM
3996 REM ***********************
3997 REM ! DISTRIBUTION REPORT !
3998 REM ***********************
3999 REM
4000 SELECT @PART S0$
4030 %##,###,###.##-
4036 K$=K1$
4040 PRINT HEX(03);TAB(24);"DISTRIBUTION REPORT"
4490 REM -------------------
4510 REM CONTROL SECTOR
4520 GOSUB '66(9,0,1)
4530 L=60
4540 GOSUB '90
4550 SELECT PRINT 005(80)
4560 REM READ A SET OF TAGS
4570 J = MOD(J,50) + 1
4580 IF J = 1 THEN DATA LOAD DC #4,K6$()
4590 IF END THEN K6$()=ALL(FF)
4600 SELECT PRINT 005(80)
4610 REM CHECK FOR END OF TAG FILE
4620 H0$=HEX(FF)
4630 H1$="AP"
4640 IF STR(K6$(J),1,1)=HEX(FF) THEN 4720
4650 REM READ JOURNAL ENTRIES FILE
4660 Q7$ = "Error in Journal Entries File"
4670 DATA LOAD DA T#1,(STR(K6$(J),,2))M$()
: ERRORGOTO 5150
4680 REM TEST FOR END OF FILE, AS INDICATED BY INPUT FILE
4690 I = VAL(STR(K6$(J),4))
4700 IF STR(M$(I),,1) <> HEX(FF) THEN $UNPACK(F=L3$)M$(I) TO H2,H0$,H1$,H,
H3$,H4$,H5$,H1
: ERRORGOTO 5150
4710 REM FIRST TIME THROUGH, GET ACCOUNT NAME, SET PREVIOUS VENDOR, ACCOUNT NU
MBERS
4720 IF K0$=" " THEN GOSUB 7230
4730 IF H1$ <> "AP" THEN 4570
4740 REM CHECK FOR VENDOR BREAK, IF DETAILED REPORT
4750 IF K$="S" THEN 4850
4760 IF K4$=H4$ AND K0$=H0$ THEN 4850
4770 GOSUB '90
4780 PRINT TAB(82);"VENDOR TOTAL";TAB(97);
4790 PRINTUSING 4030,K0;
4800 PRINT "*"
4810 PRINT HEX(0A)
4820 K0=0
4830 L=L+2
4840 REM CHECK FOR ACCOUNT NO. BREAK, ALWAYS
4850 IF K0$=H0$THEN 4970
4860 GOSUB '90
4870 IF K$="S" THEN PRINT K3$;TAB(43);
: ELSE PRINT TAB(81);"ACCOUNT TOTAL";TAB(97);
4880 REM PRINT ACCOUNT TOTALS
4890 PRINTUSING 4030,K4;
4900 IF K$="D" THEN PRINT "**"
: ELSE PRINT
4910 L=L+2
4920 IF K$="S" THEN L=L-1
: ELSE PRINT HEX(0A)
4930 REM CLEAR ACCOUNT TOTALS
4940 K4 = 0
4950 IF H0$ = HEX(FF) THEN GOSUB '31
4960 GOSUB 7230
4970 IF K$="S" THEN 5080
4980 GOSUB '90
4990 GOSUB '123(H)
5000 IF Q6$ = "E" THEN U9$ = "INVALID"
5010 PRINT K3$;TAB(41);H4$;TAB(51);H3$;TAB(75);H5$;TAB(86);U9$;TAB(97);
5020 K3$ = " "
5030 PRINTUSING 4030,H1;
5040 PRINT TAB(120);
5050 PRINTUSING "#####";H2
5060 REM ACCUMULATE TOTALS
5070 L=L+1
5080 K0 = K0 + H1
5090 K4 = K4 + H1
5100 REM ACCUMULATE REPORT TOTALS
5110 IF H1 < 0 THEN K5 = K5 + H1
: ELSE K6 = K6 + H1
5120 K4$=H4$
5130 GOTO 4570
5140 REM ERROR EXIT
5150 GOSUB '91
5160 PRINT AT(1,0,80);Q7$;HEX(07)
5170 PRINT AT(3,16,64);Q6$
5180 GOSUB '254
5190 REM END OF PROGRAM
5200 DEFFN'31
5210 IF H0$ <> HEX(FF) THEN 5315
5220 SELECT PRINT <I0$>(132)
5230 PRINT HEX(0A)
5240 IF K$="D" THEN Q9=54
: ELSE Q9=0
5250 REM PRINT REPORT TOTAL
5260 PRINT TAB(14+Q9);"TOTAL CREDITS DISTRIBUTED";TAB(43+Q9);
5270 PRINTUSING 4030,K5
5280 PRINT TAB(15+Q9);"TOTAL DEBITS DISTRIBUTED";TAB(43+Q9);
5290 PRINTUSING 4030,K6
5300 PRINT HEX(0C)
5302 $OPEN #9
5303 GOSUB '66(9,0,1)
5304 F5$(3)="1"
5305 GOSUB '66(9,0,0)
5306 $CLOSE#9
5315 GOSUB '219(S$(4),4,S2," ",0)
5325 GOSUB '219(S$(1),1,S2," ",0)
5327 GOSUB '219(S$(9),9,S2," ",0)
5330 GOSUB '239(1)
5360 COM CLEAR I
5370 LOAD T M$
7000 REM ****************
7010 REM * SUBROUTINES *
7020 REM ****************
7030 REM PAGE EJECT ROUTINE
7040 DEFFN'90
7050 SELECT PRINT <I0$>(132)
7060 Q6$=" "
7070 KEYIN Q6$,7080,7080
7080 IF Q6$="P" THEN GOSUB '254
7085 IF Q6$=HEX(1F) THEN GOSUB '31
7090 IF L < L0 THEN RETURN
7100 P1 = P1 + 1
7110 PRINT HEX(0C0A0D0E);TAB(3);N2$
7120 PRINT TAB(48);"A/P DISTRIBUTION REPORT - ";K1$;TAB(109);D9$;TAB(121);
"PAGE ";P1
7130 PRINT HEX(0A)
7140 PRINT "ACCOUNT";
7150 IF K$ = "D" THEN PRINT TAB(42);"VENDOR";TAB(76);"INVOICE";TAB(87);"IN
VOICE";TAB(120);"TRANS"
: ELSE PRINT
7160 PRINT TAB(5);"NO.";TAB(10);"NAME";
7170 IF K$ = "D" THEN PRINT TAB(45);"NO";TAB(51);"NAME";TAB(79);"NO";TAB(8
9);"DATE";TAB(101);"AMOUNT";TAB(123);"NO"
: ELSE PRINT TAB(50);"AMOUNT"
7180 PRINT HEX(0A)
7190 L = 7
7200 RETURN
7210 REM -------------
7220 REM READ CHART OF ACCOUNTS FILE
7230 GOSUB '232(1,0,H0$)
7240 O5$="Not in chart of accounts file"
7250 IF Q$ = " " THEN GOSUB '75(8)
7260 IF Q$ = "B" THEN O5$="Chart of accounts record busy"
7270 REM EXIT IF END OF FILE
7280 K3$ = H0$&" "&O5$
7290 K0$ = H0$
7300 K4$ = H4$
7310 RETURN
9000 REM *************
9010 REM * VARIABLES *
9020 REM *************
9030 REM I = SUBSCRIPT FOR J/E FILE
9040 REM J = SUBSCRIPT FOR TAG FILE
9050 REM K0$ = PREVIOUS ACCOUNT NO.
9060 REM K0 = ACCOUNT TOTALS
9070 REM K$ = REPORT TYPE (D,S)
9080 REM K1$ = REPORT TYPE (DETAIL, SUMMARY)
9090 REM K3$ = ACCOUNT NO. AND NAME
9100 REM K4$ = PREVIOUS VENDOR NO.
9110 REM K4 = VENDOR TOTALS
9120 REM $
9999 DEFFN'29"Q$=";HEX(22);"ACPA110D";HEX(22);":SCRATCHTQ$:SAVET()Q$";HEX(0D)