image of READY prompt

Wang2200.org

Listing of file='TBO.XDC' on disk='vmedia/toolbox.wvd.zip'

# Sector 1008, program filename = 'TBO.XDC'
0010 REM "TBO.XDC" 06/19/82 T.OLSEN  EXAMINE CAT.SECTORS
0015 IF D1$(10)=" "THEN LOAD T#0,"TBODISKS"8000,8800 BEG 20
0020 DIM D$(16)16, Z$(128)2,S$1
   : INIT(00)Z0$
0030 REM %.Set-up
0040 SELECT PRINT 005(64)
   : PRINT HEX(03);"Disk Examination"
0050 GOSUB '98
   : SELECT #1<D1$(D9)>
0080 PRINT " 1 = Examine Catalog"
   : PRINT " 2 = Examine disk"
   : PRINT " 3 = Search Disk for programs"
0090 INPUT " KEY DIGIT (EXEC) FOR FUNCTION DESIRED",M
0100 SELECT PRINT 005(64)
   : H=0
   : INPUT "HARD COPY  1=YES",H
0110 IF H=0THEN 120
   : SELECT PRINT 215(64)
0120 ON M GOTO 140,150,510
   : GOTO 90
0130 REM %.Examine disk
0140 GOSUB 670
   : E=E9
   : GOTO 160
0150 C0=0
   : GOSUB 670
   : S=E9+1
   : E=0
   : INPUT "START SECTOR, END SECTOR",S,E
   : IF E>STHEN 160
   : E=S+99
0160 A=S
   : FOR S1=STO E
0170 PRINT HEX(03);"START SECTOR=";S;"  END SECTOR=";E;
0180 PRINT "     SECTOR=",A,
0190 DATA LOAD BA T#1,(A,A)Z$()
   : MAT COPY Z$()TO D$()
0200 FOR Z=1TO 16
   : IF Z$(Z)<>Z0$THEN 210
   : NEXT Z
   : PRINT "IS 0000"
   : GOTO 240
0210 Z=16
   : NEXT Z
   : HEXPRINT Z$()
0230 IF M>1THEN 232
   : GOSUB 290
   : GOTO 250
0232 GOSUB 440
   : REM /examine non-cat sector
0240 PRINT
0250 IF H=1THEN 260
   : INPUT "KEY RETURN TO CONTINUE",Z
0260 NEXT S1
0270 GOTO 40
0280 REM %.SR.examine catalog sector
0290 Z=1
   : PRINT "   S---.SS..ES.--N A M E    Catalog sector"
0300 IF Z$(Z)=HEX(0000)THEN 430
0310 S$=STR(Z$(Z),1,1)
0320 IF S$<>HEX(21)THEN 330
   : PRINT "XS";
   : GOTO 370
0330 IF STR(Z$(Z),1,2)<>HEX(1080)THEN 340
   : PRINT "AP";
0340 IF STR(Z$(Z),1,2)<>HEX(1180)THEN 350
   : PRINT "SP";
0350 IF STR(Z$(Z),1,2)<>HEX(1000)THEN 360
   : PRINT "AD";
0360 IF STR(Z$(Z),1,2)<>HEX(1100)THEN 370
   : PRINT "SD";
0370 PRINT TAB(3);
   : FOR Z1=ZTO (Z+2)
   : HEXPRINT Z$(Z1);
   : NEXT Z1
   : PRINT "  ";
0380 FOR Z1=(Z+4)TO (Z+7)
   : PRINT Z$(Z1);
   : NEXT Z1
0390 IF Z$(Z)=HEX(1080)THEN 410
0400 IF Z$(Z)=HEX(1000)THEN 410
   : PRINT
   : GOTO 420
0410 PRINT TAB(28);"SECTOR START=";(VAL(Z$(Z+1),2));TAB(48);"END=";(VAL(Z$(Z+1
     ),2))
0420 Z=Z+8
   : IF Z<128THEN 300
0430 RETURN
0435 REM .SR.examine non-cat sector
0440 S$=STR(Z$(1),1,1)
   : AND (S$,F0)
   : IF A>E9THEN 450
   : PRINT "Cat area"
   : GOTO 490
0450 IF S$<>HEX(40)THEN 460
   : F$=STR(D$(1),2,8)
   : PRINT F$;" Program header"
   : C0=1
   : GOTO 490
0460 IF S$<>HEX(00)THEN 470
   : PRINT F$;" Program data line ";
   : HEXPRINT Z$(2)
   : GOTO 490
0470 IF S$<>HEX(20)THEN 480
   : PRINT F$;" Program trailer"
   : F$=" "
   : IF C0<>1THEN 490
   : C0=0
   : RETURN
0480 PRINT "Data file data  "
0482 IF STR(D$(1),1,4)<>HEX(8101BE00)THEN 484
   : PRINT "T.C. format"
   : GOTO 490
0484 IF STR(D$(1),1,4)<>HEX(8101BEF0)THEN 490
   : PRINT "T.C. format EOF"
   : GOTO 490
0490 IF C0>0THEN 495
   : PRINT "?";
0495 PRINT
   : RETURN
0500 DEFFN'1
0510 A=0
   : E=1023
   : INPUT "START SECTOR, END SECTOR",A,E
0520 DATA LOAD BA T#1,(A,A)D$()
0530 S$=D$(1)
   : IF S$=HEX(40)THEN 550
0540 IF A<E THEN 560
   : STOP "END OF JOB"
0550 PRINT "AT ";A-1;" ";STR(D$(1),2,8)
0560 KEYIN S$,570,570
   : GOTO 520
0570 PRINT "CLEARP AND  LOAD DA T #1, (ss,A)  to recover  else key (EXEC)"
0580 KEYIN S$,520,520
   : GOTO 580
0660 REM .Find cat end
0670 DATA LOAD BA T#1,(0,E)D$()
   : AND (STR(D$(1),1,1),7F)
   : S=VAL(STR(D$(1),1,1))
   : E9=VAL(STR(D$(1),2,1))-1
   : RETURN