image of READY prompt

Wang2200.org

Listing of file='INVT210A' on disk='vmedia/701-2661A.wvd.zip'

# Sector 401, program filename = 'INVT210A'
0010 REM INVT210A, RELEASE 2.0, (06/01/79) THIS PROGRAM IS A COPYRIGHT PRODUCT
      OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED
0170 COM A6$1,B6$1,C6$1,D6$8,D9$25,A9$1,B7$8,B8$20,B9$8,L
   : COM K$1,K1$Q0,K2$Q0,K3$40
   : COM K(6),K1(6)
   : GOTO 4000
4000 SELECT @PARTS0$
   : K2$=ALL(FF)
   : A6$,Q$=" "
   : B6$="Y"
   : K,P1=0
   : L=L0
   : MAT K=ZER
   : MAT K1=ZER
   : GOSUB '100("N,Y","NnYyY ",1,1,"PRINT REPORT  (Y OR N)",2)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : A6$=Q6$
   : IF A6$="Y"THEN 4160
   : $CLOSE
   : GOTO 4240
4160 GOSUB '93(" ")
   : IF I0$=" "THEN A6$="N"
   : GOSUB '100("N,Y","NnYyY ",1,1,"SCREEN DISPLAY (Y OR N)",2)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : B6$=Q6$
   : IF B6$="N"AND A6$="N"THEN 5400
4240 PRINT AT(5,0,);TAB(16);"A = Full report"
   : PRINT TAB(16);"B = Price list"
   : PRINT TAB(16);"C = Sales analysis"
   : PRINT TAB(16);"D = Inventory Management parameters"
   : GOSUB '100("A,B,C,D","AaBbCcDd",1,1,"ENTER REPORT TYPE",2)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : C6$=Q6$
4292 Q6$="FULL REPORT   PRICE LIST    SALES ANALYSIS"
   : K3$=STR(Q6$,Q9*14-13,14)
   : IF Q9=4THEN K3$="MANAGEMENT VARIABLES"
   : Q6$=STR(M5$,1,7)&"B"
   : IF C6$="D"AND A9$<>"M"THEN LOAD TQ6$6270,9999BEG 4301
   : Q6$=STR(M5$,1,7)&"A"
   : IF C6$<>"D"AND A9$="M"THEN LOAD TQ6$6270,9999BEG 4301
4301 IF C6$="D"THEN A9$="M"
   : ELSE A9$=" "
   : SELECT @PARTS0$
   : PRINT AT(5,0,)
   : GOSUB '100("A,R,I","AaIiRr",1,1,"ENTER INQUIRY TYPE  (A=ALL, R=RANGE, I=I
     NDIVIDUAL)",2)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : K$=Q6$
   : Q6$="ALL       RANGE     INDIVIDUAL"
   : K3$=K3$&", "&STR(Q6$,Q9*10-9,10)
   : K3$=K3$&" OPTION"
   : ON Q9GOTO ,4540,4450
4400 GOSUB '235(1,0)
   : GOSUB '91
   : ON J0+1GOTO 4690,,,,,,,4000
   : GOTO 5460
4450 GOSUB '34(HEX(08))
   : IF Q6$="END"THEN 5270
   : K1$,K2$=Q6$
   : GOSUB '232(1,0,K1$)
   : GOSUB '91
   : ON J0+1GOTO 4690,,,4450,,,,4450
   : GOTO 5460
4530 PRINT AT(3,0,80);"Starting ID must be lower than Ending ID.";HEX(07)
4540 K,P1=0
   : MAT K=ZER
   : GOSUB '34("STARTING")
   : IF Q6$="END"THEN 5270
   : L=L0
   : K1$=Q6$
   : GOSUB '34("ENDING")
   : K2$=HEX(FF)
   : IF Q6$<>"END"THEN K2$=Q6$
   : IF K1$>K2$THEN 4530
   : GOSUB '232(1,0,K1$)
   : J$(3)=" "
   : GOSUB '91
   : ON J0GOTO ,,5020,,,,4000
   : IF J0>0THEN 5460
4690 GOSUB '78(2)
   : IF F1$>K2$THEN 4970
   : K=K+1
   : GOSUB '123(H0)
   : D6$=U9$
   : IF MAX(H1())>0THEN $PACK(D=HEX(002F))D9$FROMH1()
   : ELSE D9$=" "
   : IF C6$<>"D"THEN 4770
4748 GOSUB '232(2,0,G1$)
   : IF Q$="N"THEN 4770
   : IF Q$=" "THEN 4764
   : GOSUB '91
   : PRINT AT(3,0,LEN(J$(J0))+2);"- PROFILE ID ";G1$
   : IF J0<>7THEN 5460
   : IF C6$="I"THEN GOTO 4450
   : ELSE GOSUB '92
   : GOTO 4748
