image of READY prompt

Wang2200.org

Listing of file='609.VDSR' on disk='vmedia/701-2738G.wvd.zip'

# Sector sector 1156, program filename = '609.VDSR'
0010 REM 609.VDSR 237-07/29/86 Copyright Wang Laboratories, Inc. 1986
0011 REM .SCRATCH T/D11,"609.VDSR" -SAVE DC<S>T/D11,()"609.VDSR"
0020 DIM @D1$3,@D1$(3)82,@D1,J6$90
   : @D1=@D
0021 REM .VARIABLES
0022 REM   @D$(128)2  = List of 'bad-damaged' sectors ('FFFF' for not used)
0023 REM   @D1$(3)82  = buffer for reading corrected sector data
0024 REM   @D1$3      = string for reading corrected sector type and id
0025 REM   @D and @D1 = Number of entries, @D from 609.VER1 & @D1 work variabl
     e
0033 REM .Process--When 'type' code is O.K., set correct control values and re
     save.
0044 REM .Process--When 'type' code is not O.K., remove pointer from VAU map
0051 REM ..PAGE HEADING
0055 J6$="V o l u m e   R e c o v e r yVolume "&D5$&" on "&STR(D6$,1,3)&" Repa
     ired sectors "&"     "&STR(R2$,,2)&"/"&STR(R2$,3,2)&"/"&STR(R2$,5,2)
0056 SELECT PRINT <STR(A0$(1),2,3)>
   : PRINT TAB(25);STR(J6$,,29)
   : PRINT HEX(0A)
   : PRINT TAB(10);STR(J6$,30,60);HEX(0A)
0057 SELECT PRINT <STR(A0$(1),2,3)>
   : PRINT TAB(33);"ATTENTION";HEX(0A)
0058 PRINT "In order for the Word Processing system to access the following do
     cuments,"
   : PRINT "corrections to control information have been performed.  The autho
     r of each"
   : PRINT "document should review the reported documents for accuracy.";HEX(0
     A)
0111 REM .correct Text type sectors
   : IF @D<1THEN 999
   : FOR I=1TO @D
   : IF @D$(I)=HEX(FFFF)THEN 199
0122 REM .READ SECTOR
   : DATA LOAD BA T#5,(VAL(@D$(I),2))C1$()
   : ERRORSTOP #
0133 ON POS("GFHWET"=STR(C1$(),253,1))GOTO 144,144,144,144,144,144
   : REM .NOT  'TEXT' TYPE SECTOR
   : GOTO 199
0144 REM .SET ALL 'CONTROL' CODES
   : STR(C1$(),1,3)=HEX(8101D2)
   : STR(C1$(),86,1),STR(C1$(),169,1)=HEX(D2)
   : STR(C1$(),252,1)=HEX(83)
0146 REM .SAVE CORRECTED SECTOR
   : DATA SAVE BA T#5,(VAL(@D$(I),2))C1$()
   : ERRORSTOP "Error trying to save corrected sector.  Execute to continue **
     *"
0151 REM .read CORRECTED SECTOR
   : DATA LOAD DA T#5,(VAL(@D$(I),2))@D1$(),@D1$
   : ERRORSTOP "Error trying to load corrected sector.  Execute to continue **
     *"
0162 REM .IDENTIFY
   : PRINT "Sector number ";VAL(@D$(I),2)
   : REM . system id of ";HEXOF(@D1$)
   : PRINT HEX(0D0A);"Document number: (Unknown. Not enough information to ide
     ntify)";HEX(0A)
0163 PRINT "Text of corrected sector is:";HEX(0A)
0165 I4=POS(@D1$()<20)
   : IF I4=0THEN 166
   : STR(@D1$(),I4,1)=STR(@D1$(),I4,1)ADDCHEX(B0)
   : GOTO 165
0166 REM .REPORT CORRECTED SECTOR-
   : PRINT TAB(7);STR(@D1$(),1,63);HEX(0D0A);TAB(7);STR(@D1$(),64,61);HEX(0D0A
     );TAB(7);STR(@D1$(),125,61);HEX(0D0A);TAB(7);STR(@D1$(),186,61);HEX(0D0A0
     A)
   : D1=D1+6
0177 REM .REMOVE FROM LIST
   : @D$(I)=ALL(FF)
   : @D1=@D1-1
0199 NEXT I
0201 REM .are we done?
   : IF @D1<=1THEN 999
0211 REM .correct 'A' (Admin) type sectors
   : IF @D<1THEN 999
   : FOR I=1TO @D
   : IF @D$(I)=HEX(FFFF)THEN 299
0222 REM .READ SECTOR
   : DATA LOAD BA T#5,(VAL(@D$(I),2))C1$()
   : ERRORSTOP #
0233 ON POS("A"=STR(C1$(),253,1))GOTO 244
   : REM .NOT  'ADMIN' TYPE SECTOR
   : GOTO 299
0244 REM .SET ALL 'CONTROL' CODES
   : STR(C1$(),1,3)=HEX(8101D2)
   : STR(C1$(),86,1),STR(C1$(),169,1)=HEX(D2)
   : STR(C1$(),252,1)=HEX(83)
0246 REM .SAVE CORRECTED SECTOR
   : DATA SAVE BA T#5,(VAL(@D$(I),2))C1$()
   : ERRORSTOP "Error trying to save corrected sector.  Execute to continue **
     *"
0251 REM .read CORRECTED SECTOR
   : DATA LOAD DA T#5,(VAL(@D$(I),2))@D1$(),@D1$
   : ERRORSTOP "Error trying to load corrected sector.  Execute to continue **
     *"
0262 REM .IDENTIFY
   : PRINT "Sector number ";VAL(@D$(I),2);" and system id of ";HEXOF(@D1$)
0271 PRINT ,"The 'adminstrative' sector is now readable.";HEX(0A0A0D),,"Check
     the summary information for ";"9999A";HEX(0A0A)
   : D1=D1+6
0274 PRINT "The system is not able to reconstruct the summary with available i
     nformation.";HEX(0A)
0276 PRINT "If the 'summary' data is wrong, then you will have to 'SUPERCOPY'"
     ;HEX(0A0D);"the document to a new document.";HEX(0A)
0277 REM .REMOVE FROM LIST
   : @D$(I)=ALL(FF)
   : @D1=@D1-1
0299 NEXT I
0301 STOP "..testing..are we done "#
   : IF @D1<=1THEN 999
0311 STOP "..Page table should be only one(s) left. (test @ "#
0999 REM .exit
   : COM CLEAR C5
   : LOAD T"609.VER1"