image of READY prompt

Wang2200.org

Listing of file='ACPA040A' on disk='vmedia/701-2652C.wvd.zip'

# Sector 76, program filename = 'ACPA040A'
0010 REM ACPA040A, RELEASE 1-0, (01/31/79)   THIS PROGRAM IS A COPYRIGHT PRODU
     CT OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBIT
     ED
0170 DIM A6$4,A7$6,A9$12,B6$5
   : DIM B6(4),C6(4)
   : GOTO 4000
4000 SELECT @PARTS0$
   : A9$="####,###.##-"
   : GOSUB '93(" ")
   : IF I0$=" "THEN 5900
4250 GOSUB '100(" ",HEX(7F),8,0,"ENTER DUE DATE (MM/DD/YY)",2)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : GOSUB '121(Q6$)
   : IF Q6$<>"E"THEN 4310
   : PRINT AT(3,0,80);"Invalid date, re-enter";HEX(07)
   : GOTO 4250
4310 GOSUB '123(U9)
   : D6=U9
   : D6$=U9$
   : PRINT AT(4,23);"OPTIONS AVAILABLE ===>"
   : PRINT TAB(25);"1) LIST ALL"
   : PRINT TAB(25);"2) LIST ONLY ITEMS DUE"
   : PRINT TAB(25);"3) LIST ONLY TOTALS"
   : GOSUB '100("1","3",1,0,"ENTER OPTION DESIRED",1)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : N7=Q9
   : PRINT AT(4,0,)
   : P1=0
   : L=L0+5
   : GOSUB '235(2,0)
4490 Q6$="A/P OPEN ITEM FILE"
   : IF Q$<>" "THEN 5980
   : A6=Q
   : GOSUB '71(4,A6)
   : DBACKSPACE #4,1S
   : C5$(A6)=" "
   : GOSUB '61(4,A6)
   : PRINT AT(5,0,80);"Processing Vendor ID.";HEX(06)
4570 B6$=C0$(A6)
   : SELECT PRINT 005(80)
   : PRINT AT(5,0,80);"Processing Vendor ID. ";B6$
   : GOSUB '232(1,0,B6$)
   : Q6$=B6$&" - VENDOR MASTER FILE"
   : IF Q$<>" "THEN 5980
   : GOSUB '70(2)
   : A7,N9,D7,D8,K,E6=0
   : MAT B6=ZER
   : GOTO 4800
4690 GOSUB '237(2,0)
   : IF Q$="E"THEN 5340
   : IF Q$<>" "THEN 5980
   : A6=Q
   : GOSUB '71(4,A6)
   : DBACKSPACE #4,1S
   : C5$(A6)=" "
   : GOSUB '61(4,A6)
   : IF B6$<>C0$(A6)THEN 5340
