image of READY prompt

Wang2200.org

Listing of file='ACCT080A' on disk='vmedia/701-2607C.wvd.zip'

# Sector 470, program filename = 'ACCT080A'
0010 REM ACCT080A, RELEASE 2.0, (06/01/79) THIS PROGRAM IS A COPYRIGHT PRODUCT
      OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED
0170 DIM K4$(5)33
   : GOTO 4000
4000 SELECT @PARTS0$
   : GOSUB '93(" ")
   : IF I0$=" "THEN 4840
   : K4$(1)="ALL CUSTOMERS"
   : K4$(2)="CUSTOMERS WITH CREDIT LIMIT"
   : K4$(3)="CUSTOMERS IN EXCESS OF LIMIT"
   : K4$(4)="CUSTOMERS WITHIN $XXXXXX OF LIMIT"
   : K4$(5)="CUSTOMERS WITHIN XX% OF LIMIT"
4100 L=L0
   : PRINT AT(4,0,);AT(5,0);,0;"= RETURN TO MENU"
   : FOR I=1TO 5
   : PRINT ,I;"= ";K4$(I)
   : NEXT I
   : GOSUB '100("0","5",1,0,"ENTER REPORT TYPE",1)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : K4=Q9
   : IF Q9=0THEN 4840
   : ON K4GOTO ,,,4220,4300
   : GOTO 4350
4220 GOSUB '100("0","999999",6,0,"ENTER DOLLAR AMOUNT",1)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : K=Q9
   : CONVERT Q9TO Q6$,(#######)
   : STR(Q6$,,POS(Q6$>"0")-1)=" "
   : STR(K4$(K4),19,6)=STR(Q6$,2)
   : GOTO 4350
4300 GOSUB '100("0","99",2,0,"ENTER PERCENT",1)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : K1=Q9
   : CONVERT Q9TO STR(K4$(K4),18,2),(##)
4350 PRINT AT(1,0,);AT(4,0,);"Processing customer ID ";HEX(06)
   : P1=0
   : GOSUB '90
   : GOSUB '235(1,0)
   : GOSUB '91
   : IF J0=7THEN 4100
   : IF J0>0THEN 4810
   : IF STR(T7$,6,1)=" "THEN 4510
4440 IF J0=7THEN GOSUB '92
   : GOSUB '237(1,0)
   : IF Q$="E"THEN 4750
   : GOSUB '91
   : IF J0=7THEN 4440
   : IF J0>0THEN 4810
   : IF STR(T7$,6,1)<>" "THEN 4440
4510 GOSUB '50(2," ")
   : PRINT AT(4,24);STR(C$,,Q0)
   : ON K4GOTO 4620,,4570,4590,4610
   : IF B0=0THEN 4440
   : GOTO 4620
4570 IF B+C0<=B0THEN 4440
   : GOTO 4620
4590 IF B+K+C0<B0THEN 4440
   : GOTO 4620
4610 IF K1*B0/100+B+C0<B0THEN 4440
4620 GOSUB '123(P4)
   : GOSUB '90
   : PRINT STR(C$,,Q0);TAB(3+Q0);STR(A1$,,MIN(27-Q0,LEN(A1$)));TAB(31);P$;TAB(
     45);U9$;TAB(55);
   : PRINTUSING "###,###",B0;
   : PRINT TAB(64);
   : PRINTUSING "###,###.##-",B;
   : PRINT TAB(77);
   : PRINTUSING "###,###.##-",C0;
   : PRINT TAB(90);
   : PRINTUSING "###,###.##-",B0-B-C0
   : L=L+1
   : GOTO 4440
4750 GOSUB '90
   : PRINT HEX(0A)
   : PRINT "END OF REPORT"
   : SELECT PRINT 005(80)
   : GOTO 4100
4810 PRINT AT(1,0,80)
   : GOSUB '254
4840 DEFFN'31
   : LOAD TM$
6020 DEFFN'90
   : SELECT PRINT 005(80)
   : Q6$=" "
   : KEYIN Q6$,6060,6060
6060 IF Q6$="P"THEN GOSUB '254
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : SELECT PRINT <I0$>(132)
   : IF L<L0THEN RETURN
   : P1=P1+1
   : PRINT HEX(0C0A0E);TAB(3);N2$
   : Q6$="CREDIT REPORT - "&K4$(K4)
   : PRINT TAB(66-LEN(Q6$)/2);Q6$;TAB(107);Q1$;TAB(117);"PAGE";TAB(122);P1
   : PRINT HEX(0A)
   : PRINT "CUST";TAB(45);"DATE LAST  CREDIT     CURRENT"
6160 PRINT TAB(1);"ID";TAB(3+Q0);"CUSTOMER NAME";TAB(31);"TELEPHONE NO";TAB(46
     );"PAYMENT";TAB(57);"LIMIT";TAB(67);"BALANCE";TAB(80);"ORDER $";TAB(90);"
     DIFFERENCE"
   : PRINT HEX(0A)
   : L=7
   : RETURN
9998 DEFFN'29"Q$=";HEX(22);"ACCT080A";HEX(22);":SCRATCH TQ$:SAVET$()Q$";HEX(0D
     )
9999 DEFFN'30"DIM Z$57:IF STR(I0$,,1)=HEX(20)THENI0$=HEX(323135):Z$=";HEX(22);
     "GBS/MVP - Print credit report.";HEX(22);":SELECT#15<I0$>:$OPEN#15:SELECT
     LIST<I0$>(132): LIST Z$:LIST Z$#:LIST Z$V:LIST Z$':$CLOSE#15:SELECTLIST00
     5(80)";HEX(0D)