image of READY prompt

Wang2200.org

Listing of file='ACPA020A' on disk='vmedia/701-2652C.wvd.zip'

# Sector 205, program filename = 'ACPA020A'
0010 REM ACPA020A, RELEASE 2.3, (12/11/80) THIS PROGRAM IS A COPYRIGHT PRODUCT
      OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED
0170 DIM B6(4),B6$(6),D9$15,C6$Q4,C7$Q6
   : GOTO 4000
4000 SELECT @PARTS0$
   : PRINT HEX(03);TAB(19);"A/P OPEN ITEM MAINTENANCE"
   : B6=24
   : C6=08
   : G0=1
   : D8=VAL(Q0$(6))
   : I9=7
   : LIMITS T#3,S$(3),Q6,Q7,Q8
   : Q9=(Q8-2)/(Q7-Q6-1)
   : IF Q9>.8THEN PRINT AT(3,0);"Maintenance audit file is more than";INT(Q9*1
     00);"% full."
   : IF Q9<.95THEN 4140
   : GOSUB '254
   : GOSUB '31
4140 GOSUB '238(2)
   : GOSUB '100(" ",HEX(7F),Q0,0,"ENTER VENDOR ID. (OR END)",2)
   : IF Q6$=HEX(1F)OR Q6$="END"OR Q6$="end"THEN GOSUB '31
   : IF Q6$=" "THEN 4140
   : GOSUB '96(4)
   : C6$=Q6$
   : PRINT AT(4,0,);TAB(5);"VENDOR ID - ";C6$
   : GOSUB '232(2,0,C6$)
   : GOSUB '91
   : IF J0=0OR J0=7THEN 4203
   : PRINT AT(3,0,80);HEX(07);"Illegal vendor ID, re-enter"
   : GOTO 4140
4203 GOSUB '100(" ",HEX(7F),8,0,"ENTER INVOICE NUMBER (OR END)",2)
   : IF Q6$=HEX(1F)OR Q6$="END"OR Q6$="end"THEN GOSUB '31
   : IF Q6$=" "THEN 4203
   : GOSUB '96(6)
   : C7$=Q6$
   : C9$=STR(C6$,,VAL(Q0$(4)))&C7$
   : GOSUB '232(1,0,C9$)
   : GOSUB '237(1,1)
   : J$(1)=" "
   : GOSUB '91
   : IF J0=1THEN T7$=ALL(FF)
   : IF J0=7THEN 4140
   : IF J0<2THEN 4350
4320 PRINT AT(1,0,80);"PROGRAM WILL BE TERMINATED"
   : PRINT AT(3,16,64);Q7$
   : GOTO 4830
4350 IF STR(T7$,1,Q0+D8)=STR(C9$,1,Q0+D8)THEN 4480
   : PRINT AT(3,0,80);HEX(07);"Record not found"
   : GOTO 4140
4480 GOSUB '71(2,Q)
   : C7$=C1$(Q)
   : GOSUB '37
   : GOSUB '33
   : DBACKSPACE #2,1S
   : GOSUB '61(2,Q)
   : GOSUB '238(1)
   : GOSUB '237(1,1)
   : J$(1)=" "
   : GOSUB '91
   : IF J0=1OR J0=7THEN 4140
   : IF J0<>0THEN 4320
   : IF STR(T7$,1,Q0)<>STR(C9$,1,Q0)THEN 4140
   : C9$=T7$
   : GOSUB '100("Y,N","YyY Nn",1,1,"NEXT INVOICE FOR THIS VENDOR?  (Y OR N)",2
     )
   : IF Q6$="N"THEN 4140
   : GOTO 4480
4750 G0$(G0)="@"&C9$
   : G1$(G0)="C"
   : G0=G0+1
   : IF G0<4THEN RETURN
   : GOSUB '49(3)
   : G0=1
   : G0$()=ALL(FF)
   : IF Q9<.95THEN RETURN
4830 GOSUB '254
4850 DEFFN'31
   : IF G0>1THEN GOSUB '49(3)
   : LOAD TM$
6060 DEFFN'37
   : Q9=POS(" CEPX"=C3$(Q))
   : IF Q9>5OR Q9<1THEN Q9=1
   : Q6$="INVOICE  CR MEMO  E-PAYMENTP-PAYMENTX-PAYMENT"
   : Q7$=STR(Q6$,Q9*9-8,9)
   : PRINT AT(4,25);"INVOICE NUMBER - ";C7$
   : PRINT AT(4,50,30);"***";Q7$;"***"
   : PRINT AT(5,0,)
   : G7=0
   : FOR I=1TO I9
   : GOSUB '35
   : NEXT I
   : RETURN
