image of READY prompt

Wang2200.org

Listing of file='WHEEL' on disk='vmedia/games-droz01.wvd.zip'

# Sector 611, program filename = 'WHEEL'
0010 REM *WHEEL*
0020 REM .  THIS IS PROGRAM "WHEEL"
0030 REM .  IT SIMULATES A "WHEEL OF FORTUNE", WHICH
0040 REM .  STARTS OUT SPINNING FAST, AND GRADUALLY
0050 REM .  SLOWS DOWN AND STOPS.  THE WHEEL POINTER
0060 REM .  POINTS TO ONE OF THE NUMBERS FROM 1 TO 10
0070 Q1=1000
   : Q=0
0080 M1=0
0090 D=1.2
0100 K=0
0110 SELECT P0, PRINT 005
0120 PRINT HEX(03)
0130 PRINT ,"   !!!  WHEEL OF FORTUNE  !!!"
0140 PRINT
   : PRINT
0150 PRINT "PRESS ANY KEY TO START WHEEL SPINNING!"
0160 KEYIN F$,170,170
   : K=K+1
   : GOTO 160
0170 PRINT HEX(01)
0180 PRINT
   : PRINT
   : PRINT "****************************************************************"
0190 PRINT "     1     2     3     4     5     6     7     8     9    10"
0200 P= 1.03 +RND(K)*.025
0210 M=M+1
0220 IF M<=10 THEN 250
0230 M=1
0240 PRINT HEX(0D); TAB(62);
0250 PRINT HEX(0D); TAB(M*6-1); "^";
0260 D=D^P
0270 IF D>400 THEN 300
0280 FOR I=1 TO D
   :  NEXT I
0290 GOTO 210
0300 FOR I=1 TO 400
   : NEXT I
0310 PRINT
0320 FOR J=1 TO 5
0330 PRINT TAB(6*M-1); "."
0340 FOR Z=1 TO 25
0350 NEXT Z
0360 PRINT HEX(07)
0370 NEXT J
0380 PRINT
0390 PRINT "YOU PICKED ";M1;" AND THE WINNER IS ";M;" !!!"
0400 IF M1<>MTHEN 410
   : Q1=Q1+9*Q
   : GOTO 450
0410 Q1=Q1-Q
   : IF Q>=0THEN 450
0420 PRINT "YOU ARE BUSTED !!!!"
0430 INPUT "ENTER 1 TO RESTART GAME, 2 TO EXIT",Q
0440 ON QGOTO 20,10
   : GOTO 430
0450 PRINT "YOU NOW HAVE- $",Q1
0460 INPUT "PLACE YOUR BET (MAX $1000) ODDS 9-1",Q
0470 IF Q>Q1THEN 480
   : IF Q<0THEN 480
   : GOTO 490
0480 PRINT HEX(0C)
   : GOTO 460
0490 INPUT "PICK YOUR NUMBER (1-10)",M1
0500 IF M1<1THEN 510
   : IF M1>10THEN 510
   : GOTO 520
0510 PRINT HEX(0C)
   : GOTO 490
0520 GOTO 90