image of READY prompt

Wang2200.org

Listing of file='INVT070A' on disk='vmedia/701-2616C.wvd.zip'

# Sector 360, program filename = 'INVT070A'
0010 REM INVT070A, RELEASE 2.0, (06/01/79) THIS PROGRAM IS A COPYRIGHT PRODUCT
      OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED
0020 REM ---------------------------------------------------------------------
0030 REM SYSTEM & MODULE   =  GBS/MVP INVENTORY SYSTEM, PHYSICAL INVENTORY ENT
     RY
0040 REM PROGRAM FUNCTION  =  ENTER RESULTS OF PHYSICAL INVENTORY COUNT
0050 REM DATE WRITTEN      =  08/12/79 MK
0060 REM LAST REVISION     =  08/12/79 MK
0070 REM ---------------------------------------------------------------------
0170     DIM K5$(50)4,L1$14
0198     GOTO 4000
3996 REM *************************
3997 REM ! INVENTORY TRANSACTION !
3998 REM *************************
3999 REM
4000     SELECT @PART S0$
4010     A6=37
   : REM START COLUMN FOR FIELD DISPLAY
4020     B6=8
   : REM STARTING LINE-MODIFIABLE FIELDS
4030     B$()="I"
4040     PACK(##)STR(B$(1),2)FROM S2
4050     N1$()=ALL(FF)
4060     L1$=HEX(A0)&BIN(Q0)&HEX(A002A001500350036204A0)&BIN(MIN(36-Q0,24))
4070     LIMITS T#2,S$(2),L9,Q7,Q8
   : REM INVENTORY FILE
4080 REM %CALCULATE AVAILABLE SPACE - TRANSACTION AUDIT FILE
4090     LIMITS T#3,S$(3),Q6,Q7,Q8
4100     Q9=(Q8-2)/(Q7-Q6-1)
4110     IF Q9>.8THEN PRINT AT(3,0,80);HEX(07);"Transaction audit file is";INT
     (Q9*100);"% full."
4120     IF Q9>=.95THEN 4730
4130 REM %CHECK INVENTORY SORT TAGS FILE
4140     LIMITS T#4,S$(4),Q6,Q7,Q8
4150     IF Q8>2 THEN 4200
4160     PRINT AT(1,0,80);"Physical inventory sheets have not been printed.";H
     EX(07)
4170     GOTO 4730
4180   % ##,###,###-
4190 REM %ACQUIRE STARTING POINT
4200     PRINT AT(4,0,);"This program displays products in stock location code
      sequence and accepts";HEX(0D0A);"physical count entries in the order in
     which they appear on the physical"
4202     PRINT "inventory sheets. The 'Enter Inventory Transactions' program p
     rovides for";HEX(0D0A);"entering physical counts in a different sequence.
     "
4208     CONVERT (Q8-2)*50 TO Q$(2),(########)
4210     GOSUB '100("1",Q$(2),ROUND((LOG(999999/Q8)/LOG(10),0),0,"ENTER STARTI
     NG ITEM NO.",1)
4220     IF Q6$=HEX(1F)THEN GOSUB '31
4225     Q9=Q9-1
4230     DSKIP #4,INT(Q9/50)S
4240     K5$()=ALL(FF)
4250     J=MOD(Q9,50)
4260     IF J>0 THEN DATA LOAD DC #4,K5$()
4270 REM %PROCESS EACH PRODUCT
4280     J=MOD(J,50)+1
4290     IF J=1THEN DATA LOAD DC #4,K5$()
4300     IF END  THEN K5$()=ALL(FF)
4310     IF STR(K5$(J),,1)=HEX(FF)THEN 4670
4320     DBACKSPACE #2,BEG
4330     DSKIP #2,VAL(STR(K5$(J),,2),2)-L9S
4340     GOSUB '52(2)
4350     IF F1$=HEX(FF) THEN 4280
   : REM WAS PRODUCT DELETED AFTER SORT?
4360     PRINT AT(4,0,);,"PRODUCT ID";TAB(A6);F1$
4370     PRINT ,"DESCRIPTION";TAB(A6);F2$
4380     PRINT ,"U/M";TAB(A6);F3$
4390     PRINT AT(B6+1,0,0);,"PHYSICAL ON HAND";TAB(A6);
4400     PRINTUSING 4180,F5
4410     PRINT ,"PHYSICAL COUNT";TAB(A6);
4420     PRINTUSING 4180,E0
4430     GOSUB '100("-9999999","9999999",7,0,"ENTER QUANTITY",1)
4440     IF Q6$=HEX(1F)THEN GOSUB '31
4450     P9=Q9
4460     PRINT AT(B6+3,0);,"PHYSICAL ENTRY";TAB(A6);
4470     PRINTUSING 4180,P9
4480     E0=E0+P9
4490 REM CHECK ENTRY
4500     GOSUB '100("Y,N","YyY Nn",1,1,"IS ENTRY OK  (Y OR N)",2)
4510     IF Q6$=HEX(1F)THEN GOSUB '31
4520     IF Q6$="N"THEN 4430
4530 REM %MOVE DATA TO TRANSACTION AUDIT FILE
4540     $PACK(F=L1$)N1$(G0)FROMF1$,F3$,A7$,0,P9,0,F2$
4545     P7=P7+1
4550     P8=P8+P9
4560 REM WRITE ADJUSTED INVENTORY RECORD
4570     DBACKSPACE #2,1S
4580     GOSUB '42(2)
4590 REM %WRITE TO TRANSACTION AUDIT FILE
4600     G0=G0+1
4610     IF G0<6THEN 4280
4620     GOSUB '48(3)
4630     G0=1
4640     N1$()=ALL(FF)
4650     IF Q9<.95 THEN 4280
4660 REM %END OF PROGRAM
4670     $PACK(F=L1$)N1$(G0)FROM" "," ","T",0,MIN(P8,99999),0,"PHYSICAL COUNT
     TOTAL"
4680     GOSUB '48(3)
4690     PRINT AT(0,0,);AT(B6,0);"NUMBER OF PRODUCTS PROCESSED";TAB(A6);
4700     PRINTUSING 4180,P7
4710     PRINT "BATCH TOTAL - ALL PRODUCTS";TAB(A6);
4720     PRINTUSING 4180,P8
4730     GOSUB '254
4740 REM %LOAD MENU
4750     DEFFN'31
4760     LOAD TM$
9000 REM %^VARIABLES
9020 REM      A9$ = PACK SPECIFICATION FOR TRANSACTION AUDIT FILE - INVENTORY
9120 REM       P8 = PHYSICAL ENTRY - TOTAL
9130 REM       P9 = PHYSICAL ENTRY
9140 REM $
9998 DEFFN'29"Q$=";HEX(22);"INVT070A";HEX(22);":SCRATCH TQ$:SAVET$()Q$";HEX(0D
     )
9999 DEFFN'30"DIM Z$57:IF STR(I0$,,1)=HEX(20)THENI0$=HEX(323135):Z$=";HEX(22);
     "GBS/MVP - Enter inventory transactions.";HEX(22);":SELECT#15<I0$>:$OPEN#
     15:SELECTLIST<I0$>(132): LIST Z$:LIST Z$#:LIST Z$V:LIST Z$':$CLOSE#15:SEL
     ECTLIST005(80)";HEX(0D)