image of READY prompt

Wang2200.org

Listing of file='KFAM0003' on disk='vmedia/701-2049C.wvd.zip'

# Sector 431, program filename = 'KFAM0003'
0010 REM KFAM0003,VER.04/28/76
0200 RETURN
0205 COM V7$8,T0$7,V9,V0$(3)2,T1(3)
   : COM V0$2,V1$8,V2$2,V3$2,V4$2,V6$1
   : COM Q2$2,Q3$2,V5$1,V8$1,T5$30,T7$30
   : COM T0,T9,T2$2,T4$3,T2,V8,T8,T1,T8$1,T2$(8)2,T(8)
   : COM T4,T5,V6,V7,V1
0225 COM Q,Q$1,T9$2,T0$(4)60
0235 COM V7$(3)8,Q4$2,Q9$2,Q0$(4)60
0240 COM T6$1,T3$3,T1$(1)2,T3$(1)33,V9$2,T1$30
0510 V9$=T9$
   : ADDC(V9$,V0$)
   : DATA SAVE DA T$#T1,(V9$,V9$)T9$,T0$()
   : RETURN
0545 ADDC(V9$,V0$)
   : DATA LOAD DA T#T1,(V9$,V9$)T9$,T0$()
   : RETURN
0570 V9$=Q9$
   : ADDC(V9$,V0$)
   : DATA SAVE DA T$#T1,(V9$,V9$)Q9$,Q0$()
   : RETURN
0645 Q2=99
0655 V9$=T2$
   : FOR T3=T0TO 1STEP -1
   : GOSUB 545
   : T2$(T3)=T9$
   : MAT SEARCHT0$()<1,V7>,>STR(T1$,1,T4)TO T1$()STEP T5
   : T=VAL(STR(T1$(1),2))-T5
   : IF T>0THEN 720
   : T=V1
0720 MAT COPY T0$()<T,T5>TO T3$()
   : V9$=STR(T3$(1),T4+1,2)
   : IF Q2<99THEN 785
0735 T(T3)=T
   : NEXT T3
   : T7$=T1$
   : V=2
   : IF STR(T1$,1,T4)=STR(T3$(1),1,T4)THEN 770
   : V=3
0770 RETURN
0785 MAT COPY T0$()<V1,1>TO T1$()
   : IF T1$(1)=HEX(FF)THEN 810
   : Q2=Q2+1
   : GOTO 735
0810 Q2=0
   : GOTO 735
0830 T4=VAL(STR(V1$,5))
   : T5=T4+3
   : V6=VAL(STR(V1$,6))
   : V7=T5*V6
   : V1=V7-T5+1
   : RETURN
0920 Q$=" "
   : IF T6<1THEN 3040
   : IF T6=T9THEN 200
0935 IF T6>3THEN 3040
   : IF V9=0THEN 3040
   : IF V0$(T6)>HEX(FF)THEN 3040
   : IF T9=0THEN 970
   : GOSUB 1015
0970 T9=T6
   : GOSUB 1045
   : GOSUB 830
   : T9$=HEX(FF)
   : RETURN
0988 GOTO 3040
1015 DATA SAVE DA T$#T1,(V0$,V9$)Q2$,Q3$,V5$,V8$,V0$,V1$,V2$,V3$,V6$,T2$,T0,T1
     ,T2,V8,T4$,T5$,T7$,T2$(),T(),T8$
   : RETURN
1045 DATA LOAD DA T#T1(T9),(V0$(T9),V9$)Q2$,Q3$,V5$,V8$,V0$,V1$,V2$,V3$,V6$,T2
     $,T0,T1,T2,V8,T4$,T5$,T7$,T2$(),T(),T8$
   : RETURN
1070 T6=VAL(T4$)*256+VAL(STR(T4$,2))
   : DBACKSPACE #T2,BEG
   : IF T6=0THEN 1095
   : DSKIP #T2,T6S
1095 Q=VAL(STR(T4$,3))
   : Q$,T8$=" "
   : RETURN
1120 DEFFN'232(T6,T7,T1$)
   : GOSUB 920
   : IF Q$>" "THEN 200
   : GOSUB 645
   : T4$=STR(T3$(1),T4+1,3)
   : T8$="2"
   : IF V<>2THEN 3005
   : IF T4$>HEX(FF)THEN 3005
   : GOSUB 1070
   : RETURN
1175 DEFFN'235(T6)
   : GOSUB 920
   : IF Q$>" "THEN 200
   : INIT(00)T1$
   : Q$,T8$="5"
   : GOTO 1265
1215 DEFFN'237(T6)
   : GOSUB 920
   : IF Q$>" "THEN 200
   : T=T(1)
   : IF T8$=" "THEN 1275
   : IF T8$>HEX(40)THEN 3035
   : T1$=T7$
