image of READY prompt

Wang2200.org

Listing of file='INVC020A' on disk='vmedia/701-2607C.wvd.zip'

# Sector 113, program filename = 'INVC020A'
0010 REM INVC020A, RELEASE 2.0, (06/01/79) THIS PROGRAM IS A COPYRIGHT PRODUCT
      OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED
0170 DIM I9$1
   : GOTO 4000
4000 SELECT @PARTS0$
   : B6=20
   : C6=14
   : B7=14
   : C7=6
   : LIMITS T#3,S$(3),Q6,Q7,Q8
   : Q9=(Q8-2)/(Q7-Q6-1)
   : IF Q9>.8THEN PRINT AT(3,0);"Maintenance audit file is more than";INT(Q9*1
     00);"% full."
   : IF Q9<.95THEN 4130
   : GOSUB '254
   : GOSUB '31
4130 GOSUB '238(1)
   : GOSUB '100(" ",HEX(7F),Q0,0,"ENTER CUSTOMER ID. (OR END)",2)
   : IF Q6$=HEX(1F)OR Q6$="END"OR Q6$="end"THEN GOSUB '31
   : IF Q6$=" "THEN 4130
   : GOSUB '96(1)
   : C$=Q6$
   : GOSUB '100("0","380",3,0,"ENTER SHIP-TO NO. (0 = MASTER RECORD)",1)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : A$=" "
   : IF Q9=0THEN 4260
   : BIN(STR(C$,Q0+1))=INT((Q9+1)/2)+64
4240 A6=2-MOD(Q9,2)
   : A$="1"
4260 PRINT AT(4,0,);TAB(10);"Customer ID - ";STR(C$,,Q0);TAB(32);
   : IF Q9=0THEN PRINT "MASTER RECORD"
   : ELSE PRINT "SHIP-TO RECORD NO.";Q9
   : GOSUB '100("A,C,D","AaCcDdC ",1,1,"ENTER TRANSACTION TYPE (A = ADD, C = C
     HANGE, D = DELETE)",2)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : G1$(G0),I9$=Q6$
   : Q6$="Add   ChangeDelete"
4330 PRINT AT(4,0);STR(Q6$,Q9*6-5,6);
   : IF I9$<>"A"THEN 4660
   : Q6$=STR(C$,,Q0)
   : Q7$="Customer ID is already in the customer master file."
   : GOSUB '232(1,1,Q6$)
   : IF A$="1"THEN 4440
   : IF Q$="N"THEN 4540
   : GOTO 4520
4440 Q7$="There is no master record for customer."
   : IF Q$>" "THEN 4520
   : GOSUB '232(1,1,C$)
   : IF Q$=" "THEN 4690
   : IF Q$="N"THEN 4540
   : GOSUB '91
   : GOTO 4130
4520 PRINT AT(3,0,80);HEX(07);Q7$
   : GOTO 4130
4540 GOSUB '36
   : GOSUB '37
   : GOSUB '32
   : GOSUB '33
   : GOSUB '233(1,1,C$,0)
   : GOSUB '91
   : IF J0>0THEN 4130
   : GOSUB '40(2,A$)
   : G5$(G0)="New Customer"
   : GOSUB 5040
   : GOTO 4130
4660 GOSUB '232(1,1,C$)
   : GOSUB '91
   : IF J0>0THEN 4130
4690 GOSUB '50(2,A$)
   : IF T7$=C$THEN 4730
   : PRINT AT(3,0,80);HEX(07);"Record ID in key file does not match the record
      ID from the master file"
   : GOTO 4130
4730 GOSUB '37
   : IF I9$="D"THEN 4810
   : IF A$="1"AND I9$="A"THEN GOSUB '32
   : GOSUB '33
4770 DBACKSPACE #2,1S
   : GOSUB '40(2,A$)
   : GOTO 4130
4810 IF A$="1"OR B=0THEN 4840
   : PRINT AT(3,0,80);HEX(07);"Customer cannot be deleted, A/R balance is not
     zero"
   : GOTO 4130
4840 GOSUB '100("Y,N","YyNn",1,1,"DELETE (Y OR N)",2)
   : IF Q6$<>"Y"THEN 4130
   : IF A$="1"THEN 5000
4870 GOSUB '231(1,0,C$)
   : GOSUB '91
   : IF J0>0THEN 4130
   : C$=HEX(FF)
   : GOSUB '40(2," ")
   : G5$(G0)="Deleted customer"
   : C$=T7$
   : IF STR(T7$,Q0+1)=" "THEN GOSUB 5040
   : GOSUB '237(1,0)
   : IF Q$>" "THEN 4130
   : IF STR(C$,,Q0)<>STR(T7$,,Q0)THEN 4130
   : C$=T7$
   : GOTO 4870