4800 IF C3$(A6)<>" "THEN B(A6)=-B(A6)
   : N6=B(A6)-ROUND((B(A6)*B0(A6)/100,2)
   : IF C3$(A6)<>"E"THEN N9=N9+N6
   : ELSE E8=E8+N6
   : IF C3$(A6)<>"E"THEN A7=A7+B(A6)
   : ELSE GOTO 4690
   : IF N7=2AND B4(A6)>D6THEN 4690
   : IF B1(A6)<>0THEN D7=B1(A6)-ROUND((B1(A6)*B0(A6)/100,2)
   : ELSE D7=N6
   : F7=F7+ROUND((B(A6)*B0(A6)/100,2)
   : F6=F6+B(A6)
   : IF N7=3THEN 5090
4910 GOSUB '123(B3(A6))
   : IF K1=1THEN 4990
   : K1=1
   : L=L+3
   : GOSUB '90
   : PRINT
   : PRINT TAB(6);"VENDOR";TAB(15);A$;TAB(23);A1$
   : PRINT
4990 L=L+1
   : GOSUB '90
   : PRINT C1$(A6);TAB(11);U9$;TAB(20);
   : PRINTUSING A9$,B(A6);ROUND((B0(A6)*B(A6)/100,2);N6;
   : Q6$,U9$="**HOLD**"
   : IF B4(A6)<>99999THEN GOSUB '123(B4(A6))
   : IF Q6$="E"THEN U9$="NO DATE"
   : PRINT TAB(57);U9$;
5090 Q7=INT(365.25*(INT(B4(A6)/1E3)-1))+MOD(B4(A6),1E3)
   : Q6=INT(365.25*(INT(D6/1E3)-1))+MOD(D6,1E3)
   : IF Q7>Q6THEN Q9=INT((Q7-Q6+59)/30)
   : ELSE Q9=1
   : Q9=MIN(Q9,4)
   : B6(Q9)=B6(Q9)+N6
   : IF Q9=1THEN Q6=N6
   : ELSE Q6=D7
   : C6(Q9)=C6(Q9)+Q6
   : IF Q9=1THEN K=1
   : IF Q9=1THEN E6=E6+D7
   : IF Q9=1AND N7=3THEN D8=D8+D7
   : IF N7=3THEN 4690
   : PRINT TAB(54+Q9*12);
   : PRINTUSING A9$,N6;
5250 IF B1(A6)=0OR B4(A6)>D6THEN 5290
   : PRINT TAB(114);
   : PRINTUSING A9$,D7;
   : PRINT TAB(126);"PART";
5290 PRINT
   : B1(A6)=0
   : GOTO 4690
5340 IF N7=3THEN 5520
   : IF K1=0THEN 5520
   : K1=0
   : A6$,A7$=" "
   : IF E6<0OR E6>N9OR A7<B6(1)THEN A7$="NO PAY"
   : ELSE D8=E6
   : IF E6=0AND K=1THEN A6$="0.00"
   : L=L+2
   : GOSUB '90
   : PRINT
   : PRINT TAB(21);"BALANCE DUE";
   : PRINT TAB(66);
   : PRINTUSING A9$,B6(1);B6(2);B6(3);B6(4);
   : IF D8<>0THEN PRINTUSING A9$,D8;
   : IF D8<>0THEN PRINT "*";A7$
   : ELSE PRINT TAB(121);A6$;TAB(126);A7$
   : D9=D9+D8
   : D8=0
5520 IF A7=A2THEN 5620
   : L=L+2
   : GOSUB '90
   : PRINT
   : PRINT TAB(5);A$;" ";A1$;" BALANCE CORRECTED FROM ";
   : PRINTUSING A9$,A2;
   : PRINT " TO ";
   : PRINTUSING A9$,A7
   : A2=A7
5620 IF N7=3AND D8>0AND D8<=A2THEN D9=D9+D8
   : IF E6<0OR E6>N9OR A2<B6(1)THEN B4$="1"
   : ELSE B4$=" "
   : DBACKSPACE #2,1S
   : GOSUB '60(2)
   : IF Q$<>"E"THEN 4570
   : L=L+4
   : GOSUB '90
   : PRINT HEX(0A0A0A0A)
   : PRINT TAB(1);"REPORT TOTALS";TAB(20);
   : PRINTUSING A9$,F6;F7;F6-F7;
   : PRINT TAB(66);
   : PRINTUSING A9$,C6(1);C6(2);C6(3);C6(4);D9
   : L=L+1
   : GOSUB '90
5790 PRINT TAB(1);"EXTERNAL PAYMENTS FOR ITEMS NOT ON FILE";TAB(66);
   : PRINTUSING A9$,E8
   : PRINT HEX(0C)
   : SELECT PRINT 005(80)
   : $OPEN #5
   : GOSUB '66(5,0,1)
   : M(3)=D6
   : F5$(2)=" "
   : GOSUB '66(5,0,0)
5900 DEFFN'31
   : LOAD TM$
5980 GOSUB '91
   : PRINT AT(1,0,80);"PROGRAM WILL BE TERMINATED";AT(3,17);"- ";Q6$
   : GOSUB '254
   : GOTO 5900
7040 DEFFN'90
   : Q6$=" "
   : KEYIN Q6$,7080,7080
7080 IF Q6$="P"THEN GOSUB '254
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : SELECT PRINT <I0$>(132)
   : IF L<L0THEN RETURN
   : P1=P1+1
   : PRINT HEX(0C0A0D0E);TAB(3);N2$
   : IF N7=2THEN Q9=44
   : ELSE Q9=53
   : Q6$="DETAIL     CURRENT DUETOTALS"
   : Q7$=STR(Q6$,N7*11-10,11)
   : PRINT TAB(Q9);"CASH REQUIREMENTS ";Q7$;" REPORT";TAB(98);"REPORT DATE ";Q
     1$;TAB(122);"PAGE";P1
7180 PRINT TAB(101);"DUE DATE ";D6$
   : PRINT
   : PRINT " INVOICE";TAB(12);"INVOICE";TAB(26);"GROSS";TAB(39);"DISC";TAB(52)
     ;"NET";TAB(62);"DUE";TAB(119);"CASH"
7210 PRINT TAB(5);"NO";TAB(14);"DATE";TAB(28);"AMT";TAB(40);"AMT";TAB(52);"AMT
     ";TAB(61);"DATE";TAB(70);"CURRENT";TAB(83);"1 - 30";TAB(94);"31 - 60";TAB
     (106);"OVER 60";TAB(119);"RQMT";TAB(125);"REMARKS"
   : PRINT
   : L=8
   : RETURN
9999 DEFFN'29"Q$= ";HEX(22);"ACPA040A";HEX(22);":SCRATCH T Q$:SAVE T$()Q$";HEX
     (0D)