image of READY prompt

Wang2200.org

Listing of file='44' on disk='vmedia/glbr_22.wvd.zip'

# Sector 64, program filename = '44'
0010 DIM Y(32),A(15),B(15)
0015 PRINT "INPUT N"
   : INPUT N
0020 PRINT "INPUT VALUES OF FUNCTION (4/LINE)"
0025 FOR I=0 TO INT((N+2)/2)-1
0030 INPUT Y(4*I+1),Y(4*I+2),Y(4*I+3),Y(4*I+4)
   : NEXT I
0035 PRINT "INPUT MAXIMUM HARMONIC TO BE CALCULATED (<=N)"
   : INPUT M
0040 PRINT
   : PRINT "HARMONIC        COSINE COEFF.  SINE COEFF."
0045 C3=2/(2*N+1)
   : K1=3.1415927*C3
0050 S1=SIN(K1)
   : C1=COS(K1)
0055 J,C=1
   : S=0
   : W=Y(1)
0060 U1,U2=0
   : I=2*N+1
0065 U3=Y(I)+2*C*U1-U2
   : U2=U1
   : U1=U3
0070 I=I-1
   : IF I>1 THEN 65
0075 A(J)=C3*(W+C*U1-U2)
   : IF J<>1 THEN 85
0080 A(1)=A(1)*.5
0085 B(J)=C3*S*U1
   : PRINT J-1,A(J),B(J)
0087 IF J>=M+1 THEN 100
0090 Q=C1*C-S1*S
   : S=C1*S+S1*C
   : C=Q
0095 J=J+1
   : GOTO 60
0100 PRINT
0110 PRINT "INPUT X-VALUE TO BE EVALUATED. TO END PROGRAM INPUT 99999"
0120 INPUT W
   : IF W=99999 THEN 999
0130 I=0
0140 FOR J=1 TO M+1
   : I=I+A(J)*COS((J-1)*W)+B(J)*SIN((J-1)*W)
   : NEXT J
0150 PRINT "Y=";I
   : PRINT
   : PRINT "INPUT X"
   : GOTO 120
0999 END