4764 GOSUB '79(4)
4770 IF C6$<>"C"THEN 4920
   : K(1)=K(1)+H
   : K(2)=K(2)+H1
   : K(3)=K(3)+F3
   : K(4)=K(4)+H+H2
   : K(5)=K(5)+H1+H4
   : K(6)=K(6)+F3+H3
   : K1(1)=K1(1)+H
   : K1(2)=K1(2)+H1
   : K1(3)=K1(3)+F3
   : K1(4)=K1(4)+H+H2
   : K1(5)=K1(5)+H1+H4
   : K1(6)=K1(6)+F3+H3
   : GOSUB '39(H1,F3,H1+H4,F3+H3)
4920 PRINT AT(5,0,)
   : IF B6$="Y"THEN GOSUB '130
   : ELSE PRINT "Processing product ID ";STR(F1$)
   : IF A6$="Y"THEN GOSUB '90
   : IF A6$="Y"THEN GOSUB '131
   : SELECT PRINT 005(80)
4970 IF K$="I"THEN 4450
   : IF F1$>=K2$THEN 5100
   : IF B6$="Y"THEN GOSUB '254
   : IF Q6$=HEX(1F)THEN GOSUB '31
5020 IF J0=7THEN GOSUB '92
   : GOSUB '237(1,0)
   : IF Q$="E"THEN 5100
   : IF Q$=" "THEN 4690
   : GOSUB '91
   : IF J0=7THEN 5020
   : GOTO 5460
5100 IF A6$="N"AND K$="R"THEN 4540
   : IF A6$="N"OR K$<>"R"THEN 5270
   : L=L+2
   : GOSUB '90
   : IF C6$<>"C"THEN 5220
   : L=L+2
   : GOSUB '90
   : PRINT HEX(0A)
   : F1$=" "
   : F2$="RANGE TOTAL"
   : GOSUB '39(K(2),K(3),K(5),K(6))
   : GOSUB '38(K(1),K(2),K(3),K(4),K(5),K(6))
5220 PRINT HEX(0A)
   : IF K>0THEN PRINT "NO. OF RECORDS PROCESSED = ";K
   : SELECT PRINT 005(80)
   : GOTO 4540
5270 IF A6$="N"THEN 5400
   : SELECT PRINT <I0$>(132)
   : IF C6$<>"C"THEN 5380
   : L=L+3
   : GOSUB '90
   : PRINT HEX(0A)
   : F1$=" "
   : F2$="FINAL TOTAL"
   : GOSUB '39(K1(2),K1(3),K1(5),K1(6))
   : GOSUB '38(K1(1),K1(2),K1(3),K1(4),K1(5),K1(6))
   : PRINT HEX(0A)
5380 PRINT HEX(0C)
5400 SELECT PRINT 005(80)
   : PRINT AT(1,0,)
   : GOSUB '100("M,R","MmRr",1,1,"ENTER R TO RESTART, M FOR MENU",2)
   : IF Q6$="R"THEN 4000
   : J0=0
5460 DEFFN'31
   : IF J0>0THEN GOSUB '254
   : LOAD TM$
6020 DEFFN'90
   : Q6$=" "
   : KEYIN Q6$,6050,6050
6050 IF Q6$="P"THEN GOSUB '254
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : SELECT PRINT <I0$>(132)
   : Q9=0
   : IF C6$="A"OR C6$="D"THEN Q9=6
   : IF L<L0-Q9THEN RETURN
   : P1=P1+1
   : PRINT HEX(0C0A0E);TAB(3);N2$
   : PRINT K3$;TAB(55);"INVENTORY MASTER FILE";TAB(110);Q1$;TAB(122);"PAGE ";P
     1
   : PRINT HEX(0A)
   : L=4
   : RETURN
6180 DEFFN'34(Q7$)
   : IF B6$="N"THEN PRINT AT(5,0,80)
   : PRINT AT(1,0,80);"ENTER ";Q7$;" PRODUCT ID (OR END)"
   : GOSUB '100(" ",HEX(7F),Q0,0," ",2)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : IF Q6$="end"THEN Q6$="END"
   : IF Q6$="END"THEN RETURN
   : GOSUB '96(2)
   : RETURN
