image of READY prompt

Wang2200.org

Listing of file='CASINO ' on disk='vmedia/gamesall.wvd.zip'

# Sector 500, program filename = 'CASINO'
0005 REM "NEW CLEA CASINO"
   : DIM Q6$64
   : W0$="N"
0010 REM "DECAY1"
   : PRINT HEX(03);TAB(20);"---THE NEW CLEA CASINO---"
   : GOSUB '248(4,0,0)
   : PRINT "     MR. A. TOM MICK, GENERAL MANAGER OF THE NEW CLEA CASINO,"
0015 DIM Q6$64
   : W0$="N"
0200 PRINT "HAS, AT TIME  T=0,  DISCOVERED  100,000 RADIOACTIVE PLAYING"
0210 PRINT "CHIPS AT HIS TABLE. THEIR HALF-LIFE IS 10 MINUTES. EACH CHIP"
   : PRINT "TRANSMUTES SPONTANEOUSLY AND COMPLETELY IN A RANDOM FASHION."
   : PRINT
   : PRINT "     AT VARIOUS TIMES T, AFTER T=0, YOU MUST DETERMINE WITHIN"
0250 PRINT "A CERTAIN PERCENTAGE, HOW MANY CHIPS ARE LEFT."
   : PRINT
   : PRINT "     TO FURTHER THE INTEREST OF THE GAME, YOU WILL START WITH"
   : PRINT "$1,000 AND THE HOUSE WITH AN UNSPECIFIED AMOUNT.  HALF THE"
0290 PRINT "MONEY YOU HAVE WILL RIDE ON EACH GUESS YOU TAKE.  LET'S SEE"
   : PRINT "IF YOU CAN BREAK THE HOUSE BEFORE THE CHIPS RUN OUT.";
   : GOSUB '243("KEY RETURN (EXEC) TO CONTINUE",1)
   : GOSUB '248(4,0,12)
   : PRINT
   : PRINT "THE HOUSE OFFERS THE FOLLOWING ODDS:"
0350 PRINT "     2) 2 TO 1 ODDS FOR GUESSING WITHIN 20 PERCENT"
   : PRINT "     4) 4 TO 1 ODDS FOR GUESSING WITHIN 10 PERCENT"
   : PRINT "     8) 8 TO 1 ODDS FOR GUESSING WITHIN  5 PERCENT."
0380 GOSUB '245("GIVE ME YOUR LUCKY NUMBER",2,0)
   : FOR I=1TO Q9
   : T3=RND(RND(Q9))
   : NEXT I
0420 IF W0$="N"THEN 450
   : GOSUB '200
   : GOTO 460
0450 GOSUB '248(5,0,6)
0460 PRINT
   : PRINT
   : PRINT "   $$ MONEY $$         TIME   GUESS         NO. OF CHIPS LEFT"
   : PRINT "   YOURS    HOUSE     (MIN)    NO.   ODDS    GUESSED   ACTUAL"
0500 % #######   #######    ###.#    ##
0510 %#      #######  #######
0520 G,D,A,B,T=0
   : Y=1000
0540 C=0
   : IF ABS(G-D)<500THEN 580
   : G=5
   : D=2
0580 B=B+1
   : FOR I=1TO 3+A+ABS(G-D)
   : T3=INT(100*RND(-Y))/10
   : NEXT I
   : T=T+T3
   : D=INT(100000*EXP(-.0693*T))
   : IF D=0THEN 1040
   : IF W0$="N"THEN 680
   : GOSUB '200
   : GOTO 690
0680 GOSUB '248(14-(1-(B/5-INT(B/5)))*5,0,2)
0690 PRINTUSING 500,Y,1.001E+6-Y,T,B
0700 GOSUB '245("WHAT ODDS DO YOU WANT (2=20%:4=10%:8=5%)",1,0)
   : A=Q9
   : IF A=2THEN 800
   : IF A=4THEN 800
   : IF A=8THEN 800
   : GOSUB '248(3,0,0)
   : PRINT "SORRY PAL, WE DONT OFFER THOSE ODDS."
   : IF C=1THEN 1020
   : C=1
   : GOTO 700
0800 GOSUB '245("HOW MANY CHIPS ARE LEFT",6,0)
   : G=Q9
0820 IF W0$="N"THEN 860
   : GOSUB '200
   : PRINT TAB(38);
   : GOTO 870
0860 GOSUB '248(14-(1-(B/5-INT(B/5)))*5,39,2)
0870 PRINTUSING 510,A,G,D
   : GOSUB '248(3,0,4)
   : T=10*B
   : IF ABS(D-G)<=D/A*.4THEN 950
   : Y=INT(Y-Y/2)
   : IF Y<=50THEN 1020
   : PRINT "TOO BAD, YOU LOST. TRY AGAIN."
   : GOTO 540
0950 Y=INT(Y+A*Y/2)
   : IF 1E+6-Y<1THEN 1070
   : IF Y>200000THEN 1000
0980 PRINT "YOU WON. TRY AGAIN."
   : GOTO 540
1000 PRINT "YOU CAN BREAK THE HOUSE IF YOU TRY A LONG SHOT."
   : GOTO 540
1020 PRINT "IT SEEMS YOU JUST CANT GET THE HANG OF IT. SAVE YOUR BREAD."
   : GOTO 1140
