image of READY prompt

Wang2200.org

Listing of file='12A ' on disk='vmedia/glbr_22.wvd.zip'

# Sector 629, program filename = '12A'
0010 DIM D(50),V(25),T(25)
0020 PRINT "NUMBER OF ROWS?"
   : INPUT R1
0030 PRINT "NUMBER OF COLUMNS?"
   : INPUT C1
0040 Y=R1*C1
0050 PRINT "INPUT CONTINGENCY TABLE 4 ELEMENTS/LINE"
0060 FOR R=1 TO Y STEP 4
0070 INPUT D(R),D(R+1),D(R+2),D(R+3)
0075 NEXT R
0080 G=0
   : R=1
0090 FOR I=1 TO R1
0100 FOR J=1 TO C1
   : T(I)=T(I)+D(R)
   : R=R+1
   : NEXT J
0110 G=G+T(I)
   : NEXT I
0120 FOR I=1 TO C1
   : FOR J=I TO Y STEP C1
0130 V(I)=V(I)+D(J)
0140 NEXT J
   : NEXT I
0150 C2=0
0160 PRINT "                 FOR EACH CELL"
0170 PRINT "OBSERVED VALUE  EXPECTED VALUE  CHI^2 CONTRIBUTION"
0180 FOR C=1 TO C1
   : PRINT "              COLUMN";C
0190 FOR R=1 TO R1
0200 E=T(R)*V(C)/G
   : I=C+(R-1)*C1
   : H=(D(I)-E)^2/E
   : C2=C2+H
0210 PRINT D(I),E,H
   : NEXT R
0220 PRINT
   : NEXT C
0230 PRINT
   : PRINT "CHI-SQUARE=";C2
0240 PRINT
   : PRINT "DEGREES OF FREEDOM";(R1-1)*(C1-1)
0250 END