image of READY prompt

Wang2200.org

Listing of file='P21W010A' on disk='vmedia/701-2046C.wvd.zip'

# Sector 807, program filename = 'P21W010A'
0010 REM .     P21W010A,  00-00 (6/28/75),   12002
0100 DIM T$(1)1,C$(5)26,I$(1)5,C1$(5)26,A$64,C2$(26)1,C3$(10)
   : SELECT PRINT 005
   : PRINT HEX(03);"2200 HARDWARE DIAGNOSTIC - 2221W"
   : PRINT "-----------------------------------"
   : PRINT "EXECUTING PROGRAM"
0150 SELECT PRINT 215(132)
   : PRINT " ";
   : $IF ON /215,220
   : SELECT PRINT 005
   : PRINT "*** TURN ON PRINTER ***"
   : INPUT "KEY EXEC TO RESUME",Z
   : GOTO 150
0220 PRINT HEX(0C)
   : PRINT "1. THIS IS THE FIRST LINE OF THE PRINT OUT"
   : PRINT
   : PRINT
   : PRINT
   : PRINT
   : PRINT "6. THIS IS THE SIXTH LINE."
   : PRINT "7. VERTICAL TAB STARTS FROM THIS LINE"
   : FOR I=1TO 8
   : N=(1+I)*6
   : PRINT HEX(0B)
   : PRINTUSING 340,N
0340 %##. VERTICAL TAB, HEX(0B)
0350 NEXT I
   : PRINT "55. THE NEXT TEST IS FOR THE LINE FEED CODE HEX(0A)"
   : FOR I=1TO 3
   : PRINT HEX(0A)
   : NEXT I
   : PRINT "59. THIS LINE SHOULD BE PRINTED BEFORE END OF DOCUMENT"
0410 PRINT "1.-------------------------THIS SHOULD BE THE FIRST LINE AFTER END
      OF DOCUMENT.-----------------------------------------------------"
0420 A$=HEX(410D00420D00430D00440D00450D00460D)
   : PRINT A$
   : FOR I=1TO 10
0450 PRINT "ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890-=!@#$%^&*()-+';/./:?.abcdefgh
     ijklmnopqrstuvwxyz!@#$%^&*()-+1234567890-=';/.:?.ABCDEFGHIJKLMNOPQ"
   : PRINT HEX(0E)
0470 PRINT "TTTT====5555wwwwjjjjMMMM;;;;;;;;jjjjjjjjTT==55wwjjMM;;;;jjjjBBBNNN
     "
   : NEXT I
   : FOR I=1TO 264
   : PRINT "AB";
   : NEXT I
   : PRINT HEX(0B)
0530 PRINT "THIS LINE SHOULD NOT BE PRINTED, UNLESS THE PRINTER IS NOT RESPOND
     ING TO THE DELETE CODE HEX(7F)";HEX(7F)
   : PRINT "37. YOU SHOULD HEAR THE BELL SOUND THREE TIMES"
   : PRINT HEX(07)
   : FOR D=1TO 300
   : NEXT D
0580 PRINT HEX(07)
   : FOR D=1TO 300
   : NEXT D
   : PRINT HEX(07)
   : PRINT "38. AFTER THIS LINE IS PRINTED THERE SHOULD BE A FORM-FEED"
   : PRINT HEX(0C)
   : N=1
0650 PRINT "EXAMINE THE FOLLOWING OUTPUT FOR PRINT QUALITY AND CONSISTENCY IN
     THE PRINT PATTERN"
   : PRINT HEX(0E);"TEST 2"
0670 P3=1
   : FOR I=1TO 26
   : BIN(STR(I$(1),1))=INT(RND(1)*94+33)
   : C2$(I)=STR(I$(1),1)
   : STR(I$(1),2)=STR(I$(1),1)
   : MAT COPY I$()TO C1$()<P3,5>
   : P3=P3+5
   : NEXT I
   : FOR I=1TO 26
   : PRINT TAB(I*5-5);C2$(I);
   : NEXT I
   : FOR I=1TO 5
   : FOR J=1TO 5
   : PRINT C1$(J);
   : NEXT J
   : NEXT I
   : PRINT HEX(0D)
   : N=N+1
0850 IF N<10THEN 670
   : PRINT HEX(0C);HEX(0E);"TEST 3"
   : P3=1
   : N=33
   : P4=1
   : FOR I=1TO 130
   : IF N<=126THEN 930
   : N=33
0930 BIN(I$(1))=N
   : N=N+1
   : MAT COPY I$()TO C$()<P3,1>
   : P3=P3+1
   : NEXT I
0980 FOR I=1TO 95
   : FOR J=1TO 5
   : IF P4=2THEN 1030
   : PRINT C$(J);
   : GOTO 1040
1030 PRINT HEX(0E);C$(J);
1040 NEXT J
   : T$(1)=STR(C$(5),26,1)
   : MAT COPY C$()<1,129>TO C1$()<2,129>
   : MAT COPY T$()<1,1>TO C1$()<1,1>
   : MAT COPY C1$()TO C$()
   : NEXT I
   : IF P4>1THEN 1130
   : P4=2
   : GOTO 980
1130 PRINT HEX(0D0C);HEX(0E);"TEST 4"
   : A$="TUIHZ-/.#+/TUIHZ-/.#+/TUIHZ-/.#+/TUIHZ-/.#+/TUIHZ-/.#+/TUIHZ-/.#+/"
   : FOR I=1TO 25
   : PRINT HEX(0E);A$
   : NEXT I
   : FOR I=1TO 25
   : PRINT A$;A$
   : NEXT I
   : PRINT HEX(0C0E);"TEST 5"
1220 DATA "SKIP 1 LINE","SKIP 2 LINES","SKIP 3 LINES","SKIP 4 LINES","SKIP 5 L
     INES","SKIP 6 LINES","SKIP 7 LINES","SKIP 8 LINES","SKIP 9 LINES"
   : INIT(0A)L3$
   : FOR I=1TO 9
   : READ C3$(I)
   : NEXT I
   : FOR I=1TO 9
1280 PRINT C3$(I)
   : PRINT STR(L3$,1,I)
   : NEXT I
   : PRINT HEX(0A0A0A0A0E);"THIS SHOULD BE THE LAST LINE OF PRINT ON THIS PAGE
     "
   : PRINT HEX(0E);"THIS IS THE FIRST LINE OF PRINT AND THE END OF THE TEST"
   : SELECT PRINT 005(64)
1340 LOAD DC T#6,"S/START"
1350 DEFFN'15
   : COM CLEAR
   : SELECT PRINT 005(64)
   : LOAD DC T#6,"START"