image of READY prompt

Wang2200.org

Listing of file='609@Cat0' on disk='vmedia/701-2737G.wvd.zip'

# Sector 824, program filename = '609@Cat0'
0010 REM "609@Cat0" - CATALOGUE/DISPLAY LIST
0015 SELECT PRINT 005
   : A5$()="Prime 62JCATSMAL"
   : LOAD T<2>A5$()3000,BEG 180
0180 COM D$1,D0$3,D(2),T5(2),D1$80,D2$16,D$(4)16,V0$(1)1
   : DIM C$1,C0$80
   : DIM T5,S5(2),S0(2),S3(2)
   : DIM T1$(5)80,S1$(20)2
   : DIM T1(8),S6(8),S1(8),T2$(8)80
   : DIM T2(1),S7(1),S2(1),S4(1),T5$(1)80
   : DIM C0$(20)3,S2$(150)2
   : DIM S2$1,T1$80,T2$2
   : DIM U1$(8),U2$(8)4
0320 KEYIN C$,320,320
0330 DEFFN'31
0350 RESTORE LINE2520
   : PRINT HEX(06);
   : IF D1$=" "AND D1=0THEN PRINT HEX(03);
   : IF D1$<>" "AND D1>0THEN PRINT HEX(03);
   : GOSUB '61
0400 T5$()=D1$
   : IF D(1)<>0THEN MAT T5=D
0420 GOSUB '62
   : ON T5+1GOTO 1590,470
   : GOSUB 2720
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 420
0470 D1$=T5$()
   : MAT D=T5
   : C2=POS(T5$()=":")
   : IF C2>1THEN 550
   : GOSUB 2730
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 400
0550 IF C2<10THEN 590
   : GOSUB 2740
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 400
0590 REM Z0$=STR(U2$(),1,A-1)
   : STR(D2$,1,8)=STR(T5$(),1,C2-1)
   : T5$()=STR(T5$(),C2+1)
   : C5=0
   : INIT(" ")D$()
   : C0$=T5$()
   : IF C0$=" "THEN 750
   : $TRAN(STR(C0$,,POS(-C0$<>20)),HEX(8020))R
0740 $TRAN(C0$," 0 1 2 3 4 5 6 7 8 9 A B C D E F G H I J K L M N O P Q R S T U
      V W X Y Z a b c d e f g h i j k l m n o p q r s t u v w x y z .")R
0750 IF POS(C0$>20)>0THEN 880
   : C0$=T5$()&"."
0780 C2=POS(C0$=".")
   : IF C2=1OR C2>17THEN 880
   : IF C2=0AND POS(C0$>" ")>0THEN 880
   : IF C2=0THEN 910
   : C5=C5+1
   : IF C5>4THEN 880
   : D$(C5)=STR(C0$,1,C2-1)
   : C0$=STR(C0$,C2+1)
   : GOTO 780
0880 GOSUB 2750
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 400
0910 D0$="005"
   : IF T5(2)=1THEN 1180
   : RESTORE LINE2630
   : GOSUB '61
   : T5$()=D$
0960 GOSUB '62
   : ON T5+1GOTO 1060,1060
   : GOSUB 2760
1000 PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 960
1030 GOSUB 2810
   : GOTO 1000
1060 D$=T5$()
   : PRINT AT(22,0,);
   : IF T5=0THEN 350
   : CONVERT D$TO C2
   : ERRORGOSUB 2800
   : GOTO 1000
1120 IF C2<1OR C2>4THEN 1030
   : LIMITS T#0,"609@DEVC",C3,S0,C4
   : DATA LOAD DA T#0,(C3+C2)A0$()
   : D0$=STR(A0$(),2,3)
1180 C0=1
1200 GOSUB '236(8,C0)
   : IF R1$<>HEX(00)THEN 1320
   : IF V1=0THEN 1350
   : MAT SEARCHSTR(U1$(),,V1*16),=STR(D2$,,8)TO T2$STEP 16
   : IF T2$>HEX(0000)THEN 1370
   : IF V1<8THEN 1350
   : C0=C0+8
   : GOTO 1200
1320 GOSUB 2770
1330 PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 400
1350 GOSUB 2780
   : GOTO 1330
1370 STR(D2$,9,8)=STR(U1$(),VAL(T2$,2)+8,8)
   : IF STR(D2$,9,8)=" "THEN 1560
   : RESTORE LINE2680
   : GOSUB '61
1430 GOSUB '62
   : ON T5+1GOTO 1490,1490
   : GOSUB 2760
1470 PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 1430
1490 PRINT AT(22,0,)
   : IF T5=0THEN 350
   : IF STR(D2$,9,8)=STR(T5$(),,8)THEN 1560
   : GOSUB 2790
   : GOTO 1470
1560 IF T5(1)=1THEN A5$(1)="609@Cat1"
   : ELSE A5$(1)="609@Cat3"
   : A5$(2)="JCATSMAL"
   : A5$(3)="609FG070"
   : LOAD T<3>A5$()
1590 COM CLEAR C
   : $CLOSE
   : LOAD DC T"609menu"
2500 % DO NOT RENUMBER THE FOLLOWING
2520 DATA 3,0,0,"WANG 2200 Word Processing System"
   : DATA 4,1,26,"Catalog Display/List Utility"
   : DATA 4,5,0,"Please Answer All Questions :"
   : DATA 4,8,0,"Enter File Name or Partial File Name : "
   : DATA 2,10,0,80," "
   : DATA 4,13,14,"Report Type :"
   : DATA 1,14,16,1,"Detail","Summary","\DE"
2590 DATA 4,13,49,"Report Destination : "
   : DATA 1,14,53,1,"Screen","Printer","\DE"
   : DATA 0
2630 DATA 3,0,0,"WANG 2200 Word Processing System"
   : DATA 4,22,0,"Printer Number : "
   : DATA 2,22,17,1," "
   : DATA 0
2680 DATA 3,0,0,"WANG 2200 Word Processing System"
   : DATA 4,22,0,"Volume Password : "
   : DATA 5,22,18,8," "
   : DATA 0
2720 B2$="Invalid Key"
   : RETURN
2730 B2$="Volume Name Must be Specified"
   : RETURN
2740 B2$="Invalid Volume Name"
   : RETURN
2750 B2$="Invalid File Name"
   : RETURN
2760 B2$="Invalid Key"
   : RETURN
2770 HEXUNPACKR1$TO T2$
   : B2$="Error occurred during volume query = "&T2$
   : RETURN
2780 B2$="Volume Does Not Exist"
   : RETURN
2790 B2$="Incorrect Volume Password"
   : RETURN
2800 B2$="Invalid Number"
   : RETURN
2810 B2$="Printer Number must be greater than 0 and less than 5"
   : RETURN