image of READY prompt

Wang2200.org

Listing of file='OREN110D' on disk='vmedia/701-2616C.wvd.zip'

# Sector 596, program filename = 'OREN110D'
0010 REM OREN110D, RELEASE 2.0, (06/01/79) THIS PROGRAM IS A COPYRIGHT PRODUCT
      OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED
0020 REM -------------------------------------------------------------------
0030 REM SYSTEM & MODULE   =  GBS/MVP ORDER ENTRY SYSTEM, ANALYZE ORDERS
0040 REM PROGRAM FUNCTION  =  PRINT ORDER ANALYSIS USING SORTED EXTRACT FILE
0050 REM DATE WRITTEN      =  08/13/78 MK
0060 REM LAST REVISION     =  08/12/79 MK
0070 REM -------------------------------------------------------------------
0170     COM K5$(50)4,K6$(4)64,K6$Q0,A6$1
0198     GOTO 4000
3996 REM **********************************************
3997 REM ! READ PRODUCTS FROM OPEN ORDER FILE , PRINT !
3998 REM **********************************************
3999 REM
4000     SELECT @PARTS0$
4010     A6$=STR(M$(),30)
   : REM SAVE REPORT TYPE
4020     M$=STR(M$(),241,8)
   : REM SAVE MENU NAME
4030     Q9=VAL(STR(M$(),32))
   : REM BLOCKING FACTOR
4040     MAT REDIM K6$(Q9)Q0+8
   : REM ORDER ANALYSIS BUFFER
4050     %###,###
4060     K6$=HEX(00)
4070     PRINT HEX(03);TAB(15);"ORDER ANALYSIS BY PRODUCT - PRINT"
4080     SELECT PRINT <STR(M$(),19,3)>(132)
   : REM SELECT PRINTER
4090     DATA LOAD DC OPEN T#1,S$(1)
   : REM RE-OPEN ORDER ANALYSIS
4100     DATA LOAD DC OPEN T#2,S$(2)
   : REM OPEN USER PORTION OF FILE
4110     DATA LOAD DC OPEN T#4,S$(4)
   : REM OPEN OUTPUT FILE
4120     L=60
4130     GOSUB '90
   : REM TOP OF PAGE
4140 REM %PROCESS TAG FILE, ANALYSIS FILE AND OPEN ORDER FILE
4150     J=0
4160     J=MOD(J,50)+1
4170     IF J=1 THEN DATA LOAD DC #4,K5$()
   : REM READ A SET OF TAGS
4180     IF END  THEN K5$()=ALL(FF)
   : REM END OF TAG FILE?
4190     K6$()=ALL(FF)
4200     I=1
4210     IF STR(K5$(J),,1)=HEX(FF) THEN 4330
   : REM END OF TAG FILE?
4220     DATA LOAD DA T#1,(STR(K5$(J),,2))K6$()
   : REM READ INTERIM FILE
4230     I=VAL(STR(K5$(J),3,2),2)
4240     IF STR(K6$(I),,1)=HEX(FF)THEN 4330
   : REM END OF ANALYSIS FILE?
4250     DBACKSPACE #2,BEG
4260     DSKIP #2,VAL(STR(K6$(I),Q0+4,2),2)S
4270     GOSUB '57(2,1)
   : REM HEADER HAS CUSTOMER NAME
4280     DBACKSPACE #2,BEG
4290     DSKIP #2,VAL(STR(K6$(I),Q0+6,2),2)S
4300     GOSUB '57(2,2)
4310     CONVERT STR(K6$(I),Q0+8,1) TO K
4320     GOSUB '90
4330     IF K6$=HEX(00)THEN K6$=STR(K6$(I),,Q0)
   : REM FIRST TIME THROUGH
4340     IF K6$=STR(K6$(I),,Q0)THEN 4420
   : REM CHECK PRODUCT ID BREAK
4350     K6$=STR(K6$(I),,Q0)
4360     PRINT TAB(20);"PRODUCT TOTAL";TAB(94);
4370     PRINTUSING 4050,K6
4380     PRINT HEX(0A)
4390     L=L+2
4400     K6=0
4410 REM EXIT, IF END OF FILE
4420     IF STR(K5$(J),,1)=HEX(FF) OR STR(K6$(I),,1)=HEX(FF) THEN GOSUB '31
4430     K6 = K6 + C3(K)
4440     CONVERT D4TO Q6$,(######)
4450     PRINT C2$(K);TAB(14);C3$(K);TAB(40);C1$;TAB(47);B0$;TAB(70);HEXOF(STR
     (O2$,,3));"-";HEXOF(A0$);TAB(81);STR(Q6$,,2);"/";STR(Q6$,3,2);"/";STR(Q6$
     ,5,2);TAB(94);
4460     PRINTUSING 4050,C3(K)
4470     L=L+1
4480     GOTO 4160
4490 REM END OF PROGRAM
4500     DEFFN'31
4510     GOSUB '219(S$(1),1,S2," ",0)
4520     GOSUB '219(S$(2),2,S2," ",0)
4530     GOSUB '219(S$(3),3,S2," ",0)
4540     COM CLEAR I
4550     LOAD TM$
   : ERRORLOAD T"SYS MENU"
6000 REM %^SUBROUTINES
6010 REM PAGE EJECT ROUTINE
6020     DEFFN'90
6030     Q6$=" "
6040     KEYIN Q6$,6050,6050
   : REM OPERATOR INTERRUPT CHECK
6050     IF Q6$="P" THEN GOSUB '254
6060     IF Q6$=HEX(1F) THEN GOSUB '31
6070     IF L <= 55 THEN RETURN
   : REM LINE COUNT CHECK
6080     P1 = P1 + 1
6090     PRINT HEX(0C0A0E);TAB(3);N2$
   : REM PRINT COMPANY NAME
6100     Q6$="ORDER ANALYSIS BY PRODUCT -"
6110     IF A6$="A" THEN Q6$=Q6$&" ALL ORDERS"
   : ELSE Q6$=Q6$&" BACKORDERS"
6120     PRINT TAB(66-LEN(Q6$)/2);Q6$;TAB(110);Q1$;TAB(122);"PAGE ";P1
6130     PRINT HEX(0A)
6140     PRINT TAB(83);"ORDER";TAB(93);"QUANTITY"
6150     PRINT "PRODUCT NO.";TAB(14);"DESCRIPTION";TAB(39);"CUST ID";TAB(47);"
     NAME";TAB(70);"ORDER NO.";TAB(84);"DATE";TAB(94);"ORDERED"
6160     PRINT HEX(0A)
6170     L = 7
6180     RETURN
9000 REM %VARIABLES
9010 REM      A6$1 = TYPE OF REPORT
9020 REM        K6 = RECORD COUNT WITHIN SECTOR
9030 REM     K6$Q0 = PREVIOUS PRODUCT ID
9040 REM     K6$() = DETAIL RECORDS (ORDER ANALYSIS FILE)
9050 REM $
9998 DEFFN'29"Q$=";HEX(22);"OREN110D";HEX(22);":SCRATCH TQ$:SAVET$()Q$";HEX(0D
     )
9999 DEFFN'30"DIM Z$57:IF STR(I0$,,1)=HEX(20)THENI0$=HEX(323135):Z$=";HEX(22);
     "GBS/MVP - Print order analysis.";HEX(22);":SELECT#15<I0$>:$OPEN#15:SELEC
     TLIST<I0$>(132): LIST Z$:LIST Z$#:LIST Z$V:LIST Z$':$CLOSE#15:SELECTLIST0
     05(80)";HEX(0D)