image of READY prompt

Wang2200.org

Listing of file='ISS.000A' on disk='vmedia/701-2424C.wvd.zip'

# Sector 80, program filename = 'ISS.000A'
0010 REM  ISS.000A, RELEASE 5-1, (11/07/79) - COPYRIGHT WANG LABS. INC.
0070 DIM B$(3)83,A$8,B$3,L$2
0120 %   THIS MUST BE STATEMENT 120
0300 S1$="ISS.200SISS.254SISS.205S"
   : LOAD DC T#0,<LEN(S1$)/8>S1$7000,9999BEG 330
0330 C$="ISS.000D"
   : CONVERT S2TO STR(C$,6,2),(##)
   : DATA LOAD DC OPEN T#0,C$
   : DATA LOAD DC #0,B$()
   : $UNPACK(F=HEX(A003A008))B$(3)TO B$,A$
   : PRINT HEX(03);AT(8,0);
   : PRINT "STATION NUMBER  -";S2;TAB(32);"CPU TYPE        - ";
   : IF S3=3THEN PRINT "VP"
   : IF S3=4THEN PRINT "MVP"
   : PRINT "GREGORIAN DATE  - ";Q1$;TAB(32);"JULIAN DATE     -";Q1
0440 PRINT "MEMORY SIZE     -";S;"K";TAB(32);"CRT WIDTH       -";S0
   : PRINT "LOADING ADDRESS - ";S$;TAB(32);"PRINTER ADDRESS - ";S$(1)
   : PRINT "DISK ADDRESSES  - ";
   : FOR I=2TO 19
   : IF S$(I)=" "THEN 500
   : PRINT S$(I);" ";
0500 NEXT I
   : GOSUB 1070
   : IF A$<>HEX(0000000000000000)THEN 600
   : GOSUB 680
   : GOSUB 1070
   : GOSUB 770
   : GOSUB 1070
0600 GOSUB '200("0","2",1,0,"ENTER OPTION TO CHANGE   (0 = LOAD APPLICATION)",
     1)
   : IF Q9=0THEN 910
   : ON Q9GOSUB 680,770
   : GOSUB 1070
   : GOTO 600
0680 GOSUB '200(" "," ",8,0,"ENTER APPLICATION TO LOAD",2)
   : A$=Q6$
   : RETURN
0740 GOSUB '255
0770 GOSUB '200(" "," ",3,0,"ENTER ADDRESS TO LOAD FROM",2)
   : B$=Q6$
0800 IF B$=S$THEN 850
   : IF B$=" "THEN 740
   : MAT SEARCHSTR(S$(),4),=B$TO L$STEP 3
   : IF L$=HEX(0000)THEN 740
0850 GOSUB '205(1,B$,1)
   : RETURN
0910 GOSUB 800
   : DATA LOAD DC OPEN T#0,C$
   : DATA LOAD DC #0,B$()
   : $PACK(F=HEX(A003A008))B$(3)FROMB$,A$
   : DATA LOAD DC OPEN T#0,C$
   : DATA SAVE DC #0,B$()
   : LOAD DC T#1,A$
   : ERRORGOTO 1010
1010 PRINT HEX(010A07);A$;" IS NOT AT ADDRESS ";B$
   : GOSUB '254
   : GOTO 600
1070 PRINT AT(5,0);
   : PRINT "1  APPLICATION TO LOAD      - ";A$;TAB(80)
   : PRINT "2  APPLICATION DISK ADDRESS - ";B$
   : RETURN
1140 DEFFN'31
   : PRINT HEX(03);"LOADING SYSTEM MENU"
   : S8$="SYSTEM"
1170 LOAD DC T#0,"ISS.002M"
   : ERRORGOTO 1180
1180 PRINT HEX(010A);"MOUNT ISS DISK AT ADDRESS ";S$
   : GOSUB '254
   : GOTO 1170