image of READY prompt

Wang2200.org

Listing of file='BLAKJACK' on disk='vmedia/games.wvd.zip'

# Sector 104, program filename = 'BLAKJACK'
0005 REM T.OLSEN  WANG LABS.
0010 %YOU HAVE $###,###,###.##       YOUR BET IS $#,###,###.##
0020 %YOU HAVE $###,###,###.##
0050 DIM A$52,B$52,C$52,D$52
0070 E$="A234567891JQK"
   : F$="10"
0080 C$="DDDDDDDDDDDDDHHHHHHHHHHHHHCCCCCCCCCCCCCSSSSSSSSSSSSS"
0090 B$="A234567891JQKA234567891JQKA234567891JQKA234567891JQK"
0100 PRINT HEX(03);"      WELCOME TO THE WANG CASINO BLACKJACK TABLE"
0110 GOSUB 1180
   : PRINT "NOT PROGRAMMED FOR:  PAIR SPLITTING"
   : PRINT
0150 M=0
   : INPUT "HOW MANY MINUTES DO YOU HAVE TO SPARE",M
0160 FOR P=1 TO M
   : D=RND(1)
   : NEXT P
0170 M=0
   : INPUT "HOW MANY DOLLARS ARE YOU WILLING TO PART WITH TONIGHT",M
0190 PRINT "TO SHUFFLE CARDS BET  0 DOLLARS"
0200 PRINT "KEY S.F.15 TO SEE RULES BEFORE ANY DEAL"
0210 PRINT "KEY S.F. 0 TO START NEW DEAL."
0220 GOSUB 930
   : REM SHUFFLE DECK
0230 DEFFN'0
   : REM NEW DEAL
0240 IF I<44THEN 245
   : B$=A$
   : C$=D$
   : GOSUB 930
   : GOSUB 1020
0245 IF M>=1THEN 250
   : PRINT "DO YOU WANT ME TO TAKE YOUR SHIRT TOO"
   : FOR I=1TO 1000
   : NEXT I
   : GOTO 100
0250 PRINTUSING 20,M;
   : B=0
   : INPUT "HOW MUCH IS YOUR BET",B
0255 IF B>MTHEN 250
   : IF B<>0THEN 260
   : GOSUB 930
   : GOTO 240
0260 IF B>=1THEN 270
   : PRINT "BETTING MINIMUM IS $1."
   : GOTO 250
0270 PRINT HEX(03);
   : PRINTUSING 10,M,B
0290 PRINT "PLAYERS CARDS",,"DEALER SHOWS"
0300 P6,P7,P8=0
0310 GOSUB 1020
   : P=K
   : P1=1
   : PRINT G$;STR(D$,I,1),,
0320 A=0
   : GOSUB 1120
0330 GOSUB 1020
   : D=K
   : REM DEALERS FIRST CARD
0340 A1=0
   : IF K<>1THEN 350
   : A1=1
0350 J$=G$
   : K$=STR(D$,I,1)
0360 PRINT "FACE DOWN CARD AND"
0370 GOSUB 1020
   : P1=P1+1
   : P=P+K
   : PRINT G$;STR(D$,I,1),,
   : REM PLAYRS 2ND
0380 GOSUB 1120
0390 GOSUB 1020
   : D=D+K
   : H$=G$
   : I$=STR(D$,I,1)
   : REM DEALERS 2ND
0400 PRINT H$;I$
   : IF K<>1THEN 410
   : A1=1
0405 REM 2 CARDS DEALT***ANALYSIS
0410 IF A1<>1THEN 450
   : IF D<>11THEN 450
0420 REM DEALER BLACKJACK
   : PRINT ,"DOWN CARD IS ",J$;K$
0430 IF A<>1THEN 440
   : IF P=11THEN 480
0440 PRINT "DEALER BLACKJACK  YOU LOSE"
   : M=M-B
   : GOTO 650
0450 IF A<>1THEN 500
   : IF P+10<>21THEN 540
0460 PRINT ,"DOWN CARD IS ",J$;K$
0470 IF A1<>1THEN 490
   : IF D<>11THEN 490
0480 PRINT "STANDOFF WE BOTH HAVE NATURALS"
   : GOTO 240
0490 PRINT "BLACKJACK YOU WIN AT 1.5 TO 1"
   : M=M+B*1.5
   : GOTO 650
0500 IF P<>11THEN 540
0510 PRINT "DOUBLE YOUR BET IF YOU WISH TO PLAY ELEVEN AND ONE"
0520 INPUT "DO YOU WISH TO PLAY 11 AND 1 (1=YES,2=NO)",Z
0522 IF Z=2THEN 600
   : IF Z<>1THEN 510
0530 GOSUB 1020
   : PRINT G$;STR(D$,I,1)
   : P=P+K
   : B=B+B
   : GOTO 800
0535 REM PLAYER PLAYOUT
0540 IF P=21THEN 690
   : IF A=1THEN 550
   : IF P<12THEN 600
0550 PRINT "YOU HAVE ";P;
   : IF A=0THEN 560
   : PRINT " OR ";P+10;
0560 Z=0
   : INPUT "DO YOU WANT A HIT (1=YES,2=NO)",Z
0570 IF Z=2THEN 690
0580 PRINT HEX(0C),,,,,HEX(0C);
0590 IF Z<>1THEN 560
0600 GOSUB 1020
0610 PRINT G$;STR(D$,I,1)
   : P=P+K
   : P1=P1+1
