image of READY prompt

Wang2200.org

Listing of file='HOCKEY' on disk='vmedia/more_games.wvd.zip'

# Sector 658, program filename = 'HOCKEY'
0010 REM *HOCKEY*
   : LOAD DC T#6,"GAMES"
0330 DIM A$(16,66)1,B$(16,66)1,L$1,T$(2)10,S$(1)10,G$1,S(2),R$1,B(2)
   : T2=1
   : GOTO 2580
0370 S(1),S(2)=0
0390 DEFFN'1
0400 T=1000
   : B(1),B(2)=0
   : L,R=8
0430 Y=7
   : X=32
   : B$(Y,X)="0"
   : $GIO/005(4001A2004001,B$)B$()
   : I=INT(4*RND(T))
   : ON I+1GOTO 510,530,560,580
0510 X1=1
   : GOTO 540
0530 X1=-1
0540 Y1=1
   : GOTO 630
0560 X1=-1
   : GOTO 590
0580 X1=1
0590 Y1=-1
   : I=5
0630 I=INT(I*RND(T))
   : ON I+1GOTO 730,710,690,670
   : Y1=0
   : GOTO 730
0670 X1=10*X1
   : GOTO 830
0690 X1=5*X1
   : GOTO 830
0710 X1=4*X1
   : GOTO 830
