image of READY prompt

Wang2200.org

Listing of file='OP1D060A' on disk='vmedia/701-2046C.wvd.zip'

# Sector 546, program filename = 'OP1D060A'
0010 REM .     OP1D060A,  00-00 (6/28/75),   12002
0100 PRINT "TESTING MAT MULTIPLICATION... ";
   : DIM C(5,5),A(5,5),B(5,5),D(20)
   : MAT REDIM A(3,4),B(4,3)
   : X=RND(0)
   : FOR I=1TO 3
   : FOR J=1TO 4
   : A(I,J)=RND(1)
   : B(J,I)=RND(1)
   : NEXT J
   : NEXT I
   : MAT C=A*B
   : GOSUB '00(3,4,3)
   : FOR L=1TO 5
   : MAT REDIM B(L,L)
   : MAT A=B
0250 MAT C=A*B
   : GOSUB '00(L,L,L)
   : NEXT L
   : MAT REDIM A(1,1),D(1)
   : A(1,1)=2
   : MAT D=A*A
   : IF D(1)<>4THEN 600
   : MAT REDIM A(1,20),D(20)
   : FOR I=1TO 20
   : A(1,I),D(I)=I
   : NEXT I
   : MAT C=A*D
   : IF C(1,1)<>2870THEN 600
   : IF E(6)<>0THEN 610
   : PRINT "OK"
   : GOTO 630
0410 DEFFN'00(D1,D2,D3)
   : FOR I=1TO D1
   : FOR J=1TO D3
   : FOR K=1TO D2
   : S=S+A(I,K)*B(K,J)
   : NEXT K
   : D(J)=S
   : S=0
   : NEXT J
   : FOR J=1TO D3
   : A(I,J)=D(J)
   : NEXT J
   : NEXT I
   : FOR I=1TO D1
   : FOR J=1TO D3
   : IF C(I,J)<>A(I,J)THEN 600
   : NEXT J
   : NEXT I
   : RETURN
0600 E(6)=E(6)+1
0610 PRINT TAB(40);E(6);"ERRORS"
   : E9$(P9)="NG"
0630 LOAD DC T#6,"OP1D070A"
0640 DEFFN'15
   : COM CLEAR
   : LOAD DC T#6,"START"