Listing of file='ASK?32G2' on disk='vmedia/bsc_3271_rel_1.14.04.wvd.zip'
# Sector 1150, program filename = 'ASK?32G2'
0010 REM ASK?32G2 11/25/81 3270 Gen Screen 2
: GOTO 1500
: ON AGOTO 2010,2030
1490 REM %.3270 Configuration Screen 2 "Print Stream Data"
1500 P0=40
: P=1
: IF STR(Z$,31,1)<>"<"THEN 1540
1510 XOR (Z$,W$)
: XOR (W$,Z$)
: XOR (Z$,W$)
: REM /.swap Z$--W$
1540 Z1$=Z$
: GOSUB '33
1550 N$(5)="ASK?3270"
: REM /.reset ? module for load
1580 XOR (Z$,W$)
: XOR (W$,Z$)
: XOR (Z$,W$)
: REM /.swap Z$--W$
1590 LOAD DC T#0,"ASK?32G3"
1990 REM %..ASKAPARM - 3270 question interface
2000 REM ...3270 Ask Parameters
2010 ON P GOSUB 2150
: RETURN
2030 ON P GOSUB 2140
: RETURN
2050 REM .Screen 2 prompts Swap Z$/W$ Use Z$ Swap W$/Z$ end in W$
2060 REM .01-08 3270
2070 REM .09-16 BSC*050A ucode module name
2073 REM .20-24 Number of sectors
2090 REM .25-40 215 216 217 218 System printer addresses
2100 REM .41-49 Prompt area for screen 2 queries
2110 REM .43 ?3 Any spool to disk data
2112 REM .44 ?4 Method Add/Create/Replace
2120 REM .51-58 Spooler file name
2125 REM .59-61 Spooler disk address
2130 REM %^.Questions
2140 D$="P r i n t S t r e a m D a t a"
: P=1
: P9=7
2150 INIT(20)D$()
: ON AGOTO 2170,2190,2220,2240,2290,2310,2330
2160 REM .?1
2170 GOSUB '203("SYSTEM PRINTER ADDRESSES",25,((VAL(STR(W$,34))-48)*4)-1," ")
: RETURN
2180 REM .Line 2 (no prompt)
2190 A$=STR(W$,34,1)
: STR(A$,2)=" PRINTERS CONFIGURED"
2200 FOR E=1 TO VAL(A$)-48
: STR(D$(1),E*4-3)=STR(W$,E*3-2,2)
: NEXT E
: E=-1
: RETURN
2210 REM .?3
2220 A$="ANY SPOOL TO DISK DATA"
: D$(1)="Yes"
: D$(2)="No"
: RETURN
2230 REM .?4
2240 IF C$(3)=HEX(02)THEN 110
: A$="STORAGE METHOD"
: D$(1)="Add to an existing file"
: D$(2)="Create a new file"
: D$(3)="Replace a file"
: RETURN
2280 REM .?5
2290 IF C$(3)=HEX(02)THEN 110
: GOSUB '202("SPOOLER FILE NAME",51,8," ")
: D$(3)="key 8 byte file name"
: RETURN
2300 REM .?6
2310 IF C$(3)=HEX(02)THEN 110
: GOSUB '204("SPOOLER DISK ADDRESS",59,3,"B10")
: RETURN
2320 REM .?7
2330 IF C$(3)=HEX(02)THEN 110
: IF C$(4)<>HEX(02)THEN 110
: GOSUB '202("NUMBER OF SECTORS",20,5,"00500")
: D$(3)="key value 200 - 99999"
: D$(4)="200"
: D$(5)="99999"
: E=4
: RETURN
2390 REM %.'202 Get 1-n char field
2400 DEFFN'202(A$,C1,C2,D1$)
: E=0
2410 BIN(C$)=1
: IF STR(Z$,C1,C2)<>" "THEN 2420
: STR(Z$,C1,C2)=D1$
2420 D$(1)=STR(Z$,C1,C2)
: RETURN
2430 REM %.'203 Get and verify 3 char printer address
2440 DEFFN'203(A$,C1,C2,D1$)
: E=3
2450 D$(3)="Key valid printer addresses"
: D$(4)="215 216 217 218"
2460 GOTO 2410
2470 REM %.'204 Get and verify 3 char disk address
2480 DEFFN'204(A$,C1,C2,D1$)
: E=3
2490 D$(3)="Key valid disk addresses"
2500 STR(D$(),97)="310 320 330 340 350 360 370 D70 B10 B20 B30 B40 B50 B60 B70
D10 D11 C12 D13 D14 D15 D20 D21 D22 D23 D24 D25 D50 D51 D52 D53 D54 D55
D60 D61 D52 D63 D64 D65 D71 D82 D73 D74 D75"
: GOTO 2410