image of READY prompt

Wang2200.org

Listing of file='609@volc' on disk='vmedia/701-2737G.wvd.zip'

# Sector sector 778, program filename = '609@volc'
0010 REM %609@volc - Create Volume 236 DGF 07/11/86
0015 DIM S4,S5(1),S0(1),T5(1),T1$(1)1,S3(1)
   : DIM S5,T1(6),S6(6),S1(6),T2$(6)40
   : DIM S6,T2(4),S7(4),S2(4),S4(4)
   : DIM S1$4,S1$(4)2,S2$(24)2
   : DIM S2$1,T1$80,T2$2
   : DIM V0$(1)1,U1$(12),U2$(12)4,R1$1
   : GOSUB '61
   : PRINT HEX(03);
0040 GOSUB '62
   : ON T5+2GOTO 350,350,77
   : GOSUB 2000
0050 PRINT AT(23,0,77);HEX(07);B5$(2);T1$;
   : GOTO 40
0077 J=0
   : GOSUB 328
0080 C0=1
0100 GOSUB '236(8,C0)
   : IF R1$=HEX(00)THEN 150
   : GOSUB 2160
   : PRINT AT(23,0);B5$(2);T1$;HEXOF(R1$);B5$(1);HEX(07);
   : GOTO 40
0150 IF V1=0THEN 270
   : MAT SEARCHSTR(U1$(),,V1*16),=STR(T5$(1),,8)TO T2$STEP 16
   : IF T2$>HEX(0000)THEN 220
   : IF V1<8THEN 270
   : C0=C0+8
   : GOTO 100
0220 GOSUB 2070
   : PRINT AT(23,0);B5$(2);T1$;B5$(1);HEX(07);
   : GOTO 40
0270 IF VERSTR(T5$(3),,3),"HHH")<>3THEN 2010
   : SELECT #6<STR(T5$(3),,3)>
   : ERRORGOTO 2010
0300 CONVERT STR(T5$(4),,5)TO C6
   : ERRORGOTO 2020
0310 IF C6>=100AND C6=INT(C6)AND C6<16000THEN 320
   : GOTO 2030
0320 IF STR(T5$(1),,8)>" "THEN 327
   : GOSUB 2150
   : GOTO 50
0327 J=6
   : GOSUB 328
   : GOTO 340
0328 C0=0
0330 $OPEN 333,#J
   : PRINT AT(23,0,77);AT(0,0)
   : RETURN
0333 GOSUB 2170
   : FOR I=1 TO 22
   : KEYIN R1$,337,335
   : GOTO 337
0335 IF R1$<>HEX(F0) THEN 337
   : I=99
0337 $BREAK 0
   : NEXT I
   : IF I<99 THEN 330
   : T1$="Volume not created."
   : RETURN  CLEAR
   : GOTO 50
0340 GOSUB 2040
   : B9$=STR(T5$(1),,8)&T5$(2)
   : GOSUB '231(B9$,STR(T5$(3),,3),C6,1,3)
   : IF R1$=HEX(00)THEN 350
   : GOSUB 2050
   : C5$=" "
   : IF R1$>HEX(29)THEN CONVERT VAL(R1$)TO C5$,(##)
   : ELSE HEXUNPACKR1$TO C5$
   : ON VAL(R1$)GOSUB 2060,2070,2080,2090,2100,2110,2120,2130,2140
   : GOTO 50
0350 DEFFN'31
   : A5$()="609@vol Prime 62JCAT"
   : LOAD T<3>A5$()
2000 T1$="Invalid key"
   : RETURN
2010 T1$="Invalid disk address"
   : GOTO 50
2020 T1$="Use only digits for number of sectors, "&STR(T5$(4),,5)&" is not cor
     rect."
   : GOTO 50
2030 T1$="Number of sectors must be greater than 99 and  less than 16000"
   : GOTO 50
2040 PRINT AT(23,0);B5$(2);"Creating volume ";STR(T5$(1),,8);AT(0,0)
   : RETURN
2050 T1$="2200 disk file maintenance required.  Contact your system administra
     tor."
   : RETURN
2060 T1$="Volume full"
   : RETURN
2070 T1$="Volume already exists"
   : RETURN
2080 T1$="File or volume does not exist"
   : RETURN
2090 T1$="No free device slots"
   : RETURN
2100 T1$="Incorrect password"
   : RETURN
2110 T1$="Exclusive open error"
   : RETURN
2120 T1$="File not opened"
   : RETURN
2130 T1$="Illegal file ID"
   : RETURN
2140 T1$="Not enough room to re-use scratched file"
   : RETURN
2150 T1$="Volume name cannot be blank"
   : RETURN
2160 T1$="Volume Query failure - Return code = "
   : RETURN
2170 C0=C0+1
   : PRINT AT(23,0);B5$(2);"Disk is busy. Attempting disk access number";C0;"
     You may WAIT or CANCEL";AT(0,0)
   : RETURN
2180 DATA 3,0,0,"C R E A T E   V O L U M E "
   : DATA 4,4,0,"Please fill in the following:"
   : DATA 4,7,10,"Volume name"
   : DATA 2,7,30,8," "
   : DATA 4,8,10,"Volume password"
   : DATA 5,8,30,8," "
   : DATA 4,9,10,"Disk address"
   : DATA 2,9,30,3," "
   : DATA 4,10,10,"Number of sectors"
   : DATA 2,10,30,5," "
   : DATA 0