image of READY prompt

Wang2200.org

Listing of file='UTILMENU' on disk='vmedia/701-2654C.wvd.zip'

# Sector 648, program filename = 'UTILMENU'
0010 REM UTILMENU, RELEASE 2.2, (09/11/80) THIS PROGRAM IS A COPYRIGHT PRODUCT
      OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED
0020 REM ---------------------------------------------------------------
0030 REM SYSTEM & MODULE   =  GBS/MVP, UTILITIES MENU
0040 REM PROGRAM FUNCTION  =  DISPLAY UTILITIES MENU
0060 REM LAST REVISION     =  09/11/80 TM
0065 REM THIS PROGRAM WAS UPGRADED TO 2.2 BY ERRATA 1146 + 1170
0070 REM ---------------------------------------------------------------
0170     COM I,Q,M5$,M0,M$8,O0
   : REM MENU VARIABLES
0172     COM Q$(2)80,Q6$80,Q7$80
   : REM DATA ENTRY VARIABLES USED BY MENU
0174     COM Q3,Q4,Q5,Q6,Q7,Q8,Q9
   : REM DATA ENTRY VARIABLES USED BY MENU
0176     COM M2$4,M3$1,M(17)
   : REM CONTROL FILE VARIABLES
3996 REM ***********************
3997 REM ! GBS/MVP SYSTEM MENU !
3998 REM ***********************
3999 REM
4000     DIM A6$(8)124
4005     N=9
   : REM NUMBER OF PROGRAMS ON MENU
4010     I=37
   : REM STARTING COLUMN - RIGHT SIDE OF MENU
4020     Q9=37+VAL(Q0$(1))
   : REM A/R OPEN ITEM RECORD LENGTH
4030     M0=INT(249/Q9)
   : REM 'BLOCKING FACTOR' - A/R OPEN ITEMS
4032     Q9=49+VAL(Q0$(2))
   : REM ORDER LINE ITEM RECORD LENGTH
4034     O0=INT((248-4)/Q9)
   : REM 'BLOCKING FACTOR' - ORDER LINES
4040     Q0=VAL(Q0$(1))-1
   : REM LENGTH OF CUSTOMER ID
4050     IF M$="SYS MENU" THEN M5$=" "
4060     M$="UTILMENU"
   : REM NAME OF MENU PROGRAM
4070 REM TITLE FOR MENU, LABEL FOR FUNCTION KEY '31
4080     Q7$="GBS/MVP UTILITIES MENU"
4090     STR(Q7$,47)="SYSTEM MENU"
4100     LOAD T"GBS MENU"10,4100
   : ERRORPRINT HEX(03);"GBS Menu is not available."
   : END
7000 REM %RESPONSE TO FUNCTION KEY '31
7010     DEFFN'32
7020     Q6$="SYS MENU"
7030     COM CLEAR I
7040     LOAD TQ6$
   : ERRORPRINT HEX(03);"System menu is not available."
   : END
7050 REM %SET-UP UNIQUE COMPANY PROGRAM CODE
7060     DEFFN'38
7090     RETURN
7100 REM %READ CONTROL FILE
7110     DEFFN'39
7120     Q6$="A/RCONT"
7130     LOAD TQ6$199,199BEG 7140
   : ERRORGOSUB '33
7140     V7$="GBS1F010"
7150     GOSUB '97
7160     MAT SEARCH A6$(),=STR(V7$,,7)TO Q6$STEP 11
7170     Q9=INT((VAL(Q6$,2)+10)/11)
7180     Q6$="A/R Control file"
7190     Q7$="(Filename is not in company control file)."
7200     IF Q9=0 THEN GOSUB '33
7210     Q7$=" "
7220     SELECT #1<STR(A6$(Q9),9,3)>
7230     DATA LOAD DC OPEN T#1,STR(A6$(Q9),,8)
   : ERRORGOSUB '33
7240     SELECT @PARTS0$
7250     M2$=HEX(A0015206)
7260     GOSUB '46(1,0,1)
7270     DATA SAVE DC CLOSE#1
7280     GOSUB '98
7290     RETURN
7300 REM THERE ARE TWO DATA STATEMENTS FOR EACH PROGRAM, WITH 5 DATA ELEMENTS
7310 REM THE FIRST ELEMENT IS THE PROGRAM NAME
7320 REM THE SECOND ELEMENT IS THE PROGRAM DESCRIPTION DISPLAYED BY THE MENU
7330 REM THE THIRD ELEMENT IS A LIST OF SUBROUTINES USED BY THE PROGRAM
7340 REM THE FOURTH ELEMENT INDICATES THE NUMBER OF KFAM FILES TO BE OPENED
7350 REM <IF ONLY SEQUENTIAL FILES ARE OPENED, THIS ELEMENT MUST BE '1'>
7360 REM <FOR SORT SET-UPS, IF NO FILES ARE OPENED, THIS ELEMENT IS '0'>
7370 REM THE FIFTH ELEMENT INDICATES WHICH FILES ARE TO BE OPENED
7380 REM <BYTES 1-8 = GBS FILE NAME, BYTE 9 = ACCESS MODE>
7390 REM <<FOR SORTS, THE ACCESS MODE IS SET TO '0'>>
7400 REM <BYTE 10 = KEY FILE NO.>
7410 REM <<FOR SEQUENTIAL FILES, THE KEY FILE NO. IS SET TO '0'>>
7420 REM <BYTE 11 = USER FILE DEVICE NO.>
7430 REM <<IF THE DEVICE NO. IS GREATER THAN 9, 'A' = 10, ...., 'E' = 15>>
7440     DATA "AUDI010A","PRINT MAINTENANCE AUDIT REPORT","SUBUTIL SUBDATE DEN
     TRY  AUDIFILEPRNTAVAL"
7450     DATA 1,"AUDIF01 401"
7460     DATA "AUDI020A","DISPLAY/PRINT TRANSACTIONS","SUBUTIL SUBDATE DENTRY
      TRAUFILEPRNTAVAL"
7470     DATA 1,"AUDIF02 401"
7480     DATA "ACCT020A","BUILD ACCOUNTS RECEIVABLE FILE","KFAMCODESUBUTIL SUB
     DATE DENTRY  CUSFILE OPNFILE A/RCONT"
7490     DATA 2,"INVCF01 312 ACCTF01 313 GBS1F01 304"
7500     DATA "UTIL010A","RESET ACCESS TABLES","DENTRY"
7510     DATA 0," "
7520     DATA "BACK010A","RESTORE DATA FROM BACKUP DISK","PRNTAVALDENTRY  SUBU
     TIL"
7530     DATA 0," "
7540     DATA "BACK010A","COPY DATA TO BACKUP DISK","PRNTAVALDENTRY  SUBUTIL"
7550     DATA 0," "
7560     DATA "UTIL020A","DELETE INCOMPLETE INVOICES, ORDERS","KFAMCODESUBUTIL
      DENTRY"
7570     DATA 2,"ORENF01 411 INVCF02 412"
7580     DATA "UTIL030A","RESET ALLOCATED (BACKORDERED) AMOUNTS","KFAMCODESUBU
     TIL DENTRY  INVFILE ORDFILE"
7590     DATA 3,"INVTF01 411 ORENF01 412"
7600     DATA "GBS1010A","DISPLAY/PRINT CONTROL FILE","SUBUTIL SUBDATE DENTRY
      A/RCONT PRNTAVAL"
7610     DATA 1,"GBS1F01 101"
9998 DEFFN'29"Q$=";HEX(22);"UTILMENU";HEX(22);":SCRATCHTQ$:SAVET$()Q$";HEX(0D)