image of READY prompt

Wang2200.org

Listing of file='ISS.071U' on disk='vmedia/701-2423D.wvd.zip'

# Sector 516, program filename = 'ISS.071U'
0010 REM  ISS.071U, RELEASE 5-1, (11/07/79) - COPYRIGHT WANG LABS. INC.
0069 DIM Y$32,Y0$32,Z1$3
   : DIM B$(4)64,B$48,N1$8,E$1
0120 % THIS MUST BE STATEMENT 120
0140 S1$="ISS.226SISS.229SISS.254SISS.217SISS.200S"
   : LOAD DC T#0,<LEN(S1$)/8>S1$10,0BEG 160
0160 IF S$(1)<>" "THEN SELECT #4<S$(1)>
   : IF F9$=" "THEN 230
0190 PRINT AT(1,0);"MOUNT INPUT PLATTER"
   : GOSUB '254
   : DATA LOAD BA T#1,(0)B$()
   : ERRORGOTO 190
0230 IF M1$="CLOSE"OR O$="CRT"THEN 270
   : GOSUB '94
   : PRINT AT(1,0,2*S0);"PRINTING REPORT ...";
0270 N1$=ALL(00)
   : L=100
   : P=1
0310 GOSUB '91
   : IF N1$=HEX(0000000000000000)THEN 440
   : LIMITS T#1,N1$,X,Y,Z,W
   : IF W<2THEN 310
   : IF M1$="CLOSE"THEN GOSUB 1090
   : ELSE GOSUB 1230
   : GOTO 310
0440 $CLOSE#4
   : IF L=100THEN 910
   : IF Z9$<>"PART"THEN Z9=0
   : Z8=0
0480 I=1
   : IF M1$<>"CLOSE"THEN 560
   : PRINT AT(10,0);
   : B$(1)="RERUN (PARAMETERS WILL BE IDENTICAL)"
   : E$="2"
   : GOTO 690
0560 IF O$="CRT"THEN 600
   : PRINT HEX(0E);"END OF REPORT"
   : SELECT PRINT 005(S0)
   : GOTO 630
0600 PRINT AT(1,0,2*S0);"END OF REPORT"
   : GOSUB '254
   : PRINT HEX(03)
0630 PRINT AT(10,0);
   : PRINT I;"REPRINT REPORT ON PRINTER"
   : I=I+1
   : B$(2)="REPRINT REPORT ON CRT"
   : E$="3"
0690 PRINT I;B$(I)
   : I=I+1
   : PRINT I;"RETURN TO MENU"
   : GOSUB '200("1",E$,1,0,"ENTER THE NUMBER OF THE DESIRED OPTION",1)
   : IF Q9=ITHEN GOSUB '31
   : PRINT AT(10,0,)
   : IF M1$<>"CLOSE"THEN 800
   : GOTO 270
0800 IF Q9=1THEN 830
   : O$="CRT"
   : GOTO 270
0830 O$="PRINTER"
   : GOSUB '44
   : IF P$=" "THEN 230
   : PRINT AT(1,0);HEX(07);"PRINTER REQUIRED"
   : GOSUB '254
   : GOTO 480
0910 SELECT PRINT 005(S0)
   : PRINT HEX(07);AT(1,0,2*S0);"NO FILES MEET SPECIFICATIONS"
   : GOSUB '254
0950 DEFFN'31
   : SELECT PRINT 005
   : PRINT HEX(03)
   : $CLOSE#4
   : COM CLEAR Z9$
   : IF Z8$<>" "THEN GOSUB '219(Z8$,1,S2," ",0)
1010 LOAD DC T#0,"ISS.100M"
   : ERRORGOTO 1020
1020 PRINT HEX(010A);"MOUNT ISS DISK AT ADDRESS ";S$
   : GOSUB '254
   : GOTO 1010
1090 L=0
   : GOSUB 2130
   : IF M$<>"MUX"THEN RETURN
   : IF N>0THEN STR(B$(),32+N,1)=HEX(20)
   : ELSE STR(B$(),33,48)=ALL(20)
   : GOSUB 2200
   : RETURN
1230 IF O$="PRINTER"THEN SELECT PRINT <S$(1)>
   : GOSUB 2130
   : IF N>0OR M1$="LIST MUX'D"OR M1$="LIST OPEN"AND M$<>"MUX"THEN RETURN
   : IF M1$="LIST OPEN"AND B$=" "THEN RETURN
   : IF N>0AND STR(B$,N,1)=" "THEN RETURN
   : IF O$="PRINTER"AND L>53THEN GOSUB 2030
   : IF O$="CRT"AND L+1>MAX(S0-59,13)THEN GOSUB 1980
   : IF N>0THEN 1660
   : IF M$="MUX"THEN 1410
   : PRINT N1$;TAB(39);"NOT A MULTIPLEXED FILE"
   : GOTO 1600
1410 IF B$<>" "THEN 1450
   : PRINT N1$;TAB(39);"NOT OPENED"
   : GOTO 1600
