image of READY prompt

Wang2200.org

Listing of file='APPLTRNS' on disk='vmedia/701-2663.wvd.zip'

# Sector 253, program filename = 'APPLTRNS'
0010 REM APPLTRNS, RELEASE 1-0, (05/10/79), THIS PROGRAM IS A COPYRIGHT PRODUC
     T OF WANG LABORATORIES., UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED,
     APPLICATION TRANSFER
0120 DIM Q$(2)64,Q6$64,Q7$64,Q$1,I$3,F$8
   : SELECT PRINT 005(80),CO 005
   : PRINT HEX(03)
0160 Q6$=I$
   : GOSUB '100(" "," ",3,0,"ENTER THE APPLICATION DISK ADDRESS",3)
   : I$=Q6$
   : IF Q6$=HEX(1F)THEN GOSUB '31
0200 MAT SEARCH"310320330350360370B10B20B30B50B60B70D10D11D12D13D14D15D20D21D2
     2D23D24D25D30D31D32D33D34D35D50D51D52D53D54D55D60D61D62D63D64D65D70D71D72
     D73D74D75",=I$TO Q7$STEP 3
   : IF STR(Q7$,,2)<>HEX(0000)THEN 260
   : PRINT AT(3,0,64);HEX(07);"ADDRESS ";I$;" IS INVALID"
   : I$=" "
   : GOTO 160
0260 SELECT #1<I$>
   : IF F$=" "THEN Q6$="START"
   : ELSE Q6$=F$
   : GOSUB '100(" "," ",8,0,"ENTER NAME OF PROGRAM TO LOAD",3)
   : IF Q6$=HEX(1F)THEN GOSUB '31
   : F$=Q6$
   : PRINT HEX(030A);"MOUNT APPLICATION PROGRAM DISK CONTAINING ";F$;" IN UNIT
      ";I$
   : GOSUB '254
   : LIMITS T#1,F$,R,R,R,R
   : ERRORGOTO 500
0340 IF R=1THEN 380
   : PRINT AT(3,0,80);HEX(07);"FILE - ";F$;" - NOT AN ACTIVE PROGRAM FILE"
   : F$=" "
   : GOTO 160
0380 SELECT #0<I$>
   : LOAD TF$
0410 DEFFN'31
   : PRINT HEX(03);AT(1,0);"MOUNT INVENTORY MANAGEMENT DISK AT ORIGINAL ADDRES
     S IF REMOVED"
   : GOSUB '254
   : LIMITS T#0,"START",R,R,R,R
   : ERRORGOTO 500
0450 IF R=1THEN LOAD DC T#0,"START"
   : PRINT AT(3,0,80);HEX(07);"INVENTORY DISK NOT IN DRIVE"
   : RETURN CLEAR
0480 GOTO 160
0500 PRINT AT(3,0,80);HEX(07);"DISK ERROR";ERR;"HAS OCCURRED"
   : GOTO 160
0570 DEFFN'100(Q$(1),Q$(2),Q3,Q4,Q7$,Q5)
   : Q6=Q9
   : SELECT PRINT 005(80)
   : IF Q7$<>" "THEN PRINT HEX(010A);Q7$;TAB(80)
0610 KEYIN Q7$,610,610
0630 Q7=Q3+Q4+2+17*(1-ABS(SGN(Q3+Q4)))
   : IF Q5>1THEN Q7=Q3+64*(1-ABS(SGN(Q3)))
   : PRINT AT(2,0,80);
   : IF Q5>-1AND Q5<3THEN 710
   : STR(Q6$,Q7+1)=" "
   : LINPUT -STR(Q6$,,Q7)
   : GOTO 840
0710 Q6$=ALL(8B)
   : IF Q5>1THEN 810
   : STR(Q6$,Q3+1,1)="."
   : STR(Q6$,Q7)=ALL(20)
   : Q7$="Default = "&Q6$
   : $TRAN(Q7$,HEX(238B))R
   : PRINT AT(2,Q7+3);
   : IF Q5=0THEN PRINTUSING Q7$,Q9;
   : PRINT HEX(0D)
   : Q7$=Q6$
0810 LINPUT ?STR(Q6$,,Q7)
   : IF Q5=0AND Q6$=Q7$THEN 990
   : IF Q5=1AND Q6$=Q7$THEN Q6$="0"
0840 $TRAN(Q6$,HEX(208B))R
   : IF Q7$=HEX(0F)THEN 630
   : IF Q6$=HEX(1F)THEN 990
   : IF Q5>1THEN 1020
   : $TRAN(STR(Q6$,POS(Q6$=".")+1)," .")R
   : CONVERT Q$(1)TO Q7
   : ERRORQ7=0
0910 CONVERT Q$(2)TO Q8
   : ERRORQ8=0
0920 CONVERT Q6$TO Q9
   : ERRORGOTO 1150
0940 IF Q3+Q4=0THEN 970
   : IF ABS(Q9)>=10^ABS(Q3)OR INT(Q9*10^Q4)<>Q9*10^Q4THEN 1150
0970 IF Q7=0AND Q8=0THEN 990
   : IF Q9<Q7OR Q9>Q8THEN 1150
0990 PRINT AT(1,0,240)
   : RETURN
1020 IF Q$()=" "THEN 990
   : IF Q4=0AND Q$(1)<=Q6$AND Q$(2)>=Q6$THEN 990
   : Q7$=HEX(07)
   : IF Q4=0THEN 1130
   : IF Q4=1THEN $TRAN(STR(Q6$,,Q3),Q$(2))R
   : Q7=LEN(Q$(1))
   : MAT SEARCHSTR(Q$(1),,Q7),=STR(Q6$,,Q3)TO STR(Q7$,,2)STEP Q3+1
   : Q9=INT((VAL(Q7$,2)+Q3)/(Q3+1))
   : IF Q9>0THEN 990
   : Q7$=" - "&STR(Q$(1),,Q7)&HEX(07)
1130 PRINT AT(3,0,80);"RE-ENTER";Q7$
   : GOTO 630
1150 Q7$=HEX(07)
   : IF Q$()=" "THEN 1130
   : PRINT AT(3,0,80);Q7$;"RE-ENTER   ";Q7;"<= X <=";Q8
   : Q9=Q6
   : GOTO 630
1210 DEFFN'254
   : KEYIN Q6$,1210,1210
   : SELECT PRINT 005
   : PRINT AT(2,0);TAB(80);AT(2,0);
   : Q6$=" "
   : INPUT "KEY RETURN(EXEC) TO RESUME",Q6$
   : RETURN