image of READY prompt

Wang2200.org

Listing of file='COPY928' on disk='vmedia/701-2356A.wvd.zip'

# Sector 5, program filename = 'COPY928'
0010 REM 10/8/77 WPSMCODE  WPS MICROCODE TO 2200 LOADER FILE
0020 SELECT #1 B10, #2 310
0025 COM F$8
0030 SELECT PRINT 005(64)
   : PRINT HEX(03)
0040 PRINT "PLACE MICROCODE FROM WPS ASSEMBLY IN 2200 LOADER FORMAT"
0050 PRINT "KEY S.F. '10 TO OPEN A NEW FILE"
0060 PRINT "PLACE WPS MICROCODE DISK IN #1 B10,  2200 DISK IN #2 310"
0070 DIM W$(128,4)16
   : REM /2200 TC LOADER FORMAT
0080 DIM Z0$(4)64, Z2$2, W$2
0090 REM %SETUP
0100 PRINT "OUTPUT CODE FILE NAME = ";F$;
0110 INPUT " OR",F$
0120 LIMITS T#2,F$,A,B,C
0130 A=0
   : C=1
0140 INIT(00)W$()
   : W$=HEX(1000)
0150 REM SET WPS SECTOR STRUCTURE
0160 Z0$=HEX(0004080C0105090D02060A0E03070B0F)
   : Z0=0
0170 FOR B=1 TO 32
0180 PRINT "MICROCODE=";
   : HEXPRINT W$
0190 REM ..WPS READ
0200 G=INT(Z0/16)
   : Z1=Z0-(16*G)
   : Z2=16*G+VAL(STR(Z0$,Z1+1))
0210 DATA LOAD BA T #1,(Z2,Z3)Z0$()
   : Z2$=Z0$(1)
0220 REM ..COPY DATA TO NEW 2200 TC LOADER ARRAY
0230 MAT COPY Z0$()<1,256>TO W$()<C,256>
0240 REM   HEXPRINT Z0$()
0250 REM ..BUMP POINTERS
0260 Z0=Z0+1
   : C=C+256
0270 ADD(STR(W$,1,1),01)
0280 NEXT B
0290 PRINT "SAVE MICROCODE IN FILE ";F$
0300 DATA LOAD DC OPEN T#2,F$
0310 DATA SAVE DC #2,W$()
0320 DATA SAVE DC #2,END
0330 STOP "END OF JOB"
0340 DEFFN'10
0350 INPUT "ENTER FILE NAME TO OPEN",F$
0360 DATA SAVE DC OPEN T #2,40,F$
0370 PRINT "FILE ";F$;" OPENED"
0380 RETURN