image of READY prompt

Wang2200.org

Listing of file='609@Cat4' on disk='vmedia/701-2737G.wvd.zip'

# Sector 887, program filename = '609@Cat4'
0010 REM '609@Cat4' - CATALOG DISPLAY/LIST - SUMMARY OUTPUT
0200 DIM D1,C0(3),C$1,C0$20,C1$80,C2$80,C3$80,C0$(256)2,C1$(256)2
   : GOSUB 2505
   : PRINT AT(3,0,80);B2$;
   : MAT SORTD0$()TO C0$(),C1$()
   : INIT(00)C0$
   : $FORMATC0$=SKIP 16,A16,SKIP 15,F6,SKIP 3,F6,SKIP 5,F6
   : PRINT AT(3,0,50);
   : IF POS(D0$(1)<>FF)>0THEN 340
   : GOSUB 2510
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 1200
0340 GOSUB 2515
   : PRINT AT(3,0);B2$
   : IF T5(2)=1THEN 450
   : SELECT #6<D0$>
0360 $OPEN 400,#6
   : ERRORGOSUB 2575
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 1200
0370 GOSUB 1472
   : GOTO 410
0400 GOSUB 2570
   : PRINT AT(23,0,);B2$;
   : GOSUB '34(0)
   : IF J$<>HEX(0D)THEN 1200
   : GOTO 360
0410 PRINT AT(23,0,);
   : SELECT PRINT <D0$>
   : GOSUB 1472
   : PRINT HEX(0C)
   : GOTO 460
0450 PRINT HEX(0306);
0460 GOSUB 2520
   : C3$=B2$&" "&STR(D2$,1,8)
   : C3$=C3$&":"
   : IF D$(1)=" "THEN 530
   : ELSE C3$=C3$&D$(1)
   : IF D$(2)=" "THEN 530
   : ELSE C3$=C3$&"."&D$(2)
   : IF D$(3)=" "THEN 530
   : ELSE C3$=C3$&"."&D$(3)
   : IF D$(4)=" "THEN 530
   : ELSE C3$=C3$&"."&D$(4)
0530 C1$=C3$
   : GOSUB 1370
   : MAT C0=ZER
   : FOR C=1TO 256
   : IF POS(D0$(C)<>FF)>0THEN 630
   : D1=C-1
   : C=256
   : GOTO 660
0630 C0(1)=C0(1)+VAL(STR(D1$(C),3),2)
   : C0(2)=C0(2)+VAL(STR(D1$(C),5),2)
   : C0(3)=C0(3)+VAL(STR(D1$(C),1),2)
0660 NEXT C
   : IF T5(2)=1THEN 860
   : C5=1
0700 FOR C=C5TO C5+55
   : IF C>D1THEN 800
   : C4=VAL(C1$(C),2)
   : $PACK(F=C0$)C2$FROMD0$(C4),VAL(STR(D1$(C4),3),2),VAL(STR(D1$(C4),5),2),VA
     L(STR(D1$(C4),1),2)
   : PRINT C2$
   : NEXT C
   : GOSUB 1370
   : C5=C5+56
   : GOTO 700
0800 PRINT
   : GOSUB 2525
   : $PACK(F=C0$)C2$FROMB2$,C0(1),C0(2),C0(3)
   : PRINT C2$
   : SELECT PRINT 005
   : GOTO 1200
0860 C5=1
   : C6=0
0890 PRINT AT(8,0,);
   : FOR C=C5TO C5+14
   : IF C<=D1THEN 1050
   : IF C6=1THEN 990
   : C2$=ALL(80)
   : STR(C2$,1,1),STR(C2$,80,1)=" "
   : PRINT C2$
   : C6=1
   : IF C=C5+14THEN 1020
0990 IF C6=2THEN 1090
   : GOSUB 2525
   : $PACK(F=C0$)C2$FROMB2$,C0(1),C0(2),C0(3)
   : C6=2
1020 C=C5+14
   : GOTO 1070
1050 C4=VAL(C1$(C),2)
   : $PACK(F=C0$)C2$FROMD0$(C4),VAL(STR(D1$(C4),3),2),VAL(STR(D1$(C4),5),2),VA
     L(STR(D1$(C4),1),2)
1070 $TRAN(STR(C2$,2,78),HEX(8020))R
   : PRINT C2$
1090 NEXT C
1110 KEYIN C$,1112,1120
   : GOTO 1110
1112 PRINT AT(23,0);
   : ON POS(HEX(0D82)=C$)GOTO 1180,1180
   : GOTO 1150
1120 PRINT AT(23,0);
   : ON POS(HEX(50F04243)=C$)GOTO 1200,1200,1240,1310
1150 GOSUB 2530
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 1110
1180 GOTO 860
1200 COM CLEAR D0$()
   : SELECT PRINT 005
   : PRINT AT(3,0,79);
   : $CLOSE
   : LOAD T"609@Cat0"
1240 IF C5-14>0THEN 1270
   : GOSUB 2535
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 1110
1270 C5=C5-14
   : C6=0
   : GOTO 890
1310 IF C5+14<=D1THEN 1340
   : GOSUB 2540
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 1110
1340 C5=C5+14
   : GOTO 890
1370 GOSUB 1472
   : GOSUB 2545
   : PRINT TAB(23);B2$
   : GOSUB 1472
   : GOSUB 2550
   : PRINT TAB(24);B2$
   : GOSUB 1472
   : PRINT
   : IF T5(2)=2THEN 1430
   : GOSUB 2555
   : PRINT TAB(12);B2$
   : PRINT
1430 GOSUB 1472
   : PRINT TAB(0);C1$
   : GOSUB 1472
   : GOSUB 2560
   : PRINT TAB(47);B2$
   : GOSUB 1472
   : PRINT
   : IF T5(2)=1THEN PRINT BOX(15,79);
   : RETURN
1472 X=1
   : B2$=ALL(00)
1473 $GIO#6(010102001212400040004000,B2$)
   : IF STR(B2$,8,1)=HEX(00)THEN RETURN
   : X=X+1
   : IF X<20THEN 1473
   : GOSUB 2565
   : PRINT AT(23,0,);B2$;
   : GOSUB '34(0)
   : IF J$<>HEX(0D)THEN 1200
   : GOTO 1472
2500 % DO NOT RENUMBER THE FOLLOWING
2505 B2$="(Sorting Volume Catalog)"
   : RETURN
2510 B2$="File or Partial File Name Not Found on Volume"
   : RETURN
2515 B2$="(Printing Catalog List)"
   : RETURN
2520 B2$="Summary Catalog of :"
   : RETURN
2525 B2$="Totals"
   : RETURN
2530 B2$="Invalid Key"
   : RETURN
2535 B2$="No Previous Screen"
   : RETURN
2540 B2$="No Next Screen"
   : RETURN
2545 B2$="WANG 2200 Word Processing System"
   : RETURN
2550 B2$="Catalog Display/List Utility"
   : RETURN
2555 B2$="Use NEXT-SRCN, PREV-SCRN, EXECUTE and CANCEL to Scan File"
   : RETURN
2560 B2$="Vaus    Sectors    Files"
   : RETURN
2565 B2$="Select Printer"
   : RETURN
2570 B2$="Printer In Use, Press EXECUTE to try again"
   : RETURN
2575 B2$="Illegal Printer Device"
   : RETURN