0620 GOSUB 1120
0630 IF P<=21THEN 670
   : PRINT "YOU BUSTED WITH A SCORE=";P
   : M=M-B
0640 PRINT ,,J$;K$;" IS DOWN CARD"
0650 REM
0660 IF M<0THEN 100
   : PRINT
   : GOTO 240
0670 IF P1<5THEN 540
   : PRINT "5 AND UNDER PAYS 2 TO 1, ETC."
   : GOTO 540
0685 REM PLAYER DEAL COMPLETE
0690 IF P1<5THEN 760
   : IF P1>5THEN 700
   : D=2
   : GOTO 740
0700 IF P1>6THEN 710
   : D=4
   : GOTO 740
0710 IF P1>7THEN 720
   : D=8
   : GOTO 740
0720 IF P1>8THEN 730
   : D=16
   : GOTO 740
0730 PRINT "NUMBER CARDS=";P1
   : STOP
0740 PRINT P1;" CARDS OF 21 OR UNDER";
0750 PRINT " PAYS ";D;" TO 1"
   : M=M+B*D
0755 PRINT ,,J$;K$;" IS DOWN CARD"
   : GOTO 650
0760 IF A=0THEN 770
   : IF P+10>21THEN 770
   : P=P+10
0770 IF P<>21THEN 810
   : IF P7<>3THEN 780
   : PRINT "3 SEVENS";
   : D=3
   : GOTO 750
0780 IF P6<>1THEN 810
   : IF P7<>1THEN 810
   : PRINT "6,7,8";
   : D=2
   : GOTO 750
0790 PRINT "3 SEVENS";
   : D=3
   : GOTO 750
0800 PRINT ,,J$;K$
0810 PRINT
   : PRINT "YOU HAVE";P,,"DEALER HAS"
0820 PRINT ,,J$;K$
   : PRINT ,,H$;I$
0830 REM DEALER PLAYOUT
0840 IF D>=17THEN 870
   : IF A1<>1THEN 850
   : IF D+10<17THEN 850
   : IF D+10>21THEN 850
   : D=D+10
   : GOTO 870
0850 FOR Z=1TO 200
   : NEXT Z
   : GOSUB 1020
   : PRINT ,,G$;STR(D$,I,1)
   : D=D+K
0855 FOR Z=1TO 200
0860 IF K<>1THEN 840
   : A1=1
   : GOTO 840
0870 PRINT ,,"DEALER HAS";D
0880 IF D<=21THEN 890
   : GOTO 910
0890 IF D<PTHEN 910
   : IF D=PTHEN 900
   : PRINT "YOU LOSE"
   : M=M-B
   : GOTO 650
0900 PRINT "STAND-OFF"
   : GOTO 650
0910 PRINT "YOU WIN"
   : M=M+B
   : GOTO 650
0930 PRINT
   : PRINT "CARDS BEING SHUFFLED"
   : A$=" "
0940 FOR X=1TO 52
0950 Y=INT(52*RND(1)+1)
   : IF STR(A$,Y,1)<>" "THEN 950
0970 STR(A$,Y,1)=STR(B$,X,1)
   : STR(D$,Y,1)=STR(C$,X,1)
0990 PRINT STR(B$,X,1);STR(C$,Y,1)
1000 PRINT HEX(0C)
1010 NEXT X
   : I=0
   : RETURN
1020 REM GET NEXT CARD FROM DECK
   : I=I+1
   : FOR J=1 TO 13
1030 IF STR(A$,I,1)<>STR(E$,J,1)THEN 1100
1040 IF STR(A$,I,1)="1"THEN 1080
1050 IF J<10THEN 1060
   : J=10
1060 K=J
   : G$=STR(A$,I,1)
   : GOTO 1090
1080 K=J
   : G$=F$
1090 J=13
1100 NEXT J
   : RETURN
1110 REM LOGIC FOR PLAYER***ACE   6,7,8  OR 7,7,7
1120 IF K<>1THEN 1130
   : A=1
   : RETURN
1130 IF K<>6THEN 1140
   : P6=P6+1
   : RETURN
1140 IF K<>7THEN 1150
   : P7=P7+1
   : RETURN
1150 IF K<>8THEN 1160
   : P8=P8+1
1160 RETURN
1170 DEFFN'15
1180 PRINT "THE WANG 2200 IS PERMANENT DEALER AND PLAYS ACCORDING TO HOYLE."
1190 PRINT ,"USING A FIFTY-TWO CARD DECK"
1200 PRINT "STAND-OFF MEANS DEALER AND PLAYER HAVE EQUAL VALUE."
1210 PRINT "DEALER STANDS ON 17 OR MORE POINTS.","     PAYOFF"
1220 PRINT ,"BLACKJACK OR NATURAL (2 CARDS=21)  1.5 TO 1"
1230 PRINT ,"5 CARDS TOTALLING 21 OR UNDER PAYS   2 TO 1"
1240 PRINT ,"6 CARDS TOTALLING 21 OR UNDER PAYS   4 TO 1"
1250 PRINT ,"7 CARDS TOTALLING 21 OR UNDER PAYS   8 TO 1"
1260 PRINT ,"THREE SEVENS                  PAYS   3 TO 1"
1270 PRINT ,"SIX,SEVEN,EIGHT               PAYS   2 TO 1"
1280 PRINT ,"CHOICE TO PLAY ELEVEN AND ONE (DOUBLE YOUR BET)"
1290 RETURN
1291 DEFFN'14
   : LOAD DC R"MENU"