5000 A1$(A6)="Deleted Ship-to"
   : A2$(A6),A3$(A6),A4$(A6),A5$(A6),E$(A6)=" "
   : GOTO 4770
5040 G2$(G0)=" "
   : G3$(G0)=A1$
5060 G0$(G0)="1"&C$
   : G0=G0+1
   : IF G0<4THEN RETURN
   : GOSUB '49(3)
   : G0=1
   : G0$()=ALL(FF)
   : Q$,Q7$=" "
   : IF Q9<.95THEN RETURN
   : GOSUB '254
5160 DEFFN'31
   : IF G0>1THEN GOSUB '49(3)
   : LOAD TM$
6020 DEFFN'36
   : A1$,A2$,A3$,A4$,A5$,C3$,C4$,N1$,G$,P$,P2$,P3$,P5$,A1$(),A2$(),A3$(),A4$()
     ,A5$(),E$()=" "
   : B0,B,M,M1,P2,P3,P4,P5=0
   : RETURN
6070 DEFFN'37
   : PRINT AT(5,0,)
   : G7=0
   : I9=14
   : IF A$="1"THEN I9=6
   : FOR I=1TO I9
   : GOSUB '35
   : NEXT I
   : RETURN
6170 DEFFN'33
   : CONVERT I9TO Q7$,(##)
   : PRINT AT(1,0,80);"ENTER LINE NO. ( 1 -";I9;") TO CORRECT  (0=NONE, -1=EXI
     T)"
   : GOSUB '100("-1",Q7$,2,0," ",1)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : I=Q9
   : IF I=-1THEN 6310
   : IF I=0THEN RETURN
   : Q7$=" "
   : G7=G7+1
   : GOSUB '35
   : IF I9$="C"THEN GOSUB 5060
   : GOTO 6170
