image of READY prompt

Wang2200.org

Listing of file='3741080A' on disk='vmedia/3741_util.wvd.zip'

# Sector 165, program filename = '3741080A'
0010 REM 3741080A,02.00(12/1/78),THIS PROGRAM IS A PRODUCT OF WANG LABS. INC.
3000 % THIS MUST BE STATEMENT 3000
3010 DIM Y$(2)64,Y1$(2)64,B$1,C$16,N$64,M$21
3020 % SECTOR #### (##/##)
3050 DEFFN'15
   : PRINT HEX(03);,"DUMP 3741 SECTOR(S)."
   : PRINT "MOUNT DISK PLATTER."
   : GOSUB '254
   : GOSUB '200("1","1950",4,0,"ENTER THE ADDRESS OF THE STARTING SECTOR.",1)
   : X1=Q9
3110 GOSUB '200("1","1950",4,0,"ENTER THE ADDRESS OF THE ENDING SECTOR.",1)
   : X2=Q9
   : IF X1<=X2THEN 3160
   : GOSUB '255
   : GOTO 3110
3160 GOSUB '200(" "," ",1,0,"ARE YOUR SECTORS WRITTEN IN EBCDIC? (Y/N)",2)
   : D$=Q6$
   : IF D$="Y"THEN 3240
   : IF D$="N"THEN 3220
   : GOSUB '255
   : GOTO 3160
3220 D1$="ASCII"
   : GOTO 3250
3240 D1$="EBCDIC"
3250 X=0
   : CONVERT X1TO B1$,(####)
   : CONVERT X2TO B2$,(####)
   : C$=HEX(30313233343536373839414243444546)
   : Z0,Z1=X1
   : Z2=X2
   : Z5=128
   : Z6=9
   : PRINT HEX(03);,"DUMPING SECTORS",X1;"-";X2
   : PRINT HEX(010D0A0D0A0D0A0D0A)
3390 IF Z0<=X2THEN 3410
   : Z0=X2
3410 GOSUB '197
   : MAT COPY Z$()TO Y$()
   : Z0=Z0-1
   : IF D$="Y"THEN 3470
   : GOSUB '197
   : GOTO 3510
3470 GOSUB '181
3510 $TRAN(Z$(),X9$())
   : MAT COPY Y$()TO Y1$()
   : FOR I=1TO 2
   : ROTATE(Y1$(I),4)
   : NEXT I
   : $TRAN(Y1$(),C$)0F
   : $TRAN(Y$(),C$)0F
   : GOTO 3710
3630 KEYIN B$,3640,3650
3640 GOTO 3630
3650 ON VAL(B$)-6GOTO 4000,4060,3710,4280,4100,3390,4160,4220,3050
   : IF B$=HEX(04)THEN 4030
   : IF B$=HEX(05)THEN 4520
   : IF VAL(B$)=31THEN 3910
   : GOTO 3630
3710 IF Q$=HEX(08)THEN 3830
   : PRINT HEX(030A);TAB(19);"INPUT OPTION - READ ";D1$
   : PRINT HEX(0D0A0D0A0D0A);
   : PRINTUSING 3020,Z0-1,INT((Z0-2)/26),Z0-1-INT((Z0-2)/26)*26
3750 $GIO/005(A000400D400A,A$)Z$()<1,64>
   : PRINT Y1$(1)
   : PRINT Y$(1)
   : PRINT HEX(0D0A)
   : $GIO/005(A000400D400A,A$)Z$()<65,64>
   : PRINT Y1$(2)
   : PRINT Y$(2)
   : GOTO 3630
3830 PRINT HEX(030A0D0A0D0A0D0A);
   : PRINTUSING 3020,Z0-1,INT((Z0-2)/26),Z0-1-INT((Z0-2)/26)*26;
   : PRINT "  ERROR - ";
   : HEXPRINT STR(Q$,1,1)
   : GOTO 3750
3910 DEFFN'31
   : GOSUB '229(1,"3741020A")
   : IF R=1THEN 3970
   : PRINT HEX(030A);"MOUNT SYSTEM PATTER."
   : GOSUB '254
   : GOTO 3910
3970 PRINT HEX(03);"SYSTEM NOW LOADING - SYSTEM MENU"
   : LOAD DC T#1,"3741020A"3000,6990
4000 Z0=X1
   : GOTO 3390
4030 Z0=X2
   : GOTO 3390
4060 GOSUB '200(B1$,B2$,4,0,"ENTER THE ADDRESS OF THE SECTOR TO DUMP",1)
   : Z0=Q9
   : GOTO 3390
4100 IF Z0+4>X2THEN 4130
   : Z0=Z0+4
   : GOTO 3390
4130 Z0=X2
   : GOTO 3390
4160 IF Z0-2<X1THEN 4190
   : Z0=Z0-2
   : GOTO 3390
4190 Z0=X1
   : GOTO 3390
4220 IF Z0-6<X1THEN 4250
   : Z0=Z0-6
   : GOTO 3390
4250 Z0=X1
   : GOTO 3390
4280 INIT(20)M$
   : IF C4=1THEN 4320
   : STR(M$,1,2)=HEX(0D0C)
   : GOSUB '50(STR(M$,1,2))
4320 STR(M$,1,3)=HEX(0D0A0E)
   : STR(M$,4,7)="SECTOR "
   : CONVERT Z0-1TO STR(M$,11,4),(####)
   : STR(M$,15,1)=HEX(28)
   : CONVERT INT((Z0-2)/26)TO STR(M$,16,2),(##)
   : STR(M$,18,1)=HEX(2F)
   : CONVERT Z0-1-INT((Z0-2)/26)*26TO STR(M$,19,2),(##)
   : STR(M$,21,1)=HEX(29)
4400 GOSUB '50(M$)
   : GOSUB '50(Z$(1))
   : GOSUB '50(Y1$(1))
   : GOSUB '50(Y$(1))
   : INIT(20)M$
   : STR(M$,1,2)=HEX(0D0A)
   : GOSUB '50(M$)
   : GOSUB '50(Z$(2))
   : GOSUB '50(Y1$(2))
   : GOSUB '50(Y$(2))
   : C4=1
   : GOTO 3630
4520 IF D$="Y"THEN 4570
   : D$="Y"
   : D1$="EBCDIC"
   : Z0=Z0-1
   : GOTO 3390
4570 D$="N"
   : D1$="ASCII"
   : Z0=Z0-1
   : GOTO 3390