image of READY prompt

Wang2200.org

Listing of file='609@arch' on disk='vmedia/701-2737G.wvd.zip'

# Sector sector 948, program filename = '609@arch'
0010 REM '609@arch' - ARCHIVE ASSIGNMENTS
0140 DIM J$(4)62,J$1,J0$(52)3
   : DIM S5(2),S0(2),T5(2),T1$(56)20,S3(2),S1$(56)2
   : DIM T1(14),S6(14),S1(14),T2$(14)80
   : DIM T2(2),S7(2),S2(2),S4(2),T5$(2)25
   : DIM S2$(50)2,S1$56
   : DIM S7,S9,T0,T2,T3,S0,T5,C0,T7,S2$1,T1$80,T2$2
   : DATA LOAD DC OPEN T#0,"609@ARCH"
   : DBACKSPACE #0,BEG
   : DSKIP #0,1S
   : FOR C=1TO 52
   : DATA LOAD DC #0,J$()
0280 J0$(C)=STR(J$(),133,3)
   : NEXT C
0340 RESTORE LINE2510
   : PRINT HEX(0306);
   : S2=4
   : S3=12
   : GOSUB '61
   : T1$=HEX(020400040E)&T2$(4)&B5$(1)
   : T2$(4)=T1$
   : T1$=HEX(020400040E)&T2$(5)&B5$(2)&HEX(0F)
   : T2$(5)=T1$
   : FOR C=1TO 52
   : IF J0$(C)<>" "THEN T1$(C)=T1$(C)&" / "&J0$(C)
   : NEXT C
   : IF J1<>0THEN T5(1)=J1-1
0490 GOSUB '62
   : ON T5+1GOTO 1420,520
   : GOSUB 2715
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 490
0520 J0=T5(2)
   : J1=T5(1)+1
   : J$=T1$(T5(1))
   : DBACKSPACE #0,BEG
   : DSKIP #0,J1-1S
   : DATA LOAD DC #0,J$()
   : ON J0GOTO 660,620,660
0620 IF STR(J$(),136,1)=" "THEN 710
   : GOSUB 2725
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 490
0660 IF STR(J$(),136,1)<>" "THEN 710
   : GOSUB 2730
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 490
0710 RESTORE LINE2575
   : PRINT HEX(0306);
   : GOSUB '61
   : T2$(5)=T2$(5)&" "&J$
   : ON J0GOTO 950,800,1100
   : STOP "MENU ERROR"
0800 GOSUB 2720
   : T2$(2)=B2$
   : T5$()=" "
   : T5(1)=1
0850 GOSUB '62
   : ON T5+1GOTO 340,880
   : GOSUB 2715
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 850
0880 IF VERSTR(T5$(),,3),"H##")=3THEN 1320
   : GOSUB 2735
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 850
0950 T5$(1)=STR(J$(),133,3)
   : CONVERT STR(J$(),136,1)TO T5(1)
   : ERRORT5(1)=1
0990 T5$(2)=STR(J$(),137,25)
1010 GOSUB '62
   : ON T5+1GOTO 340,1040
   : GOSUB 2715
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 1010
1040 IF VERSTR(T5$(),,3),"H##")=3THEN 1320
   : GOSUB 2735
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 1010
1100 RESTORE LINE2640
   : GOSUB '61
   : T2$(5)=T2$(5)&" "&J$
   : T2$(7)=STR(J$(),133,3)
   : CONVERT STR(J$(),136,1)TO T5(1)
   : ERRORT5(1)=1
1180 IF T5(1)=1THEN T2$(9)=HEX(8B)
   : ELSE T2$(9)="."
   : IF T5(1)=1THEN T2$(11)="."
   : ELSE T2$(11)=HEX(8B)
   : T2$(14)=STR(J$(),137,25)
   : $TRAN(STR(T2$(14),,25),HEX(8520))R
1240 GOSUB '62
   : ON T5+1GOTO 340,1270
   : GOSUB 2715
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 1240
1270 STR(J$(),125)=" "
   : J0$(J1-1)=" "
   : GOTO 1370
1320 STR(J$(),125,8)=J$
   : J0$(J1-1),STR(J$(),133,3)=T5$(1)
   : CONVERT T5(1)TO STR(J$(),136,1),(#)
   : STR(J$(),137,25)=T5$(2)
1370 DBACKSPACE #0,1S
   : DATA SAVE DC #0,J$()
   : GOTO 340
1420 LOAD T"609menu"
2500 % DO NOT RENUMBER THE FOLLOWING
2510 DATA 3,0,0,"A R C H I V E   A S S I G N M E N T S"
   : DATA 4,2,0,"Press EXECUTE to Continue"
   : DATA 4,3,5,"CANCEL to Exit"
   : DATA 4,5,19,"Archive / Address"
   : DATA 4,5,57,"Option"
   : DATA 1,-7,8,1,"A","B","C","D","E","F","G","H","I","J","K","L"
2545 DATA "M","N","O","P","Q","R","S","T","U","V","W","X","Y","Z"
   : DATA "a","b","c","d","e","f","g","h","i","j","k","l"
   : DATA "m","n","o","p","q","r","s","t","u","v","w","x","y","z","BIN("
   : DATA 1,7,57,1,"Edit","Create","Delete","BIN("
   : DATA 0
2575 DATA 3,0,0,"A R C H I V E   A S S I G N M E N T S"
   : DATA 4,1,34,"  E D I T  "
   : DATA 4,2,0,"Press EXECUTE to Continue"
   : DATA 4,3,5,"CANCEL to Exit"
   : DATA 4,7,25,"Archive : "
   : DATA 4,9,25,"Disk Address :"
   : DATA 2,9,40,3," "
   : DATA 4,11,25,"Type of Archive : "
2615 DATA 1,11,44,1,"2200 System Archive","WP Archive Diskette","BIN("
   : DATA 4,14,25,"Comments : "
   : DATA 2,14,36,25," "
   : DATA 0
2640 DATA 3,0,0,"A R C H I V E   A S S I G N M E N T S"
   : DATA 4,1,34,"D E L E T E"
   : DATA 4,2,0,"Press EXECUTE to Continue"
   : DATA 4,3,5,"CANCEL to Exit"
   : DATA 4,7,25,"Archive : "
   : DATA 4,9,25,"Disk Address :"
   : DATA 4,9,40,"XXX"
   : DATA 4,11,25,"Type of Archive : "
   : DATA 4,11,44,"X"
2685 DATA 4,11,46,"2200 System"
   : DATA 4,12,44,"X"
   : DATA 4,12,46,"WP System Diskette"
   : DATA 4,14,25,"Comments : "
   : DATA 4,14,36,"XXXXXXXXXXXXXXXXXXXXXXXXX"
   : DATA 0
2715 B2$="Invalid Key"
   : RETURN
2720 B2$="C R E A T E"
   : RETURN
2725 B2$="Archive Already Assigned"
   : RETURN
2730 B2$="Archive Not Assigned Yet"
   : RETURN
2735 B2$="Invalid Disk Address"
   : RETURN