image of READY prompt

Wang2200.org

Listing of file='@DOSREN' on disk='vmedia/734-8446.wvd.zip'

# Sector 2475, program filename = '@DOSREN'
0010 REM %^ @DOSREN UTILITY BY KIRIT BAXI EAME R&D
0020 REM % Version 1.0 20 JUN 1991
0030 REM ***********************************************
0040 REM *                                             *
0050 REM *              RENAME Program                 *
0060 REM *                                             *
0070 REM ***********************************************
0100 REM % DEFINE VARIABLES
0110 DIM A$(16)32,D$(16),B$4,C$16,D$3,E$2,F$2,G$2,H$8,J$11,L$2,M$4,N$1,O$1,P$1
     ,Q$1,V$11
   : PRINT HEX(02050F)
0120 REM % CHECK FOR DRIVE READY
   : DATA LOAD BMT#N,(0)D$()
   : ERRORE=ERR
   : IF E=98THEN DO
   : PRINT HEX(070E);"Please insert Diskette in drive "
   : END DO
   : IF E=98THEN 370
0130 REM ADDRESS SETUP BY DOS PROGRAM
0140 REM % FIND DISK TYPE AND SET OFFSET SECTOR
0150 DATA LOAD BMT#N,(1440,L)A$()
   : ERRORE=ERR
   : IF E=98THEN Y=10
   : V=13
   : GOTO 170
0160 DATA LOAD BMT#N,(4800,L)A$()
   : ERRORE=ERR
   : IF E=98THEN Y=30
   : V=27
   : GOTO 170
0170 A1,B,C,D,D2=0
   : IF Y=0THEN DO
   : Y=10
   : V=13
   : END DO
0180 REM % TRANSFER THE FILE T0 RENAME TO J$
   : MAT SEARCHI1$,="."TO E$
   : A=VAL(E$,2)
   : IF A=0THEN 190
   : STR(J$,1,8)=STR(I1$,1,A-1)
   : STR(J$,9,3)=STR(I1$,A+1,3)
   : GOTO 200
0190 J$=I1$
0200 REM % TRANSFER THE NEW FILE NAME TO J1$
   : MAT SEARCHI2$,="."TO E$
   : A=VAL(E$,2)
   : IF A=0THEN 210
   : STR(J1$,1,8)=STR(I2$,1,A-1)
   : STR(J1$,9,3)=STR(I2$,A+1,3)
   : GOTO 220
0210 J1$=I2$
0220 REM
0230 REM % GET THE DIRECTORY INFORMATION AND CHECK FOR FILES TO DELETE
0240 FOR Z=YTO Y+VSTEP 2
0250 DATA LOAD BMT#N,(Z,L)A$()
0260 FOR X=1TO 16
   : IF STR(A$(X),1,1)=HEX(00)OR STR(A$(X),1,1)=HEX(E5)OR STR(A$(X),12,1)=HEX(
     28)OR STR(A$(X),12,1)=HEX(03)OR STR(A$(X),12,1)>HEX(7F)THEN GOTO 320
   : IF STR(A$(X),12,1)=HEX(27)OR STR(A$(X),12,1)=HEX(02)OR STR(A$(X),12,1)=HE
     X(01)THEN 270
   : ELSE GOTO 280
0270 GOTO 320
0280 REM
0290 IF STR(A$(X),1,11)=STR(J$,1,11)THEN STR(A$(X),1,11)=STR(J1$,1,11)
0300 IF STR(A$(X),1,11)=STR(J$,1,11)THEN GOTO 360
   : ELSE GOTO 320
0310 REM
0320 NEXT X
0330 DATA SAVE BMT#N,(Z,L)A$()
0340 NEXT Z
0350 GOTO 370
0360 DATA SAVE BMT#N,(Z,L)A$()
0370 REM RET > COMMAND PROC
   : PRINT
   : I4$="R"
   : LOAD T"@DOS"