6270 %###,###.##-
6280 %##,###,###-
6290 %######.##-
6300 %####.##-
6310 %####.####
6330 Q6=2
   : Q7=25
   : Q8=41
   : Q9=62
   : PRINT TAB(Q6);"PRODUCT ID";TAB(Q7-2);F1$
   : PRINT TAB(Q6);"DESCRIPTION";TAB(Q7-2);F2$
   : PRINT HEX(0A)
   : PRINT TAB(Q6);"UNIT OF MEASURE";TAB(Q7+8);F3$;TAB(Q8);"ON HAND";TAB(Q9);
   : PRINTUSING 6280,E
   : PRINT TAB(Q6);"LAST ACTIVITY";TAB(Q7+2);D6$;TAB(Q8);"AVERAGE COST";TAB(Q9
     );
   : PRINTUSING 6270,F
   : PRINT TAB(Q6);"PRICE 1";TAB(Q7);
6450 PRINTUSING 6270,H(1);
   : PRINT TAB(Q8);"LAST COST";TAB(Q9);
   : PRINTUSING 6270,F1
   : PRINT TAB(Q6);"PRICE 2";TAB(Q7);
   : PRINTUSING 6270,H(2);
   : PRINT TAB(Q8);"TOTAL COST";TAB(Q9);
   : PRINTUSING 6270,ROUND((F*E,2)
   : PRINT TAB(Q6);"PRICE 3";TAB(Q7);
   : PRINTUSING 6270,H(3)
   : RETURN
6560 Q6=2
   : Q7=25
   : Q8=41
   : Q9=62
   : PRINT TAB(Q6);"PRODUCT ID";TAB(Q7-2);F1$
   : PRINT TAB(Q6);"DESCRIPTION";TAB(Q7-2);F2$
   : PRINT TAB(Q6);"ALTERNATE ID";TAB(Q7-2);G3$
   : IF D9$>" "THEN PRINT TAB(Q6);"PRICE BREAKS";TAB(Q7-2);D9$
   : PRINT TAB(Q6);"LOC CODE";TAB(Q7-2);I5$;TAB(Q8);"WEIGHT";TAB(Q9+3);
   : PRINTUSING 6310,H5
6660 PRINT TAB(Q6);"PREFIX";TAB(Q7-2);F$;TAB(Q8);"AVERAGE COST";TAB(Q9);
   : PRINTUSING 6270,F
   : PRINT TAB(Q6);"UNIT OF MEASURE";TAB(Q7+8);F3$;TAB(Q8);"LAST COST";TAB(Q9)
     ;
   : PRINTUSING 6270,F1
   : PRINT TAB(Q6);"LAST ACTIVITY";TAB(Q7+2);D6$;TAB(Q8);"PRICE 1";TAB(Q9);
   : PRINTUSING 6270,H(1)
   : PRINT TAB(Q6);"VENDOR ID";TAB(Q7+5);G2$;TAB(Q8);"PRICE 2";TAB(Q9);
   : PRINTUSING 6270,H(2)
6740 PRINT TAB(Q6);"ON HAND";TAB(Q7);
   : PRINTUSING 6280,E;
   : PRINT TAB(Q8);"PRICE 3";TAB(Q9);
   : PRINTUSING 6270,H(3)
   : PRINT TAB(Q6);"PACK SIZE";TAB(Q7);
   : PRINTUSING 6280,B4;
   : PRINT TAB(Q8);"PRICE 4";TAB(Q9);
   : PRINTUSING 6270,H(4)
   : PRINT TAB(Q6);"ITEM MINIMUM ORDER";TAB(Q7);
   : PRINTUSING 6280,B5;
   : PRINT TAB(Q8);"PRICE 5";TAB(Q9);
   : PRINTUSING 6270,H(5)
   : PRINT TAB(Q6);"MINIMUM";TAB(Q7);
   : PRINTUSING 6280,E4;
6880 PRINT TAB(Q8);"QUANTITY ALLOCATED";TAB(Q9);
   : PRINTUSING 6280,E3
   : PRINT TAB(Q6);"MAXIMUM";TAB(Q7);
   : PRINTUSING 6280,E5;
   : PRINT TAB(Q8);"QUANTITY BACKORDERED";TAB(Q9);
   : PRINTUSING 6280,E2
   : PRINT TAB(Q6);"COUNTING CYCLE";TAB(Q7+9);H5$;
   : PRINT TAB(Q8);"QUANTITY ON ORDER";TAB(Q9);
   : PRINTUSING 6280,E1
   : PRINT TAB(Q6);"ON HAND - PHYSICAL";TAB(Q7);
   : PRINTUSING 6280,F5;
6990 PRINT TAB(Q8);"PHYSICAL COUNT";TAB(Q9);
   : PRINTUSING 6280,E0
   : RETURN
7030 Q6=2
   : Q7=16
   : Q8=24
   : Q9=43
   : PRINT TAB(Q6);"PRODUCT ID";TAB(Q7);F1$
   : PRINT TAB(Q6);"DESCRIPTION";TAB(Q7);F2$
   : PRINT HEX(0A)
   : PRINT TAB(Q8-3);"CURRENT MONTH";TAB(Q9-2);"YEAR TO DATE"
   : PRINT "  UNITS SOLD";TAB(Q8);
   : PRINTUSING 6280,H;
   : PRINT TAB(Q9);
   : PRINTUSING 6280,H2+H
   : PRINT "  COST OF UNITS SOLD";TAB(Q8);
   : PRINTUSING 6270,F3;
   : PRINT TAB(Q9);
   : PRINTUSING 6270,F3+H3
7190 PRINT "  SALES";TAB(Q8);
   : PRINTUSING 6270,H1;
   : PRINT TAB(Q9);
   : PRINTUSING 6270,H4+H1
   : PRINT "  MARGIN";TAB(Q8+3);
   : PRINTUSING 6300,A6;
   : PRINT TAB(Q9+3);
   : PRINTUSING 6300,A7
   : RETURN
7290 Q2=10
   : Q3=0
   : Q4=Q0+2
   : Q5=39
   : Q6=45
   : Q8=72
   : IF L<>4THEN 7400
   : PRINT TAB(Q3);"PRODUCT ID";TAB(Q4);"DESCRIPTION";TAB(Q5);"U/M";TAB(Q6);"Q
     UANTITY PRICE BREAKS";TAB(Q8+2);"PRICE 1";TAB(Q8+Q2+2);"PRICE 2";TAB(Q8+2
     *Q2+2);"PRICE 3";TAB(Q8+3*Q2+2);"PRICE 4";TAB(Q8+4*Q2+2);"PRICE 5"
   : PRINT HEX(0A)
   : L=L+2
