image of READY prompt

Wang2200.org

Listing of file='@MODSYSF' on disk='vmedia/701-2294U.wvd.zip'

# Sector 77, program filename = '@MODSYSF'
0010 REM % Prog = @MODSYSF  V1.0   By MCF     Date = 02/01/85     For MVP Rel
     2.6
0015 REM % COPYRIGHT WANG LABORATORIES 1985
0020 REM % CONVERT @SYSFILE TO NEW STRUCTURE FOR MVP 2.6
0030 REM % V1.1   ST 01/03/85
0040 DIM T$16,F$8,S$32,C$16,P$(16)8,D$(33)3,D1$(11,33)3,M2$15,A4$3,Q$1,Q6$2
0050 DIM  F1$(11)8,U1(11),S1$(11)32,T2$(11)16,C1$(11)16,P1$(11,16)8,P2$(16)8,D
     3$(33)3,F2$8
0060 DIM T1$(15)13
0070 T1$()=ALL(00)
   : I=0
   : F2$="JUNKXXXA"
0080 PRINT HEX(030E);AT(0,17);"Convert System Configuration File"
0090 REM %*** READ OLD CONFIGURATIONS ***
0100 PRINT HEX(06);AT(5,0,80);
   : LINPUT "Enter disk address of datafile '@SYSFILE'  ",-A4$
   : GOSUB '205(A4$)
   : IF Q$<>" " THEN 100
   : SELECT #1<A4$>
   : ERRORGOTO 100
0110 DATA LOAD DC OPEN T #1,"@SYSFILE"
   : ERRORE=ERR
   : PRINT AT(18,0,80);"No configurations ('@SYSFILE') on disk  -  (Error ";E;
     " )"
   : END
0120 DATA LOAD DC #1, F$,U,S$,T$,C$,P$(),D$(),T1$()
   : ERRORE=ERR
   : IF E=74 OR E=88 THEN 140
   : REM JUMP IF OLD FILE TYPE
   : ELSE PRINT HEX(0E);"Error ";E;" while loading @SYSFILE"
   : END
0130 PRINT
   : PRINT "System Configuration File has already been converted"
   : END
0140 DBACKSPACE #1,BEG
   : T1$()=ALL(00)
0150 DATA LOAD DC #1, F$,U,S$,T$,C$,P$(),D$()
   : ERRORE=ERR
   : PRINT HEX(0E);"Error ";E;" while loading @SYSFILE"
   : END
0160 IF END THEN 200
   : IF F$=" "THEN 150
   : I=I+1
   : IF I>10 THEN  200
   : GOSUB '225
   : GOTO 150
0170 REM % *** READ THE OLD CONFIGURATION INFORMATION INTO ARRAYS ***
0180 DEFFN '225
   : F1$(I)=F$
   : U1(I)=U
   : S1$(I)=S$
   : C1$(I)=C$
   : T2$(I)=T$
   : FOR J=1 TO 16
   : P1$(I,J)=P$(J)
   : NEXT J
   : FOR J =1 TO 33
   : D1$(I,J)=D$(J)
   : NEXT J
   : RETURN
0190 REM % SAVE THE NEW CONFIG FILE
0200 REM % STRETCH EXISTING FILE TO ACCOMODATE EXTRA INFO
0210 SCRATCH T#1,"@SYSFILE"
   : ERRORPRINT AT(10,0);HEX(060E);"Disk write protected - press any key to re
     try ";
   : KEYIN K$
   : PRINT HEX(06),AT(10,0,)
0230 SAVE DC T#1,("@SYSFILE")F2$10,10
   : ERRORF2$=ADDCHEX(01)
   : GOTO 230
0240 SCRATCH T#1,F2$
0250 DATA SAVE DC OPEN T#1,(3*11+2)"@SYSFILE"
   : ERRORE=ERR
   : PRINT AT(10,0);"Disk error ";E;" while creating new @SYSFILE"
   : STOP #
   : END
0260 DBACKSPACE #1, BEG
   : FOR J=1 TO I
0270 FOR K=1 TO 16
   : P2$(K)=P1$(J,K)
   : NEXT K
0280 FOR K=1 TO 33
   : D3$(K)=D1$(J,K)
   : NEXT K
0290 DATA SAVE DC #1,F1$(J),U1(J),S1$(J),T2$(J),C1$(J),P2$(),D3$(),T1$()
   : NEXT J
0300 DATA SAVE DC #1,END
   : DATA SAVE DC CLOSE
0310 PRINT
   : PRINT "File conversion complete"
   : IF V9=0THEN END
   : LOAD T"@GENPART"
0320 DEFFN '205 (W3$)
   : Q$=" "
   : MAT SEARCH"310320326330350360370B10B20B26B30B50B60B70D10D11D12D13D14D15D2
     0D21D22D23D24D25D30D31D32D33D34D35D50D51D52D53D54D55D60D61D62D63D64D65D70
     D71D72D73D74D75",=STR(W3$,,3) TO Q6$STEP 3
   : IF Q6$<>HEX(0000) THEN RETURN
   : Q$="I"
   : RETURN
0330 DEFFN'31
   : SCRATCH T"@MODSYSF"
   : SAVE DC T()"@MODSYSF"