image of READY prompt

Wang2200.org

Listing of file='@PSTAT' on disk='vmedia/mvp-boot-3.1.0.wvd.zip'

# Sector 149, program filename = '@PSTAT'
0010 REM % Prog = @PSTAT  By PLS (Modified by TBO)   Date = 07/16/87   Rel. 3.
     1
0015 REM % (c) Copr. Wang Laboratories, Inc. 1985, 1986
0020 DIM P$29,P1$2,P2$80,P$(16)29,Q$1,R$2
   : P2$=ALL("-")
   : P$=$PSTAT(1)
   : UNPACK(#.#)STR(P$,10,1) TO R
0030 PRINT HEX(03060E);"     ***** Partition Status - (c) Copr. Wang Laborator
     ies, Inc. 1986 *****"
   : PRINT TAB(24);
   : IF STR(P$,9,1)="M" THEN PRINT "M";
   : PRINT "VP Release";R;"     Partition";#PART
0040 PRINT "#PART  USER-MSG   BANK  SPACEK PRGM #TERM    @NAME    ERR    TEXT
     @P DATA    I/O"
   : PRINT P2$
0050 PRINT AT(22,0,80);"Press SF'0 to attach terminal to a different partition
     .";
   : B=1
0051 PRINT AT(23,0);"Press 'FN' or 'TAB' to return to menu.";
0060 REM %GET & DISPLAY STATUS OF EACH PARTITION--
   : PRINT AT(4,0);
   : FOR P=1 TO 16
   : P$=$PSTAT(P)
   : ERRORP=ERR
   : P=16
   : GOTO 140
0070 PRINT "-";
   : IF P$=P$(P) THEN 130
0080 CONVERT P TO P1$,(##)
   : UNPACK(##) STR(P$,15,1) TO T
0090 REM ELIMINATE UNPRINTABLE CHARACTERS
   : $TRAN(STR(P$,,8),"................")
   : $TRAN(STR(P$,17,8),"................")
0100 IF T=#TERM THEN PRINT HEX(0E);
0110 PRINT P1$;"    ";STR(P$,,8);"   ";
   : IF B=16OR VAL(STR(P$,11))=B THEN 115
   : PRINT BOX(0,3);
   : B=VAL(STR(P$,11))
0115 PRINTUSING " ##    ",VAL(STR(P$,11,1));
   : PRINT HEXOF(STR(P$,12,1));".";HEXOF(STR(P$,13,1));"   ";
0120 PRINT STR(P$,14,1);"   ";HEXOF(STR(P$,15,1));"-";
   : IF T=#TERM OR T=0 AND STR(P$,16,1)="W" THEN PRINT HEX(020404000E);
   : PRINT STR(P$,16,1);HEX(020402000F);
   : IF T=#TERM THEN PRINT HEX(0E);
   : PRINT "   ";STR(P$,17,8);"   ";HEXOF(STR(P$,25,1));"     ";HEXOF(STR(P$,2
     6,1));"  ";HEXOF(STR(P$,27,1));"  ";HEXOF(STR(P$,28,1));"     ";HEXOF(STR
     (P$,29,1));
0130 $BREAK2
   : PRINT HEX(0D);" "
0140 P$(P)=P$
   : NEXT P
   : PRINT P2$
   : B=8
0150 REM %RELEASE?--
   : KEYIN Q$,60,160
   : GOTO 60
0160 IF Q$<>HEX(00) AND Q$ <> HEX(7E) AND Q$ <> HEX(7F)  THEN 60
   : IF Q$ <> HEX(00) THEN 161
   : P$()=" "
   : GOTO 180
0161 DEFFN'126
0162 DEFFN'127
   : LOAD RUN
0170 P=ERR
   : PRINT AT(23,0);"CANNOT ATTACH TO PARTITION ";R$;" SINCE IT IS ASSIGNED TO
      ANOTHER TERMINAL.";
0180 REM %RELEASE TERMINAL
   : PRINT AT(22,0,79);
   : PRINT "Which partition is terminal";#TERM;"to be attached to (#PART)?";
   : R$=" "
   : LINPUT ?-R$
   : IF R$=" " THEN 30
   : CONVERT R$ TO P
   : ERRORGOTO 180
0190 IF P<1 OR P>16 OR INT(P)<>P THEN 180
   : P$=$PSTAT(P)
   : ERRORGOTO 180
0200 UNPACK(##) STR(P$,15,1) TO T
   : IF T<>#TERM AND T<>0 THEN 170
0210 REM %RELEASE PARTITION
   : PRINT AT(22,0,80);
   : PRINT "Do you want to release partition";#PART;"for another terminal (Y o
     r N)?";
   : Q$=" "
   : LINPUT ?-Q$
   : ON POS("YyNn"=Q$) GOTO 220,220,220,220
   : GOTO 210
0220 REM %RELEASE
   : PRINT HEX(0D03);
   : $RELEASE TERMINAL TO P
   : IF Q$="Y" OR Q$="y" THEN $RELEASE PART
   : LOAD T"START"
   : GOTO 30
   : REM LOAD T/xyz,"filename" should replace previous GOTO if you want to loa
     d a program into the released partition.