7400 PRINT TAB(Q3);F1$;TAB(Q4);STR(F2$,,MIN(36-Q0,LEN(F2$)));TAB(Q5);F3$;TAB(Q
     6);D9$;TAB(Q8);
   : FOR J=1TO 5
   : PRINT TAB(Q8+(J-1)*Q2);
   : PRINTUSING 6290,H(J);
   : NEXT J
   : PRINT
   : L=L+1
   : RETURN
7490 Q2=0
   : Q3=14
   : Q4=41
   : Q5=58
   : Q6=75
   : Q7=90
   : Q8=107
   : Q9=120
   : PRINT TAB(Q2);"PRODUCT ID";TAB(Q3);STR(F1$,,MIN(Q4-Q3-2,LEN(F1$)));TAB(Q4
     );"ON HAND";TAB(Q5);
   : IF E<>0THEN PRINTUSING 6280,E;
   : PRINT TAB(Q6);"MINIMUM";TAB(Q7);
   : IF E4<>0THEN PRINTUSING 6280,E4;
   : PRINT TAB(Q8);"PRICE 1";TAB(Q9);
   : PRINTUSING 6270,H(1)
7650 PRINT TAB(Q2);"DESCRIPTION";TAB(Q3);F2$;TAB(Q4);"BACKORDER";TAB(Q5);
   : IF E2<>0THEN PRINTUSING 6280,E2;
   : PRINT TAB(Q6);"MAXIMUM";TAB(Q7);
   : IF E5<>0THEN PRINTUSING 6280,E5;
   : PRINT TAB(Q8);"PRICE 2";TAB(Q9);
   : PRINTUSING 6270,H(2)
   : PRINT TAB(Q2);"PRICE BREAKS";TAB(Q3);D9$;TAB(Q4);"ON ORDER";TAB(Q5);
   : IF E1<>0THEN PRINTUSING 6280,E1;
   : PRINT TAB(Q6);"PACK SIZE";TAB(Q7);
   : IF B4<>0THEN PRINTUSING 6270,B4;
7760 PRINT TAB(Q8);"PRICE 3";TAB(Q9);
   : PRINTUSING 6270,H(3)
   : PRINT TAB(Q2);"PREFIX/ALT ID";TAB(Q3);F$;TAB(Q3+12);G3$;TAB(Q4);"QTY ALLO
     CATED";TAB(Q5);
   : IF E3<>0THEN PRINTUSING 6280,E3;
   : PRINT TAB(Q6);"ITEM MIN ORDER";TAB(Q7);
   : IF B5<>0THEN PRINTUSING 6270,B5;
   : PRINT TAB(Q8);"LAST ACTIVITY";TAB(Q9+2);D6$
   : PRINT TAB(Q2);"U/M";TAB(Q3);F3$;TAB(Q3+8);"WEIGHT";TAB(Q3+15);