1040 PRINT "OOOOPS... SORRY PAL, THE LAST CHIP JUST DISINTEGRATED."
1050 PRINT "THE HOUSE IS CLOSED."
   : GOTO 1140
1070 PRINT "YOU BROKE THE HOUSE. YOU NEEDED ONLY ";
   : IF B>5THEN 1110
   : PRINT "THE MINIMUM NUMBER OF GUESSES."
   : GOTO 1120
1110 PRINT B;"GUESSES."
1120 PRINT "CONGRATULATIONS."
   : PRINT "YOU MUST KNOW A LOT ABOUT RADIOACTIVITY AND THINGS."
1140 GOSUB '243("KEY RETURN (EXEC) TO CONTINUE",0)
   : GOSUB '248(4,0,12)
   : PRINT "    THANKS FOR PLAYING......DONT SPEND IT ALL IN ONE PLACE"
   : PRINT
   : PRINT "     * * * * * * * * * * * * * * * * * * * * * * * * * * *"
   : PRINT "     *";TAB(36);"CHECK NO.";B+D;TAB(57);"*"
1200 PRINT "     *";TAB(36);"DATE: ----------19--";TAB(57);"*"
   : PRINT "     *";TAB(57);"*"
   : PRINT "     *  PAY TO THE ORDER OF     C A S H     $";Y;TAB(57);"*"
   : PRINT "     *";TAB(29);"-------------------------";TAB(57);"*"
   : PRINT "     *  THE NEW CLEA CASINO";TAB(40);"A  TOM MICK      *"
1250 PRINT "     *";TAB(40);"GENERAL MANAGER  *"
   : PRINT "     * * * * * * * * * * * * * * * * * * * * * * * * * * *"
1260 GOSUB '243("WOULD YOU LIKE TO PLAY THE GAME AGAIN (Y/N)",1)
   : PRINT HEX(03);TAB(20);"---THE NEW CLEA CASINO---"
   : IF Q6$="Y"THEN 380
   : IF Q6$<>"N"THEN 1260
1300 STOP
8710 Q6=3
   : GOTO 9490
8790 DEFFN'242(W0,Q6$)
   : IF W0<=0THEN 9680
   : IF W0=1THEN 8840
   : STR(Q6$,2)=STR(Q6$,1,W0-1)
8840 PRINT Q6$;
   : RETURN
8870 DEFFN'243(Q6$,Q0)
   : GOSUB 9330
8900 SELECT CO 205
   : Q6$=" "
   : INPUT Q6$
   : IF Q0=0THEN 9430
   : IF LEN(Q6$)<=Q0THEN 9430
   : GOSUB 9290
8970 DEFFN'244(Q0)
   : GOSUB 9400
   : GOSUB 9360
   : GOTO 8900
9020 DEFFN'245(Q6$,Q2,Q3)
   : Q0=ABS(Q2)+Q3+1
9050 GOSUB 9330
9060 GOSUB '242(ABS(Q2)+2,HEX(09))
   : PRINT "/"
   : GOSUB 9400
   : SELECT CO 205
   : Q9,W0=-1E-99
   : INPUT Q9
   : IF W0=Q9THEN 9160
   : IF Q9>=0THEN 9240
   : IF Q2<=0THEN 9240
9160 GOSUB 9290
9180 DEFFN'246(Q2,Q3)
   : Q0=ABS(Q2)+Q3+1
   : GOSUB 9400
   : GOSUB 9360
   : GOTO 9060
9240 IF ABS(Q9)>=10^ABS(Q2)THEN 9160
   : W0=ABS(Q9*10^Q3)
   : IF INT(W0)<>W0THEN 9160
   : GOTO 8710
9290 GOSUB 8710
   : PRINT "RE-ENTER"
   : RETURN
9330 GOSUB 9680
   : PRINT HEX(010A);STR(Q6$,1);
9360 GOSUB 9680
   : GOSUB '242(Q0+2,"-")
   : PRINT TAB(64)
9400 PRINT HEX(010A0A)
   : RETURN
9430 PRINT HEX(0A);TAB(64)
   : GOTO 9680
9450 Q6=0
9490 Q7=0
   : Q8=1
9520 DEFFN'248(Q6,Q7,Q8)
   : GOSUB 9680
   : IF Q8<1THEN 9640
   : GOSUB 9640
   : SELECT PRINT 205
   : Q6$=" "
   : PRINT STR(Q6$,Q7+1)
   : IF Q8<2THEN 9640
   : FOR W0=2TO Q8
   : PRINT HEX(0A);STR(Q6$,1)
   : NEXT W0
9640 PRINT HEX(01)
   : GOSUB '242(Q7,HEX(09))
   : GOSUB '242(Q6,HEX(0A))
9680 SELECT PRINT 005(64),CO 005
   : RETURN
9720 DEFFN'31
   : W0$="N"
   : RETURN
9770 DEFFN'15
   : W0$="Y"
   : RETURN
9820 DEFFN'200
9830 SELECT PRINT 015(80)
   : IF W9$="T"THEN 9880
   : SELECT PRINT 211(80)
   : IF W9$="P"THEN 9880
   : SELECT PRINT 215(80)
9880 RETURN