image of READY prompt

Wang2200.org

Listing of file='609INAB ' on disk='vmedia/701-2737G.wvd.zip'

# Sector 557, program filename = '609INAB'
0010 REM 609INAB WP 2.3.5 Copyright Wang Laboratories, Inc. 1986
0130 DIM T2$2,U1$(8),V0$(1)1,C1$122,U2$(8),V2$(256)1,T1$80,C0$2,C4$5,D0$2
   : $PSTAT="609INAB"
   : C9=0
   : C3=INT(D4/6)+SGN(MOD(D4,6))
   : PRINT HEX(0306)
   : GOSUB 2020
   : C6,C2=1
   : D3=4
0195 C1=0
   : FOR C6=1TO 6
   : C9=C9+1
   : IF C8=0THEN 250
   : MAT SEARCHC8$(),=STR(J9$(C9),5,1)TO D0$
   : IF D0$=HEX(0000)THEN 340
   : J=VAL(D0$,2)
   : B0$="DOCUMENT."&C8$(J)&"."&STR(J9$(C9),1,4)
   : B9$=C9$(J)
   : GOTO 255
0250 B0$="DOCUMENT."&T5$(1)&"."&J9$(C9)
0255 GOSUB '217(1,1,B0$,B9$)
   : B0$=STR(B0$,1,10)
   : $TRAN(U1$(),HEX(8020))R
   : IF C8=0THEN C4$=J9$(C9)&T5$(1)
   : ELSE C4$=J9$(C9)
   : PRINT AT(D3,0);HEX(85);AT(D3,1);BOX(1,6);AT(D3,2);C4$;
   : IF R1$<>HEX(00)THEN 315
   : IF STR(V2$(),8,6)<>HEX(202020202020)THEN PRINT AT(D3,8);"*";
0295 PRINT AT(D3,10);B5$(2);STR(U1$(),1,25);AT(D3,37);STR(U1$(),76,20);AT(D3,5
     9);STR(U1$(),51,20);B5$(1)
   : PRINT AT(D3+1,37);STR(U1$(),101,5);AT(D3+1,59);STR(U1$(),26,20);
   : GOSUB 2091
0315 PRINT AT(D3+2,0);BOX(0,79)
   : D3=D3+3
   : C1=C1+1
   : IF C9=D4THEN C6=6
0340 NEXT C6
   : IF C9<D4 THEN 366
   : IF @L3=0 THEN 366
   : GOSUB 2434
0366 GOSUB 2160
   : PRINT AT(23,4);B2$;C2;AT(4,0);HEX(05);
   : C6=1
   : D3=4
0380 PRINT HEX(06);AT(D3,0);HEX(05);
   : KEYIN C0$,,450
   : PRINT HEX(06);AT(23,40,);
   : ON POS(HEX(2008820D)=C0$)GOTO 475,475,425,425
   : PRINT HEX(07);
   : GOTO 380
0425 IF C8=0THEN R5$=J9$((C2-1)*6+C6)&T5$(1)
   : ELSE R5$=J9$((C2-1)*6+C6)
   : COM CLEAR C
   : $PSTAT=" "
   : LOAD T"609menu"
0450 ON POS(HEX(46454342F00F)=C0$)GOTO 475,475,565,530,490,505
   : PRINT HEX(07);
   : GOTO 380
0475 GOSUB 615
   : GOTO 380
0490 COM CLEAR C
   : $PSTAT=" "
   : LOAD T"609menu"
0505 GOSUB 740
   : PRINT HEX(0306)
   : GOSUB 2020
   : GOTO 195
0530 IF C2-1<1THEN C2=C3+1
   : C2=C2-1
   : GOTO 590
0565 IF C2+1<=C3THEN 585
   : C2=0
0585 C2=C2+1
0590 PRINT HEX(0306)
   : C9=(C2-1)*6
   : GOSUB 2020
   : GOTO 195
0615 PRINT HEX(06);
   : ON POS(HEX(20450846)=C0$)GOTO 630,630,675,675
0630 C6=C6+1
   : IF C6>C1THEN C6=1
   : IF C6>6OR J9$((C2-1)*6+C6)=" "THEN C6=1
   : C7=D3+3
   : IF C7>19OR C7>3*(C6+1)THEN C7=4
   : D3=C7
   : GOTO 725
0675 C6=C6-1
   : IF C6>0THEN 710
   : C6=7
0690 C6=C6-1
   : IF C6>C1THEN 690
   : IF J9$((C2-1)*6+C6)=" "THEN 690
0710 C7=D3-3
   : IF C7<4THEN C7=3*(C6+1)-2
   : D3=C7
0725 PRINT AT(D3,0);HEX(05);
   : RETURN