0730 X1=3*X1
0750 T=T-1
   : IF T=0THEN 2410
   : T1=INT(T/200)
   : CONVERT T1TO S$(1),(##)
   : MAT COPY S$()<1,2>TO A$()<35,2>
   : T1=60*(T/200-T1)
   : CONVERT T1TO S$(1),(##)
   : MAT COPY S$()<1,2>TO A$()<42,2>
0830 Y=Y+Y1
   : X=X+X1
   : IF Y1<0THEN 1430
   : IF X1<0THEN 1160
   : IF X<64THEN 1110
   : X=64
   : I=4
   : IF Y=RTHEN 950
   : IF Y<>R+1THEN 1020
0950 SELECT P2
   : PRINT HEX(010A0A);,,,"SHOT BLOCKED"
   : SELECT P
   : B(1)=B(1)+1
   : X=61
   : GOTO 2010
1020 IF Y>11THEN 2010
   : IF Y<7THEN 2010
   : SELECT P3
   : PRINT HEX(010A0A);,,,"*** SCORE ***"
   : SELECT P
   : S=1
   : GOTO 2330
1100 I=4
1110 IF Y<15THEN 2040
   : Y=15
   : I=3
   : GOTO 1860
1160 IF X>1THEN 1380
   : X=1
   : I=4
   : IF Y=LTHEN 1230
   : IF Y<>L+1THEN 1300
1230 SELECT P2
   : PRINT HEX(010A0A);"SHOT BLOCKED"
   : SELECT P
   : B(2)=B(2)+1
   : X=4
   : GOTO 1710
1300 IF Y>11THEN 1710
   : IF Y<7THEN 1710
   : SELECT P3
   : PRINT HEX(010A0A);"*** SCORE ***"
   : SELECT P
   : S=0
   : GOTO 2330
1380 IF Y<15THEN 2040
   : Y=15
   : I=3
   : GOTO 1560
1430 IF X1<0THEN 1750
   : IF X<64THEN 1680
   : X=64
   : I=4
   : IF Y=RTHEN 1510
   : IF Y<>R+1THEN 1600
1510 SELECT P2
   : PRINT HEX(010A0A);,,,"SHOT BLOCKED"
   : SELECT P
   : B(1)=B(1)+1
   : X=61
1560 Y1=-1
   : X1=-1
   : GOTO 630
1600 IF Y>10THEN 1560
   : IF Y<6THEN 1560
   : SELECT P3
   : PRINT HEX(010A0A);,,,"*** SCORE ***"
   : SELECT P
   : S=1
   : GOTO 2330
1680 IF Y>2THEN 2040
   : Y=2
   : I=3
1710 Y1=1
   : X1=1
   : GOTO 630
1750 IF X>1THEN 1980
   : X=1
   : I=4
   : IF Y=LTHEN 1810
   : IF Y<>L+1THEN 1900
1810 SELECT P2
   : PRINT HEX(010A0A);"SHOT BLOCKED"
   : SELECT P
   : B(2)=B(2)+1
   : X=4
1860 Y1=-1
   : X1=1
   : GOTO 630
1900 IF Y>10THEN 1860
   : IF Y<6THEN 1860
   : SELECT P3
   : PRINT HEX(010A0A);"*** SCORE ***"
   : SELECT P
   : S=0
   : GOTO 2330
1980 IF Y>2THEN 2040
   : Y=2
   : I=3
2010 Y1=1
   : X1=-1
   : GOTO 630
2040 GOSUB 2990
   : B$(Y,X)="0"
   : $GIO/005(4001A2004001,B$)B$()
   : KEYIN G$,830,2120
   : GOTO 750
2110 B$(L,4),B$(L+1,4),B$(R,61),B$(R+1,61)=" "
2120 IF G$=HEX(00)THEN 2290
   : IF G$=HEX(01)THEN 2250
   : IF G$=HEX(0E)THEN 2210
   : IF G$<>HEX(0F)THEN 2040
   : IF R>12THEN 2040
   : R=R+1
   : GOTO 2040
2210 IF R<4THEN 2040
   : R=R-1
   : GOTO 2040
2250 IF L>12THEN 2040
   : L=L+1
   : GOTO 2040
2290 IF L<4THEN 2040
   : L=L-1
   : GOTO 2040
2330 S(S+1)=S(S+1)+1
   : CONVERT S(2)TO S$(1),(###)
   : MAT COPY S$()<1,3>TO A$()<12,3>
   : CONVERT S(1)TO S$(1),(###)
   : MAT COPY S$()<1,3>TO A$()<61,3>
   : GOSUB 2990
   : GOTO 430
2410 PRINT HEX(030A0A);,"THIS IS THE END OF PERIOD";T2
   : PRINT
   : PRINT ,"THE SCORE IS:  ";T$(1);S(1);"   ";T$(2);S(2)
   : PRINT
   : PRINT ,"SHOTS ON GOAL: ";T$(1);B(1)+S(1);"   ";T$(2);B(2)+S(2)
   : T2=T2+1
   : PRINT HEX(0A0A0A);
2480 IF T2>3THEN 2550
   : CONVERT T2TO S$(1),(#)
   : MAT COPY S$()<1,1>TO A$()<26,1>
   : GOSUB 2990
   : PRINT "KEY RETURN(EXEC) TO CONTINUE"
2530 KEYIN G$,400,400
   : GOTO 2530
2550 STOP "END OF GAME"
2570 DEFFN'0
2580 INIT(20)A$()
   : FOR I=1TO 15
   : A$(I,65)=HEX(0D)
   : A$(I,66)=HEX(0A)
   : IF I<3THEN 2660
   : IF I>14THEN 2660
   : A$(I,1),A$(I,21),A$(I,43),A$(I,64)="I"
   : A$(I,32)="*"
2660 NEXT I
   : FOR I=4TO 61
   : A$(2,I),A$(15,I)="-"
   : NEXT I
   : FOR I=6TO 11
   : A$(I,2),A$(I,63)="*"
   : NEXT I
   : A$(6,1),A$(6,64),A$(11,1),A$(11,64)="*"
   : A$(2,3),A$(3,1),A$(14,64),A$(15,62)=HEX(2F)
2760 A$(2,62),A$(3,64),A$(14,1),A$(15,3)=HEX(5C)
   : S$(1)="PERIOD"
   : CONVERT T2TO STR(S$(1),8,1),(#)
   : MAT COPY S$()<1,8>TO A$()<19,8>
   : S$(1)="TIME:"
   : MAT COPY S$()<1,5>TO A$()<29,5>
   : S$(1)="MIN    SEC"
2830 MAT COPY S$()<1,10>TO A$()<38,10>
   : L$=HEX(5D)
   : R$=HEX(5B)
   : L,R=8
   : PRINT HEX(03);,"WANG 2200T HOCKEY GAME"
   : INPUT "ENTER TEAM NAME ON THE RIGHT",T$(1)
   : STR(T$(1),9,2)=" ="
   : INPUT "ENTER TEAM NAME ON THE LEFT",T$(2)
2930 STR(T$(2),9,2)=" ="
   : MAT COPY T$()<1,10>TO A$()<51,10>
   : MAT COPY T$()<11,10>TO A$()<2,10>
   : GOSUB 2990
   : GOTO 370
2990 MAT COPY A$()TO B$()
   : B$(L,4),B$(L+1,4)=L$
   : B$(R,61),B$(R+1,61)=R$
   : RETURN