1450 $TRAN(B$,HEX(0001010101))0F
   : STR(B$,,47)=ADDSTR(B$,,48)
   : IF O$="PRINTER"AND L+VAL(B$)>54THEN GOSUB 2030
   : PRINT N1$;
1520 I=POS(STR(B$(),33,48)<>20)
   : IF I=0THEN 1610
   : GOSUB 1760
   : PRINT
   : GOTO 1520
1600 L=L+1
1610 PRINT "--------------------------------------------------------------"
   : L=L+1
   : RETURN
1660 PRINT N1$;
   : I=N
   : GOSUB 1760
   : IF STR(B$(),33,48)=" "THEN PRINT
   : ELSE PRINT TAB(39);"OPEN BY MULTIPLE STATIONS"
   : RETURN
1760 IF O$="PRINTER"OR L<MAX(S0-59,13)THEN 1810
   : GOSUB 1980
   : PRINT N1$;
1810 L=L+1
   : PRINT TAB(14);I;TAB(22);
   : ON VAL(STR(B$(),32+I,1))-48GOSUB 1870,1890,1910,1930
   : STR(B$(),32+I,1)=" "
   : RETURN
1870 PRINT "INQUIRY";
   : RETURN
1890 PRINT "READ ONLY";
   : RETURN
1910 PRINT "SHARED";
   : RETURN
1930 PRINT "EXCLUSIVE";
   : RETURN
1980 IF L=100THEN 2010
   : PRINT AT(1,0,2*S0);"READY FOR NEXT DISPLAY";
   : GOSUB '254
2010 PRINT HEX(03);AT(0,S0/2-9);"FILE STATUS REPORT";AT(3,0)
   : GOTO 2060
2030 PRINT HEX(0D0C0E);"FILE STATUS REPORT";TAB(25);"PAGE";P
   : P=P+1
   : PRINT
2060 PRINT "FILE NAME    ST. #   ACCESS MODE             COMMENT"
   : PRINT "---------    -----   -----------       -------------------"
   : L=4
   : RETURN
2130 DATA LOAD BA T#1,(Y,Y1)B$()
   : B$=STR(B$(),33,48)
   : IF STR(B$(),4,4)=HEX(FD4D5558)THEN M$="MUX"
   : ELSE M$=" "
   : RETURN
2200 DATA SAVE BA T#1,(Y,Y1)B$()
   : RETURN
2250 DEFFN'91
   : IF Z9$="INDIRECT"THEN 2560
   : IF Z9$="PART"THEN 2430
   : IF Z9=0THEN N1$=ALL(HEX(00))
   : IF Z9=0THEN Z9=1
2330 GOSUB '226(1,N1$)
   : N1$=R9$
   : IF N1$=HEX(0000000000000000)THEN RETURN
   : IF R<>2THEN 2330
   : IF N1$<Z1$(1)THEN 2330
   : IF N1$>Z2$(1)THEN 2330
   : RETURN
2430 Z8=Z8+1
   : IF Z8>Z9THEN 2530
   : N1$=Z1$(Z8)
2470 LIMITS T#1,N1$,W,W,W,W
   : IF W=2THEN RETURN
   : PRINT HEX(07010A);"MOUNT INPUT PLATTER"
   : GOSUB '254
   : GOTO 2470
2530 N1$=ALL(HEX(00))
   : RETURN
2560 MAT REDIM Z1$(14)8,Z2$(14)8,Z3$(14)1
   : IF Z9=1THEN 2640
2590 GOSUB '217(Z8$,3,S2,-2,2,"ISS 4.0 REF"," ",0)
   : IF Q$<>" "THEN 2770
   : Z9=1
   : Z8=0
2640 IF Z8=0THEN DATA LOAD DC #3,STR(Z1$(),1),STR(Z2$(),1),STR(Z3$(),1)
   : IF END THEN 2730
   : Z8=Z8+1
   : N1$=Z1$(Z8)
   : IF Z8=14THEN Z8=0
   : IF N1$=" "THEN 2640
   : RETURN
2730 N1$=ALL(HEX(00))
   : GOSUB '219(Z8$,3,S2," ",0)
   : RETURN
2770 PRINT AT(1,0);"ERROR IN REFERENCE FILE OPEN = ";Q$
   : GOSUB '254
   : GOTO 2590
2830 DEFFN'94
2850 $OPEN 2920,#4
2860 $GIO#4(010A02001212400040004000,A$)
   : IF STR(A$,8,1)=HEX(00)THEN RETURN
   : PRINT AT(1,0,S0);"SELECT PRINTER"
   : GOSUB '254
   : GOTO 2860
2920 PRINT AT(1,0,S0);"PRINTER HOGGED"
   : GOSUB '254
   : GOTO 2850
2980 DEFFN'44
   : P$="   000005"
   : MAT SEARCHP$,=S$(1)TO P$
   : IF STR(P$,1,2)=HEX(0000)THEN P$=" "
   : ELSE P$="P"
   : RETURN