0740 GOSUB 2220
   : PRINT HEX(06);AT(0,58);B5$(2);HEX(0E);B2$;AT(23,40,40);B5$(1);
   : GOSUB '100(1,4,0,70," ")
   : PRINT HEX(06);AT(0,48,32);AT(23,40,20);
   : IF STR(C1$,1,3)=" "THEN 785
   : CONVERT STR(C1$,1,3)TO C2
   : IF C2=0THEN C2=1
   : IF C2>C3THEN C2=C3
   : GOTO 790
0785 C2=1
0790 C9=(C2-1)*6
   : RETURN
0810 DEFFN'100(D2,J4,J7,C0,C1$)
0815 D8=1
   : C0$=ALL(20)
   : PRINT AT(J7,C0);
0835 PRINT HEX(05);
   : KEYIN C0$,,865
   : IF C0$>=HEX(30)AND C0$<=HEX(39)THEN 1045
   : ON POS(HEX(080DE582)=C0$)GOTO 1005,965,985,980
0865 PRINT HEX(06);AT(23,60,20);
   : ON POS(HEX(F04C4D)=C0$)GOTO 900,920,940
   : GOSUB 2240
   : PRINT HEX(0607);AT(23,60);B5$(2);HEX(0E);B2$;AT(J7,C0+D8-1);B5$(1);
   : GOTO 835
0900 PRINT HEX(06);AT(23,60,20);AT(0,40,40);
   : RETURN CLEAR
0915 GOTO 380
0920 D8=D8+1
   : IF D8>J4THEN D8=J4
   : PRINT HEX(06);AT(J7,C0+D8-1);
   : GOTO 835
0940 D8=D8-1
   : IF D8<1THEN D8=1
   : PRINT HEX(06);AT(J7,C0+D8-1);
   : GOTO 835
0960 GOTO 835
0965 $TRAN(C1$,HEX(2020))R
   : RETURN
0980 RETURN
0985 C1$=ALL(20)
   : PRINT HEX(06);AT(J7,C0);STR(C1$,1,J4);
   : GOTO 815
1005 D8=D8-1
   : IF D8>=1THEN 1030
   : PRINT HEX(06);
   : GOTO 815
1030 PRINT HEX(082008);
   : STR(C1$,D8,1),C0$=" "
   : GOTO 1105
1045 STR(C1$,D8,1)=C0$
   : IF C0$=" "THEN C0$=HEX(20)
   : PRINT HEX(06);C0$;
   : IF D8=1THEN 1090
   : C0$=" "
   : D8=D8+1
   : IF D8>J4THEN 965
   : GOTO 1105
1090 STR(C1$,2,J4-1)=ALL(20)
   : PRINT STR(C1$,2,J4-1);AT(J7,C0+1);
   : D8=D8+1
1105 PRINT HEX(06);AT(23,60,20);AT(J7,C0+D8-1);
   : GOTO 835
2020 PRINT B6$(2)
   : PRINT AT(1,11);B5$(2);"Document Name";AT(1,38);"Comments";B5$(1);"/Archiv
     e ID";AT(1,60);B5$(2);"Author";B5$(1);"/Operator";
   : C1$=ALL(CC)
   : PRINT B5$(2);STR(C1$,1,80);B5$(1);B6$(1);
   : D3=4
   : C6=-1
   : RETURN
2091 IF STR(U1$(),109,1)=HEX(00)THEN 2100
   : IF STR(U1$(),109,1)=HEX(FF)THEN PRINT AT(D3+1,4);"archived";
   : GOTO 2140
2100 IF STR(V2$(),7,1)=HEX(00)AND STR(U1$(),107,1)=HEX(00)THEN 2130
   : PRINT AT(D3+1,4);"in use";
   : GOTO 2140
2130 IF STR(U1$(),106,1)=HEX(00)THEN PRINT AT(D3+1,4);"available";
   : ELSE PRINT AT(D3+1,4);"recovered";
2140 RETURN
2160 B2$="Page"
   : RETURN
2220 B2$="Which page?"
   : RETURN
2240 B2$="Digits only!"
   : RETURN
2422 %Warning:  Program can report only ### documents.  Volume has #,### docum
     ents.
2424 %Consider reporting index with different selection from the 'Which Ones'
     column
2426 %         on the selection menu for 'Document Index'.
2428 %Consider removing documents by using 'Delete from Library' or 'File to A
     rchive'
2430 %         on the selection menu for 'Document Filing'.
2432 %Good luck. Hope your day is interesting and productive.
2434 PRINT
   : PRINTUSING 2422,@L2,@L4
   : PRINT
   : PRINTUSING 2424
   : PRINTUSING 2426
   : PRINT
   : PRINTUSING 2428
   : PRINTUSING 2430
   : PRINT
   : PRINTUSING 2432
   : PRINT
   : PRINT BOX(0,79)
   : RETURN