Listing of file='P02D010A' on disk='vmedia/702-0079.wvd.zip'
# Sector 275, program filename = 'P02D010A'
0010 REM . P02D010A, 00-00 (08/14/75), 12002
0100 DIM A$1,B$58,C$(3),Q6$64
: SELECT PRINT 005
: PRINT HEX(03);"PERIPHERAL DIAGNOSTIC - 2202 DIGITAL PLOTTER"
: GOSUB '248(4,0,0)
: PRINT "--------------------------------------------"
0120 PRINT " THE 2202 DEVICE ADDRESS SHOULD BE SET TO 413 "
: PRINT "2202 DIGITAL PLOTTER TEST USING 2200-B DEVICE=X13"
: PRINT "USES 10 INCH BY 10 INCH GRID ON PAPER"
0150 PRINT "1. PLOT + ON EACH OF FOUR CORNERS"
: PRINT "2. BRACKET EACH + WITH 3 CENTERED DOTS"
: PRINT "3. PRINT THEN PLOT THEN PLOT 6 LINES (3 UPPER/3 LOWER CASE."
0180 PRINT "4. PLOT SPECIAL CHARACTERS (7 PRINTABLE)"
: PRINT "5. TEST ALIGNMENT ON CENTERED DOT."
: PRINT "6. CENTER 'O' ON X,Y AXIS."
: GOSUB '243("KEY (EXEC) TO RESUME",0)
: GOSUB '248(1,0,3)
: GOSUB '248(2,5,0)
0237 PRINT "TESTING THE 2202 DIGITAL PLOTTER..";
: SELECT PRINT 213
: PRINT
: A$="+"
: X=999.9
: PLOT <1,,>
: PLOT <X,,"+">,<0,-X,A$>,1<-(990+9),0,HEX(2B)>
: PLOT <,999,STR(A$,1)>
: Z=0
0320 PLOT <,,HEX(FBFBFB)>,10<-3,-4,>,<-Z,,>,3<.9,10,HEX(FB)>
: PLOT <X,-X+10," ">,<-50,,HEX(FBFBFB20)>
: FOR I=1TO 3
: PLOT <,10,HEX(FB)>
: NEXT I
: PLOT <-999,,HEX(FB)>,<,-10,HEX(FB)>,<0,-10,HEX(FB)>,<,-10,HEX(FBFBFB)>
0390 PLOT <929,999,HEX(FBFBFB20)>,3<,-10,HEX(FB)>
: B$="ABCDEFGHIJKLMNOPQRSTUVWXYZ 0123456789 :;<>?!#$%&'()*+-,./"
: PRINT
: PRINT B$;
: PLOT <20,-17,>
: FOR I=58TO 1STEP -1
: PLOT <-10,,STR(B$,I,1)>
: IF STR(B$,I,1)<>" "THEN 460
: PLOT <-10,,>
0460 NEXT I
: PRINT
: PLOT <,,B$>
: OR (B$,20)
: PLOT <,,HEX(0D0D)>
: FOR I=1TO 58
: PLOT <10,,STR(B$,I,1)>
: IF STR(B$,I,1)<>HEX(20)THEN 520
: PRINT HEX(08);
0520 NEXT I
: PRINT
: PRINT B$
: PLOT <,,B$>
: PLOT <0,0,HEX(0D0D)>
: PRINT "OTHER SPECIAL CHARACTERS: ";
: FOR I=0TO 29
: BIN(A$)=I
: PLOT <,,A$>
: NEXT I
: PLOT <270,,HEX(FA1E1F)>
: C$(2)=HEX(405B5C5D5E5F)
: PLOT <,,C$(2)>
: OR (C$(2),20)
: PLOT <,,C$(2)>
0592 PRINT HEX(0D0A0A0A0A)
: PLOT <300,-300,>
: Y=-100
: FOR X=-100TO 100STEP 20
: GOSUB 770
: NEXT X
: X=100
: FOR Y=-100TO 100STEP 20
: GOSUB 770
: NEXT Y
: Y=100
: FOR X=100TO -100STEP -20
: GOSUB 770
: NEXT X
: X=-100
: FOR Y=100TO -100STEP -20
: GOSUB 770
: NEXT Y
0660 PLOT <200,-0,>,41<5,0,HEX(FB)>,<-100,-105,>,41<0,5,HEX(FB)>
: PLOT <,-100,>
: PLOT <300,400,>,<-880,-880,>
: PLOT <,200,>,<870,-200,>
: FOR I=1TO 10
: PLOT <-88,88,>
: NEXT I
: PLOT <490,,>,<,-490,>
: PLOT <100,-250,>
: PLOT <,340,>
0740 PLOT 2<,,"O">
: PLOT <,-500,HEX(0D)>
: SELECT PRINT 005
: GOSUB '248(1,0,3)
: GOSUB '248(2,5,0)
: PRINT "VERIFY THE OUTPUT WITH DISPLAY, KEY (EXEC) TO RESUME";
: INPUT Z
: GOSUB '248(1,0,14)
: GOSUB '248(6,4,0)
: PRINT "SF. 15 -- DIAGNOSTIC MENU"
: STOP
0770 PLOT <X,Y,"+">,<-X,-Y,HEX(FB)>
: RETURN
: GOTO 10
1000 DEFFN'31
: LOAD DC T"START"
2080 Q6=3
: GOTO 2460
2100 DEFFN'254
: GOSUB '243("KEY RETURN(EXEC) TO RESUME",0)
: W4$=Q6$
: GOSUB '248(0,0,4)
: Q6$=W4$
: RETURN
2140 DEFFN'242(W0,Q6$)
: IF W0<=0THEN 2540
: IF W0=1THEN 2160
: STR(Q6$,2)=STR(Q6$,1,W0-1)
2160 PRINT Q6$;
: RETURN
2180 DEFFN'243(Q6$,Q0)
: GOSUB 2360
2200 SELECT CO 205
: Q6$=" "
: INPUT Q6$
: IF Q0=0THEN 2420
: IF LEN(Q6$)<=Q0THEN 2420
: GOSUB 2340
2220 DEFFN'244(Q0)
: GOSUB 2400
: GOSUB 2380
: GOTO 2200
2240 DEFFN'245(Q6$,Q2,Q3)
: Q0=ABS(Q2)+Q3+1
: GOSUB 2360
2260 GOSUB '242(ABS(Q2)+2,HEX(09))
: PRINT "/"
: GOSUB 2400
: SELECT CO 205
: Q9,W0=-1E-99
: INPUT Q9
: IF W0=Q9THEN 2280
: IF Q9>=0THEN 2320
: IF Q2<=0THEN 2320
2280 GOSUB 2340
2300 DEFFN'246(Q2,Q3)
: Q0=ABS(Q2)+Q3+1
: GOSUB 2400
: GOSUB 2380
: GOTO 2260
2320 IF ABS(Q9)>=10^ABS(Q2)THEN 2280
: W0=ABS(Q9*10^Q3)
: IF INT(W0)<>W0THEN 2280
: GOTO 2080
2340 GOSUB 2080
: PRINT "RE-ENTER"
: RETURN
2360 GOSUB 2540
: PRINT HEX(010A);STR(Q6$,1);
2380 GOSUB 2540
: GOSUB '242(Q0+2,"-")
: PRINT TAB(64)
2400 PRINT HEX(010A0A)
: RETURN
2420 PRINT HEX(0A);TAB(64)
: GOTO 2540
: Q6=0
2460 Q7=0
: Q8=1
2480 DEFFN'248(Q6,Q7,Q8)
: GOSUB 2540
: IF Q8<1THEN 2500
: GOSUB 2500
: SELECT PRINT 205
: Q6$=" "
: PRINT STR(Q6$,Q7+1)
: IF Q8<2THEN 2500
: FOR W0=2TO Q8
: PRINT HEX(0A);STR(Q6$,1)
: NEXT W0
2500 PRINT HEX(01)
: GOSUB '242(Q7,HEX(09))
: GOSUB '242(Q6,HEX(0A))
2540 SELECT PRINT 005(64),CO 005
: RETURN