1265 GOSUB 645
1275 T=T+T5
   : IF T2$(1)=T9$THEN 1305
   : V9$=T2$(1)
   : GOSUB 545
1305 IF T>V1THEN 1365
   : MAT COPY T0$()<T,T5>TO T3$()
   : IF T3$(1)>HEX(FF)THEN 1365
1325 T7$=STR(T3$(1),1,T4)
   : T4$=STR(T3$(1),T4+1,3)
   : IF T4$>HEX(FF)THEN 3000
   : T(1)=T
   : T2$(1)=T9$
   : GOSUB 1070
   : RETURN
1365 T3=1
1370 T3=T3+1
   : IF T3>T0THEN 3060
   : V9$=T2$(T3)
   : GOSUB 545
   : T=T(T3)
   : T=T+T5
   : IF T>V1THEN 1370
   : MAT COPY T0$()<T,T5>TO T3$()
   : IF T3$(1)>HEX(FF)THEN 1370
1420 T(T3)=T
   : IF T3=1THEN 1325
   : V9$=STR(T3$(1),T4+1,2)
   : GOSUB 545
   : MAT COPY T0$()<1,T5>TO T3$()
   : T3=T3-1
   : T=1
   : T2$(T3)=T9$
   : GOTO 1420
1480 DEFFN'236(T6)
   : GOSUB 920
   : IF Q$>" "THEN 200
   : T1$=HEX(FF)
   : GOSUB 645
   : GOTO 1325
1545 GOSUB 1640
   : IF T=V1THEN 1580
   : T6=V1-T
   : MAT COPY -T0$()<T,T6>TO -T0$()<T+T5,T6>
1580 T3$(1)=T1$
   : STR(T3$(1),T4+1,3)=STR(T3$,1,3)
   : MAT COPY T3$()<1,T5>TO T0$()<T,T5>
   : RETURN
1640 IF T3>1THEN 1750
   : IF Q$="4"THEN 1720
   : ADD(V5$,01)
   : IF V5$<=V8$THEN 1690
   : ADDC(Q2$,V6$)
   : V5$=HEX(01)
1690 T3$=Q2$
   : STR(T3$,3)=V5$
   : T4$=T3$
   : RETURN
1720 T3$=T4$
   : RETURN
1750 T3$=Q4$
   : RETURN
1770 DEFFN'234(T6,T7,T1$,Q)
   : GOSUB 920
   : IF Q$>" "THEN 200
   : Q$="4"
   : IF T8$<>"1"THEN 3035
   : IF STR(T4$,1,2)>Q3$THEN 3035
   : IF STR(T4$,3,1)>V8$THEN 3035
   : GOTO 1870
1830 DEFFN'233(T6,T7,T1$,Q)
   : GOSUB 920
   : IF Q$>" "THEN 200
1870 Q2=1
   : T6$=T1$
   : IF T6$=HEX(FF)THEN 3035
   : GOSUB 655
   : IF V=2THEN 2980
   : V8=.004+.98*V8
   : IF T1$>T5$THEN 1930
   : V8=V8+.012
1930 T5$=T1$
   : T8=INT(V8*V6+.6)
   : T=T+T5
   : IF Q$="4"THEN 1975
   : IF V5$<V8$THEN 1975
   : V9$=Q2$
   : T6$=V6$
   : ADD(T6$,FF)
   : ADDC(V9$,T6$)
   : ADDC(V9$,V6$)
   : IF V9$>Q3$THEN 1995
1975 IF Q2=0THEN 2300
   : IF Q2<9THEN 2010
1995 T8$,Q$="S"
   : RETURN
2010 V9$=V2$
   : BIN(T6$)=Q2
   : ADDC(V9$,T6$)
   : IF V3$<V9$THEN 1995
2040 ADDC(V2$,01)
   : Q9$=V2$
   : INIT(FF)Q0$()
   : Q2,T6=T8*T5
   : IF T<V7-Q2+T5THEN 2100
   : Q2=Q2-T5
2100 Q3=V7-Q2+1
   : MAT COPY T0$()<Q3,Q2>TO Q0$()<1,Q2>
   : MAT COPY Q0$()<Q2+1,1>TO T0$()<Q3,1>
   : MAT COPY T0$()<Q3,Q2-1>TO T0$()<Q3+1,Q2-1>
   : IF Q2=T6THEN 2205
   : T=T-(V7-Q2)
   : IF T=Q2+1THEN 2175
2155 MAT COPY -Q0$()<T,Q2+1-T>TO -Q0$()<T+T5,Q2+1-T>
2175 T3$(1)=T1$
   : GOSUB 1640
   : STR(T3$(1),T4+1,3)=STR(T3$,1,3)
   : MAT COPY T3$()<1,T5>TO Q0$()<T,T5>
   : GOTO 2215