6310 RETURN CLEAR
6320 IF I9$="A"OR G7=0THEN 4130
   : CONVERT MIN(G7,99)TO Q6$,(##)
   : G2$(G0)=Q6$&" previous edits for"
   : G3$(G0)="this customer are void."
   : GOSUB 5060
   : GOTO 4130
6390 DEFFN'32
   : G7=1
   : FOR I=1TO I9
   : Q7$=" "
   : GOSUB '35
   : NEXT I
   : RETURN
6470 DEFFN'34(Q6$,Q9,G5$(G0),Q7$,Q$(1),Q$(2),Q3,Q4,Q5)
   : IF G7>0THEN PRINT AT(1,0,80);"ENTER ";G5$(G0);Q7$
   : IF Q5<2THEN GOSUB 6730
   : G2$(G0)=Q6$
   : IF Q6$>" "AND Q5=2THEN Q5=3
   : IF Q9<>0AND Q5=1THEN Q5=0
   : IF G7>0THEN GOSUB '100(Q$(1),Q$(2),Q3,Q4," ",Q5)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : IF Q5<2THEN GOSUB 6730
   : G3$(G0)=Q6$
   : Q8=45
   : Q2=INT(I9/2)
   : IF A$="1"THEN Q2=I9
6600 IF I>Q2THEN 6660
   : PRINT AT(I+5,0,Q8);
   : PRINTUSING "##) ";I;
   : B8=Q8-B6-2
   : IF Q5<2THEN B8=B8+C6-Q3
   : GOTO 6700
6660 PRINT AT(I+5-Q2,Q8,80-Q8);
   : PRINTUSING "##) ";I;
   : B8=80-B7-2
   : IF Q5<2THEN B8=B8+C7-Q3
6700 PRINT G5$(G0);TAB(B8);Q6$
   : RETURN
6730 Q6$=ALL("#")
   : Q7$=STR(Q6$,,Q3)
   : IF Q4>0THEN Q7$=Q7$&"."&STR(Q6$,,Q4)
   : Q6$=ALL(00)
   : PRINTUSING TO Q6$,Q7$,Q9
   : Q6$=STR(Q6$,3,LEN(Q7$))
   : RETURN
6810 DEFFN'35
   : Q$=" "
   : IF A$=" "THEN ON IGOSUB 6870,6900,6930,6960,6990,7020,7050,7080,7110,7150
     ,7180,7220,7260,7300
   : ELSE ON IGOSUB 7330,7360,7390,7420,7450,7480
   : IF Q$>" "THEN 6810
   : RETURN
6870 GOSUB '34(A1$,0,"CUSTOMER NAME"," "," ",HEX(7F),21,0,2)
   : A1$=Q6$
   : RETURN
6900 GOSUB '34(A2$,0,"ADDRESS 1"," "," ",HEX(7F),20,0,2)
   : A2$=Q6$
   : RETURN
6930 GOSUB '34(A3$,0,"ADDRESS 2"," "," ",HEX(7F),20,0,2)
   : A3$=Q6$
   : RETURN
6960 GOSUB '34(A4$,0,"CITY,STATE"," "," ",HEX(7F),16,0,2)
   : A4$=Q6$
   : RETURN
6990 GOSUB '34(A5$,0,"ZIP CODE"," "," ",HEX(7F),5,0,2)
   : A5$=Q6$
   : RETURN
7020 GOSUB '34(C3$,0,"LOCATION CODE"," (not used)"," ",HEX(7F),6,0,2)
   : C3$=Q6$
   : RETURN
7050 GOSUB '34(C4$,0,"DISCOUNT CLASS"," (not used)"," ",HEX(7F),3,0,2)
   : C4$=Q6$
   : RETURN
7080 GOSUB '34(P$,0,"TELEPHONE NO."," "," ",HEX(7F),12,0,2)
   : P$=Q6$
   : RETURN
7110 GOSUB '34(N1$,0,"SALESMAN ID"," "," ",HEX(7F),VAL(Q0$(3)),0,2)
   : GOSUB '96(3)
   : N1$=Q6$
   : RETURN
7150 GOSUB '34(" ",B0,"CREDIT LIMIT"," (in dollars)","0","999999",6,0,1)
   : B0=Q9
   : RETURN
7180 IF NUM(G$)=2THEN CONVERT G$TO Q9
   : GOSUB '34(" ",Q9,"SVC CHG CODE"," ","0","17",2,0,1)
   : CONVERT Q9TO G$,(##)
   : RETURN
7220 IF NUM(P2$)=1THEN CONVERT P2$TO Q9
   : ELSE Q9=1
   : GOSUB '34(" ",Q9,"PRICE CODE"," (to select one of five inventory prices)"
     ,"1","5",1,0,1)
   : P2$=Q6$
   : RETURN
7260 IF NUM(P3$)=1THEN CONVERT P3$TO Q9
   : ELSE Q9=0
   : GOSUB '34(" ",Q9,"A/R CODE"," (0 = open item, 1 = balance forward)","0","
     1",1,0,1)
   : P3$=Q6$
   : RETURN
7300 GOSUB '34(P5$,0,"PARTIAL SHIP"," (Y OR N)","N,Y","YyNnY ",1,1,2)
   : P5$=Q6$
   : RETURN
7330 GOSUB '34(A1$(A6),0,"SHIP-TO NAME"," "," ",HEX(7F),21,0,2)
   : A1$(A6)=Q6$
   : RETURN
7360 GOSUB '34(A2$(A6),0,"ADDRESS 1"," (ship-to)"," ",HEX(7F),20,0,2)
   : A2$(A6)=Q6$
   : RETURN
7390 GOSUB '34(A3$(A6),0,"ADDRESS 2"," (ship-to)"," ",HEX(7F),20,0,2)
   : A3$(A6)=Q6$
   : RETURN
7420 GOSUB '34(A4$(A6),0,"CITY, STATE"," (ship-to)"," ",HEX(7F),16,0,2)
   : A4$(A6)=Q6$
   : RETURN
7450 GOSUB '34(A5$(A6),0,"ZIP CODE"," (ship-to)"," ",HEX(7F),5,0,2)
   : A5$(A6)=Q6$
   : RETURN
7480 GOSUB '34(E$(A6),0,"LOCATION CODE"," (ship-to)"," ",HEX(7F),6,0,2)
   : E$(A6)=Q6$
   : RETURN
9998 DEFFN'29"Q$=";HEX(22);"INVC020A";HEX(22);":SCRATCH TQ$:SAVET$()Q$";HEX(0D
     )
9999 DEFFN'30"DIM Z$57:IF STR(I0$,,1)=HEX(20)THENI0$=HEX(323135):Z$=";HEX(22);
     "GBS/MVP - Maintain customer master file.";HEX(22);":SELECT#15<I0$>:$OPEN
     #15:SELECTLIST<I0$>(132): LIST Z$:LIST Z$#:LIST Z$V:LIST Z$':$CLOSE#15:SE
     LECTLIST005(80)";HEX(0D)