7860 IF H5<>0THEN PRINTUSING 6310,H5;
   : PRINT TAB(Q4);"PHYSICAL COUNT";TAB(Q5);
   : IF E0<>0THEN PRINTUSING 6270,E0;
   : PRINT TAB(Q6);"LAST COST";TAB(Q7);
   : IF F1<>0THEN PRINTUSING 6270,F1;
   : PRINT TAB(Q8);"LOCATION CODE";TAB(Q9+4);I5$
   : PRINT TAB(Q2);"VENDOR ID";TAB(Q3);G2$;
   : PRINT TAB(Q4);"PHYSICAL ON HAND";TAB(Q5);
   : IF F5<>0THEN PRINTUSING 6270,F5;
   : PRINT TAB(Q6);"AVERAGE COST";TAB(Q7);
7970 IF F<>0THEN PRINTUSING 6270,F;
   : PRINT TAB(Q8);"COUNTING CYCLE";TAB(Q9+4);H5$
   : PRINT HEX(0A)
   : L=L+7
   : RETURN
8030 GOSUB '38(H,H1,F3,H+H2,H1+H4,F3+H3)
   : RETURN
8050 DEFFN'38(K1,K2,K3,K4,K5,K6)
   : Q2=44
   : Q4=0
   : Q5=2+Q0
   : Q6=40
   : Q7=52
   : Q8=64
   : Q9=75
   : IF L<>4THEN 8200
   : Q6$=ALL("-")
   : PRINT TAB(40);STR(Q6$,,13);" CURRENT MONTH ";STR(Q6$,,14);TAB(84);STR(Q6$
     ,,14);" YEAR TO DATE ";STR(Q6$,,14)
8160 PRINT TAB(Q4);"PRODUCT ID";TAB(Q5);"DESCRIPTION";TAB(Q6+5);"UNITS";TAB(Q7
     +5);"SALES";TAB(Q8+6);"COST";TAB(Q9+1);"MARGIN";TAB(Q6+Q2+5);"UNITS";TAB(
     Q7+Q2+5);"SALES";TAB(Q8+Q2+6);"COST";TAB(Q9+Q2+1);"MARGIN"
   : PRINT HEX(0A)
   : L=L+3
8200 PRINT TAB(Q4);F1$;TAB(Q5);STR(F2$,,MIN(36-Q0,LEN(F2$)));TAB(Q6);
   : IF K1<>0THEN PRINTUSING 6280,K1;
   : PRINT TAB(Q7);
   : IF K2<>0THEN PRINTUSING 6270,K2;
   : PRINT TAB(Q8);
   : IF K3<>0THEN PRINTUSING 6270,K3;
   : PRINT TAB(Q9);
   : IF A6<>0THEN PRINTUSING 6300,A6;
   : PRINT TAB(Q6+Q2);
   : IF K4<>0THEN PRINTUSING 6280,K4;
   : PRINT TAB(Q7+Q2);
   : IF K5<>0THEN PRINTUSING 6270,K5;
   : PRINT TAB(Q8+Q2);
   : IF K6<>0THEN PRINTUSING 6270,K6;
   : PRINT TAB(Q9+Q2);
   : IF A7<>0THEN PRINTUSING 6300,A7;
   : PRINT
   : L=L+1
   : RETURN
8420 DEFFN'39(K2,K3,K5,K6)
   : A6,A7=0
   : IF K3<>0THEN A6=ROUND((K2/K3*100-100,2)
   : IF K6<>0THEN A7=ROUND((K5/K6*100-100,2)
   : RETURN
8480 DEFFN'130
   : ON VAL(C6$)-64GOSUB 6560,6330,7030
   : RETURN
8510 DEFFN'131
   : ON VAL(C6$)-64GOSUB 7490,7290,8030
   : RETURN
9998 DEFFN'29"Q$=";HEX(22);"INVT210A";HEX(22);":SCRATCH TQ$:SAVET$()Q$";HEX(0D
     )
9999 DEFFN'30"DIM Z$57:IF STR(I0$,,1)=HEX(20)THENI0$=HEX(323135):Z$=";HEX(22);
     "GBS/MVP - Print/display the inventory master file.";HEX(22);":SELECT#15<
     I0$>:$OPEN#15:SELECTLIST<I0$>(132): LIST Z$:LIST Z$#:LIST Z$V:LIST Z$':$C
     LOSE#15:SELECTLIST005(80)";HEX(0D)