6150 DEFFN'33
   : CONVERT I9TO Q7$,(##)
   : PRINT AT(1,0,80);"ENTER ITEM NO.(0=END, -1=VOID)";
   : GOSUB '100("-1",Q7$,2,0," ",1)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : I,J9=Q9
   : IF I=-1THEN 6290
   : IF I=0THEN RETURN
   : IF C3$(Q)=" "AND I=7THEN 6271
   : IF C3$(Q)="C"THEN ON IGOTO ,6271,6271,6271,,6271,6271
   : IF C3$(Q)="E"OR C3$(Q)="X"OR C3$(Q)="P"THEN ON IGOTO ,6271,6271,,,,6271
   : Q7$=" "
6240 G7=G7+1
   : GOSUB '35
   : GOSUB 4750
   : GOTO 6150
6271 PRINT AT(3,0,80);"Illegal field selection, re-enter.";HEX(07)
   : INIT(20)Q$()
   : GOTO 6150
6290 RETURN CLEAR
6300 IF G7=0THEN 4140
   : CONVERT MIN(G7,99)TO Q6$,(##)
   : G2$(G0)=Q6$&" previous edits for"
   : G3$(G0)="this open item are void."
   : G5$(G0)=" "
   : GOSUB 4750
   : GOTO 4140
6450 DEFFN'34(Q6$,Q9,G5$(G0),Q7$,Q$(1),Q$(2),Q3,Q4,Q5)
   : IF G7>0THEN PRINT AT(1,0,80);"ENTER ";G5$(G0);Q7$
   : IF Q5<2THEN GOSUB 6650
   : G2$(G0)=Q6$
   : IF Q6$>" "AND Q5=2THEN Q5=3
   : IF Q9<>0AND Q5=1THEN Q5=0
   : IF G7>0THEN GOSUB '100(Q$(1),Q$(2),Q3,Q4," ",Q5)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : IF Q5<2THEN GOSUB 6650
   : G3$(G0)=Q6$
   : Q8=50
   : PRINT AT(I+5,0,Q8);
   : PRINTUSING "##) ";I;
6560 B8=Q8-B6-2
   : IF Q5<2THEN B8=B8+C6-Q3
   : PRINT G5$(G0);TAB(B8);Q6$
   : RETURN
6650 Q6$=ALL("#")
   : Q7$=STR(Q6$,,Q3)
   : IF Q4>0THEN Q7$=Q7$&"."&STR(Q6$,,Q4)
   : Q7$=Q7$&"-"
   : Q6$=ALL(00)
   : PRINTUSING TO Q6$,Q7$,Q9
   : Q6$=STR(Q6$,3,LEN(Q7$))
   : RETURN
6730 DEFFN'35
   : Q$=" "
   : ON IGOSUB 6800,6830,6860,6890,6920,6945,6980
   : IF Q$>" "THEN 6730
   : RETURN
6800 GOSUB '34(C4$(Q),0,"P. O. NUMBER"," "," ",HEX(7F),D8,0,2)
   : C4$(Q)=Q6$
   : RETURN
6830 GOSUB '34(" ",B0(Q),"DISCOUNT %"," ","0","100.00",2,8,1)
   : B0(Q)=Q9
   : RETURN
6860 GOSUB '34(" ",B1(Q),"PARTIAL PAYMENT"," ","0","9999999.99",7,2,1)
   : IF Q9<B(Q)THEN 6870
   : PRINT AT(3,0,80);HEX(07);"Partial payment amount must be less than gross
     amount, re-enter."
   : GOTO 6860
6870 B1(Q)=Q9
   : RETURN
6890 GOSUB '34(" ",B2(Q),"CHECK NUMBER"," ","0","99999999",8,0,1)
   : B2(Q)=Q9
   : RETURN
6920 Q7$=" MM/DD/YY"
   : IF C3$(Q)=" "THEN Q7$=Q7$&" (OR "&HEX(22)&"HOLD"&HEX(2229)
   : IF B4(Q)=99999THEN U9$="HOLD"
   : ELSE GOSUB '123(B4(Q))
   : GOSUB '34(U9$,0,"DUE DATE"," "," ",HEX(7F),8,0,2)
   : IF Q6$="HOLD"AND C3$(Q)<>" "THEN 6939
   : IF Q6$="HOLD"THEN U9=99999
   : ELSE GOSUB 6959
   : B4(Q)=U9
   : U9=0
   : RETURN
6939 PRINT AT(3,0,80);"Holds may be placed on invoices only, re-enter"
   : GOTO 6920
6945 GOSUB '123(B5(Q))
   : GOSUB '34(U9$,0,"DATE PAID","  MM/DD/YY"," ",HEX(7F),8,0,2)
   : GOSUB 6959
   : B5(Q)=U9
   : U9=0
   : RETURN
6959 IF G7=0THEN RETURN
   : GOSUB '121(Q6$)
   : IF Q6$<>"E"THEN 6965
   : PRINT AT(3,0,80);"Illegal date, re-enter."
   : GOTO 6973
6965 IF U9>=B3(Q)THEN RETURN
   : GOSUB '123(B3(Q))
   : Q6$="Date must equal or exceed "&U9$&", re-enter."
6973 RETURN CLEAR
6975 IF I=5THEN 6920
   : ELSE GOTO 6945
6980 GOSUB '34(" ",B(Q),"GROSS AMOUNT"," ","0","99999999.99",8,2,1)
   : B(Q)=Q9
   : RETURN
9998 DEFFN'29"Q$=";HEX(22);"ACPA020A";HEX(22);":SCRATCH TQ$:SAVE T$()Q$";HEX(0
     D)
9999 DEFFN'30"DIM Z$57:IF STR(I0$,,1)=HEX(20)THENI0$=HEX(323135):Z$=";HEX(22);
     "GBS/MVP - A/P OPEN ITEM MAINTENANCE";HEX(22);":SELECT#15<I0$>:$OPEN#15:S
     ELECTLIST<I0$>(132): LIST Z$:LIST Z$#:LIST Z$V:LIST Z$':LISTZ$THEX(7A):$C
     LOSE#15:SELECTLIST005(80)";HEX(0D)