image of READY prompt

Wang2200.org

Listing of file='ISS.060U' on disk='vmedia/701-2423D.wvd.zip'

# Sector 455, program filename = 'ISS.060U'
0010 REM  ISS.060U, RELEASE 5-1, (11/07/79) - COPYRIGHT WANG LABS. INC.
0050 COM F$8,O$7,D$14,N$11,I$5,G2,F3,F1,F6,F5
   : DIM I1$3,P$(16),Z$(3)83
   : DIM D1$44,I2$10
0120 %   THIS MUST BE STATEMENT 120
0240 S1$="ISS.200SISS.254SISS.050S"
   : LOAD DC T#0,<LEN(S1$)/8>S1$10,0BEG 270
0270 GOSUB '50(6)
   : $UNPACK(F=HEX(A003A005A008A007A00EA00B))Z$(Z1)TO I1$,I$,F$,O$,D$,N$
   : GOSUB '60("DISK DUMP",6)
   : GOSUB '61("INPUT ADDRESS",I1$,"81","DISK")
   : GOSUB '61("INPUT MODE",I$,"82"," ")
   : GOSUB '61("FILE NAME",F$,"83"," ")
   : GOSUB '61("OUTPUT DEVICE",O$,"84"," ")
0360 GOSUB '61("DUMP OPTION",D$,"85"," ")
   : GOSUB '61("SECTORS TO DUMP",N$,"86"," ")
0390 GOSUB '70
   : SELECT #1<I1$>
   : IF O$="CRT"THEN 510
   : GOSUB '44
   : IF P$="P"THEN 1200
   : IF I$="RANGE"THEN 1030
   : GOTO 550
0510 IF D$<>"VERTICAL"THEN 1240
   : IF I$="RANGE"AND N$="ALL"THEN 1060
0550 PRINT HEX(010A);"MOUNT INPUT PLATTER"
   : GOSUB '254
   : DATA LOAD BA T#1,(0)P$()
   : ERRORGOTO 550
0590 F5=VAL(STR(P$(),5,2),2)
   : IF I$="FILE"THEN 750
   : CONVERT STR(N$,,POS(N$="-")-1)TO G2
   : CONVERT STR(N$,POS(N$="-")+1)TO F3
   : F1=F3-G2
   : IF F3>=F5THEN 1120
   : GOTO 990
0750 LIMITS T#1,F$,G2,F3,F1,F6
   : ERRORPRINT HEX(07)
   : GOTO 550
0770 IF N$="ALL"OR O$="CRT"THEN 830
   : CONVERT STR(N$,POS(N$="-")+1)TO F4
   : IF F4>=F1THEN 1090
0830 IF F6<1THEN 1270
   : IF F6=1AND D$="DATA STRUCTURE"THEN 1300
   : DATA LOAD BA T#1,(F3)P$()
   : IF STR(P$(),4,4)<>HEX(FD4D5558)THEN 990
   : IF P$(2)=" "THEN 990
0920 GOSUB '200(" "," ",16,0,"ENTER PASSWORD",2)
   : IF Q6$=P$(2)THEN 990
   : PRINT AT(3,0,S0);HEX(07);"RE-ENTER, WRONG PASSWORD"
   : GOTO 920
0990 LOAD DC T#0,"ISS.061U"
   : ERRORGOTO 1150
1030 PRINT HEX(010A07);"PRINTER ALLOWS 'FILE' DUMP ONLY"
   : GOTO 1210
1060 PRINT HEX(010A07);"RANGE NOT SPECIFIED"
   : GOTO 1210
1090 PRINT HEX(010A07);"SECTORS MUST BE WITHIN FILE LIMITS"
   : GOTO 1210
1120 PRINT HEX(010A07);"SECTORS MUST BE WITHIN DISK LIMITS"
   : GOTO 1210
1150 PRINT HEX(010A07);"RE-MOUNT ISS DISK AT ";S$;TAB(S0)
   : GOSUB '254
   : F9$="M"
   : GOTO 990
1200 PRINT HEX(010A07);"PRINTER REQUIRED"
1210 GOSUB '254
   : GOTO 390
1240 PRINT HEX(010A07);"CRT ALLOWS VERTICAL DUMP ONLY"
   : GOTO 1210
1270 PRINT HEX(010A07);"INACTIVE FILE"
   : GOTO 1210
1300 PRINT HEX(010A07);"DATA STRUCTURE FOR DATA FILES ONLY"
   : GOTO 1210
1330 DEFFN'15
   : RETURN CLEAR ALL
1350 PRINT AT(3,0,S0);
   : GOTO 390
1410 DEFFN'81
   : GOSUB '40("ENTER INPUT ADDRESS")
   : Z$,I1$=Z1$
   : RETURN
1460 DEFFN'82
   : IF I$="FILE"THEN I$="RANGE"
   : ELSE I$="FILE"
   : Z$=I$
   : RETURN
1510 DEFFN'83
   : Q6$=F$
   : GOSUB '200(" "," ",8,0,"ENTER FILE NAME",3)
   : Z$,F$=Q6$
   : RETURN
1560 DEFFN'84
   : IF O$="CRT"THEN O$="PRINTER"
   : ELSE O$="CRT"
   : Z$=O$
   : RETURN
1610 DEFFN'85
   : PRINT AT(13,0);"1 - HORIZONTAL"
   : PRINT "2 - VERTICAL"
   : PRINT "3 - DATA FILE STRUCTURE";
   : GOSUB '200("1","3",1,0,"ENTER OPTION",1)
   : D1$="HORIZONTAL    VERTICAL      DATA STRUCTURE"
   : Z$,D$=STR(D1$,Q9*14-13,14)
   : PRINT AT(13,0,3*S0)
   : RETURN
1750 DEFFN'86
1760 GOSUB '200(" "," ",11,0,"ENTER OPTION (FFFFF-LLLLL OR ALL)",2)
   : Z$,N$=Q6$
   : IF STR(N$,,3)="ALL"THEN RETURN
   : K=POS(N$="-")
   : IF K<2OR NUM(N$)<K-1OR NUM(STR(N$,K+1,LEN(N$)-K))<LEN(N$)-KTHEN 1840
   : CONVERT STR(N$,K+1)TO L
   : CONVERT STR(N$,,K-1)TO K
   : IF K<=LTHEN RETURN
1840 GOSUB '255
   : GOTO 1760
1890 DEFFN'51
   : $PACK(F=HEX(A003A005A008A007A00EA00B))Z$(Z1)FROMI1$,I$,F$,O$,D$,N$
   : RETURN
1950 DEFFN'31
   : PRINT HEX(03)
   : COM CLEAR F$
1980 LOAD DC T#0,"ISS.100M"
   : ERRORGOTO 1990
1990 PRINT HEX(010A);"MOUNT ISS DISK AT ADDRESS ";S$
   : GOSUB '254
   : GOTO 1980