2205 GOSUB 1545
2215 GOSUB 570
   : GOSUB 510
   : T1$=STR(Q0$(1),1,T4)
   : Q4$=Q9$
   : T3=T3+1
   : IF T3>T0THEN 2345
   : V9$=T2$(T3)
   : GOSUB 545
   : T=T(T3)+T5
   : MAT COPY T0$()<V1,T5>TO T3$()
   : IF T3$(1)>HEX(FF)THEN 2300
   : GOTO 2040
2300 GOSUB 1545
   : GOSUB 510
2315 GOSUB 1070
   : T8$="3"
   : GOSUB 1015
   : RETURN
2345 ADDC(V2$,01)
   : Q9$=V2$
   : INIT(FF)Q0$()
   : INIT(00)T3$(1)
   : STR(T3$(1),T4+1,2)=STR(T2$,1,2)
   : MAT COPY T3$()<1,T5>TO Q0$()<1,T5>
   : T3$(1)=T1$
   : STR(T3$(1),T4+1,2)=Q4$
   : MAT COPY T3$()<1,T5>TO Q0$()<T5+1,T5>
   : GOSUB 570
   : T0=T3
2400 T2$=Q9$
   : GOTO 2315
2420 DEFFN'231(T6,T7,T1$)
   : GOSUB 920
   : IF Q$>" "THEN 200
   : Q$=T1$
   : IF Q$=HEX(FF)THEN 3035
   : GOSUB 645
   : IF V<>2THEN 3000
   : T4$=STR(T3$(1),T4+1,3)
   : IF T4$>HEX(FF)THEN 3035
2480 IF T=V1THEN 2510
   : T6=V7-T+1-T5
   : MAT COPY T0$()<T+T5,T6>TO T0$()<T,T6>
2510 INIT(FF)T3$(1)
   : MAT COPY T3$()<1,T5>TO T0$()<V1,T5>
2515 GOSUB 510
   : IF T=1THEN 2555
   : GOSUB 1070
   : T8$="1"
   : RETURN
2555 T3$(1),Q$=T0$(1)
   : T3=T3+1
   : V9$=T2$(T3)
   : GOSUB 545
   : T=T(T3)
   : IF Q$=HEX(FF)THEN 2480
   : MAT COPY T3$()<1,T4>TO T0$()<T,T4>
   : GOTO 2515
2620 DEFFN'230(T6,T7,Q2,Q3,V7$)
   : IF T6<1THEN 3035
   : IF T6>3THEN 3035
   : IF V9>0THEN 2840
   : INIT(FF)V0$()
   : INIT(00)T0$
2695 IF STR(T0$,T7+1,1)>HEX(00)THEN 3035
   : IF STR(T0$,Q2+1,1)>HEX(00)THEN 3035
   : IF Q2=T7THEN 3035
2715 V7$(T6)=V7$
2718 DATA LOAD DC OPEN T#Q2,V7$
   : STR(V7$,5,1)="K"
   : CONVERT Q3TO STR(V7$,6,1),(#)
   : LIMITS T#T7,V7$,T,V,T3
   : V=INT(T/256)
   : BIN(V0$)=V
   : BIN(STR(V0$,2))=T-256*V
   : T9=T6
   : V0$(T9)=V0$
   : T1(T9)=T7
   : GOSUB 1045
   : GOSUB 830
   : V0$=V0$(T9)
   : T1=T7
   : T2=Q2
2800 STR(T0$,T7+1,1)=HEX(01)
   : STR(T0$,Q2+1,1)=HEX(01)
   : V9=V9+1
   : Q$=" "
   : T8$="O"
   : RETURN
2840 IF V0$(T6)<HEX(FF)THEN 3035
   : IF T9=0THEN 2695
   : GOSUB 1015
   : T9=0
   : GOTO 2695
2875 DEFFN'239(T6)
   : IF T9=0THEN 2900
   : GOSUB 1015
   : T9=0
2900 IF V9=0THEN 3035
   : IF V0$(T6)>HEX(FF)THEN 3035
   : T9=T6
   : GOSUB 1045
2914 LIMITS T#T2,V7$(T9),T,V,T3
   : V=V-1
   : T0$(1)=HEX(A0FD)
   : STR(T0$(1),3)=Q2$
   : STR(T0$(1),5)=V5$
   : STR(T0$(1),6)=V8$
   : STR(T0$(1),7)=V1$
   : STR(T0$(1),15)=V6$
   : DATA SAVE BA T$#T2,(V,V)T0$()
2935 T9=0
   : INIT(FF)V0$(T6)
   : STR(T0$,T1+1,1),STR(T0$,T2+1,1)=HEX(00)
   : V9=V9-1
   : Q$=" "
   : RETURN
2980 T8$,Q$="D"
   : RETURN
3000 T8$="N"
3005 Q$="N"
   : RETURN
3035 T8$="X"
3040 Q$="X"
   : RETURN
3060 IF Q$="5"THEN 3000
   : T8$,Q$="E"
   : RETURN
3072 %#