image of READY prompt

Wang2200.org

Listing of file='IDS2PUM1' on disk='vmedia/701-2715B.wvd.zip'

# Sector 735, program filename = 'IDS2PUM1'
1000 REM 'IDS2PUM1' MAINTENANCE PROGRAM FOR CPU ID FILE
3000 DEFFN'71
   : DIM F0(6),E3$(249)8
   : P=2
3002 LIMITS T#P,"IDS2f001",A,B,C,D
   : ERRORIF P=0THEN STOP " Invalid device specification"
   : P=0
   : GOTO 3002
3005 IF D>0THEN 3020
   : DATA SAVE DC OPEN T#P,(3)"IDS2f001"
   : ERRORGOTO 3195
3007 MAT F0=ZER
   : F0=1
   : F0(1)=#ID
   : R0=#PART
   : DATA LOAD DC OPEN T#P,"IDS2f001"
   : DATA SAVE DC #P,F0,F0()
   : DATA SAVE DC #P,END
   : GOSUB 3160
   : GOTO 3110
3020 DATA LOAD DC OPEN T#P,"IDS2f001"
   : DATA LOAD DC #P,F0,F0()
   : GOSUB 3160
   : FOR I=1TO F0
   : IF F0(I)<>#IDTHEN 3050
   : PRINT AT(20,0,80);"CPU is already in master file"
   : R0=(I-1)*16+#PART
   : GOTO 3110
3050 NEXT I
3060 IF F0=6THEN 3090
   : ELSE PRINT AT(21,0,80);BOX(1,79);AT(21,5);" Your CPU is not in Master Fil
     e; Select 'A' to add, 'C' to change";AT(21,71);
   : E6$=" "
   : LINPUT E6$
   : IF E6$<>"A"AND E6$<>"C"THEN 3060
   : IF E6$="C"THEN 3090
   : F0=F0+1
   : F0(F0)=#ID
   : R0=(F0-1)*16+#PART
   : DBACKSPACE #P,1S
   : DATA SAVE DC #P,F0,F0()
   : DATA SAVE DC #P,END
   : GOTO 3110
3090 PRINT AT(21,0,80);BOX(1,79);AT(21,5);" Please enter number for CPU to cha
     nge (1 to ";F0;")";AT(21,54);
   : E6$=" "
   : LINPUT E6$
   : IF E6$<"1"OR E6$>"6"THEN PRINT HEX(07);
   : IF E6$<"1"OR E6$>"6"THEN 3090
   : CONVERT E6$TO F
   : IF F>F0THEN PRINT HEX(07);
   : IF F>F0THEN 3090
   : F0(F)=#ID
   : R0=(F-1)*16+#PART
   : DBACKSPACE #P,1S
   : DATA SAVE DC #P,F0,F0()
   : DATA SAVE DC #P,END
   : GOTO 3110
3110 DIM J$8
   : J$="IDS2fs  "
   : IF R0>=#PARTTHEN CONVERT (R0-#PART)/16+1TO STR(J$,7,2),(##)
   : LIMITS T#P,J$,A,B,C,D
   : IF D>0AND B-A>=165THEN 3150
   : IF D=0THEN 3140
   : DIM J1$8
   : J1=0
   : J1$="JUNKxxxx"
3130 J1=J1+1
   : CONVERT J1TO STR(J1$,5,4),(####)
   : LIMITS T#P,J1$,A,B,C,D
   : IF D<>0THEN 3130
   : SCRATCH T#P,J$
   : SAVE DC T#P,(J$)J1$1000,1000
   : SCRATCH T#P,J1$
3140 DATA SAVE DC OPEN T#P,(166)J$
   : ERRORGOTO 3195
3145 MAT REDIM E3$(9)83
   : E3$()=" "
   : DATA SAVE DC #P,E3$()
   : DSKIP #P,161S
   : DATA SAVE DC #P,END
   : LIMITS T#P,J$,A,B,C,D
   : FOR I=A+3TO A+163
   : DATA SAVE BA T#P,(I)STR(E3$(),,256)
   : NEXT I
   : STR(E3$(),,8)=ALL(30)
   : DATA SAVE BA T#P,(A+3)STR(E3$(),,256)
3150 RETURN
3160 SELECT PRINT 005
   : PRINT HEX(03);AT(1,10,80);BOX(1,59);AT(1,20);HEX(020402000E);" CPU Master
      File Maintenance Program";HEX(0F);AT(8,20);BOX(9,40);AT(9,26);" CPU NUMB
     ER ";AT(9,45);" CPU ID ";AT(10,25);BOX(0,30);
   : FOR I=1TO 6
   : PRINT AT(9+I,29);I;AT(9+I,45);
   : IF I<=F0THEN PRINT F0(I);
   : ELSE PRINT "NOT USED";
   : NEXT I
3180 PRINT AT(17,20);BOX(1,40);AT(17,27);"Current CPU ID # is ";#ID;
   : PRINT HEX(06);AT(23,20);BOX(1,40);AT(23,24);"Creating system files, pleas
     e wait";
   : RETURN
3195 PRINT AT(20,0,80);"FATAL ERROR - No room on system platter for necessary
     files";
   : STOP
   : END
3200 DEFFN'127"J5$=";HEX(22);"IDS2PUM1";HEX(22);":SCRATCH T J5$ :SAVE DC T ()
     J5$ ";HEX(0D)