image of READY prompt

Wang2200.org

Listing of file='P12D010A' on disk='vmedia/702-0079.wvd.zip'

# Sector 340, program filename = 'P12D010A'
0010 REM .    P12D010A,    00-00 (08/14/75),    12002
0050 GOSUB 2600
0095 DIM Q6$64
   : PRINT HEX(03);"2200 HARDWARE DIAGNOSTIC - 2212 FLATBED PLOTTER ----------
     ------"
   : GOSUB '248(15,0,0)
   : PRINT "DIAGNSTIC MENU ; KEY 'RESET' AND SF'31";HEX(01)
0096 GOSUB '248(4,0,0)
   : PRINT "----------------------------------------------"
   : GOSUB '248(6,6,0)
0131 PRINT " 1. THE 2212 SET AT ADDRESS ";F$
   : GOSUB '248(7,6,0)
   : PRINT " 2. SET UP THE 2212 WITH CPU"
   : GOSUB '248(8,6,0)
   : PRINT " 3. MOUNT A 10'X 15' PAPER"
   : GOSUB '248(9,6,0)
0146 PRINT " 4. SET UP THE X,Y AXIES ON 2212"
   : GOSUB '243("KEY (EXEC) TO RESUME",0)
   : GOSUB '248(1,0,10)
   : PRINT "-------------------------------"
   : PLOT <,,R>
   : PRINT ".SETTING SCALE"
   : PRINT "  X-AXIS"
   : FOR I=1TO 10
0220 PLOT <100,,D>,<,10,D>,<,-10,D>
   : NEXT I
   : PLOT <,,R>
   : PRINT "  Y-AXIS"
   : FOR I=1TO 10
   : PLOT <,100,D>,<10,,D>,<-10,,D>
   : NEXT I
   : PLOT <,,R>
   : PRINT ".PLOTTING DIAGONAL"
   : PLOT <999,999,D>
   : PRINT ".RETRACING DIAGONAL USING REPETITION"
0310 PLOT 3<-111,-111,D>,<-10,,D>,<10,,D>,<,-10,D>,<,10,D>
   : PLOT 3<-111,-111,D>,<,10,D>,<,-10,D>,<10,,D>,<-10,,D>
   : PLOT 3<-111,-111,D>
   : PRINT ".DRAWING SQUARE"
0350 PLOT <333,333,U>,<333,,D>,<,333,D>,<-333,,D>,<,-333,D>,<,,R>
   : PRINT ".RETRACING DIAGONAL"
   : FOR I=0TO 900STEP 100
   : PLOT <I,I,U>,<100,100,D>,<,,R>
   : NEXT I
   : PLOT <2,,C>,<22,,S>,<,800,U>
0410 PRINT ".IN PRINT MODE TO PRINT STANDARD CHARACTER SET"
   : PLOT <,,"ABCDEFGHIJKLMNOPQRSTUVWXYZ 0123456789():.,?=+-'/">
   : PLOT <,,R>,<5,500,U>
   : PRINT ".DISPLAY OF 15 OPTIONAL CHARACTER SIZES"
0450 A$="ABCDEFGHIJKLMNO"
   : FOR I=1TO 15
   : PLOT <I,,C>,<I*11,,S>,<,,STR(A$,I,1)>
   : NEXT I
0490 DEFFN'1
   : PRINT ".CIRCLE PLOT"
   : SELECT R
   : PLOT <,,R>
   : D=.05
   : R=499
   : GOTO 530
0520 INPUT "INC,RAD-MAX 500",D,R
0530 X0=R+500
   : Y0=500
   : PLOT <X0,Y0,>
   : FOR T=0TO 2*#PI+DSTEP D
   : X=500+R*COS(T)
   : Y=500+R*SIN(T)
   : X1=X-X0
   : Y1=Y-Y0
   : PLOT <X1,Y1,D>
   : X0=X
   : Y0=Y
   : NEXT T
   : PLOT <,,R>
   : PRINT "** SF. 31 -- PERIPHERAL DIAGNOSTIC MENU"
   : STOP
1000 DEFFN'31
   : LOAD DC T"START"
2080 Q6=3
   : GOTO 2460
2100 DEFFN'254
   : GOSUB '243("KEY RETURN(EXEC) TO RESUME",0)
   : W4$=Q6$
   : GOSUB '248(0,0,4)
   : Q6$=W4$
   : RETURN
2140 DEFFN'242(W0,Q6$)
   : IF W0<=0THEN 2540
   : IF W0=1THEN 2160
   : STR(Q6$,2)=STR(Q6$,1,W0-1)
2160 PRINT Q6$;
   : RETURN
2180 DEFFN'243(Q6$,Q0)
   : GOSUB 2360
2200 SELECT CO 205
   : Q6$=" "
   : INPUT Q6$
   : IF Q0=0THEN 2420
   : IF LEN(Q6$)<=Q0THEN 2420
   : GOSUB 2340
2220 DEFFN'244(Q0)
   : GOSUB 2400
   : GOSUB 2380
   : GOTO 2200
2240 DEFFN'245(Q6$,Q2,Q3)
   : Q0=ABS(Q2)+Q3+1
   : GOSUB 2360
2260 GOSUB '242(ABS(Q2)+2,HEX(09))
   : PRINT "/"
   : GOSUB 2400
   : SELECT CO 205
   : Q9,W0=-1E-99
   : INPUT Q9
   : IF W0=Q9THEN 2280
   : IF Q9>=0THEN 2320
   : IF Q2<=0THEN 2320
2280 GOSUB 2340
2300 DEFFN'246(Q2,Q3)
   : Q0=ABS(Q2)+Q3+1
   : GOSUB 2400
   : GOSUB 2380
   : GOTO 2260
2320 IF ABS(Q9)>=10^ABS(Q2)THEN 2280
   : W0=ABS(Q9*10^Q3)
   : IF INT(W0)<>W0THEN 2280
   : GOTO 2080
2340 GOSUB 2080
   : PRINT "RE-ENTER"
   : RETURN
2360 GOSUB 2540
   : PRINT HEX(010A);STR(Q6$,1);
2380 GOSUB 2540
   : GOSUB '242(Q0+2,"-")
   : PRINT TAB(64)
2400 PRINT HEX(010A0A)
   : RETURN
2420 PRINT HEX(0A);TAB(64)
   : GOTO 2540
2440 Q6=0
2460 Q7=0
   : Q8=1
2480 DEFFN'248(Q6,Q7,Q8)
   : GOSUB 2540
   : IF Q8<1THEN 2500
   : GOSUB 2500
   : SELECT PRINT 205
   : Q6$=" "
   : PRINT STR(Q6$,Q7+1)
   : IF Q8<2THEN 2500
   : FOR W0=2TO Q8
   : PRINT HEX(0A);STR(Q6$,1)
   : NEXT W0
2500 PRINT HEX(01)
   : GOSUB '242(Q7,HEX(09))
   : GOSUB '242(Q6,HEX(0A))
2540 SELECT PRINT 005(64),CO 005
   : RETURN
2600 PRINT HEX(03);"2200 HARDWARE DIAGNOSTIC - 2212 FLATBED PLOTTER-----------
     -----"
   : PRINT
   : PRINT
   : PRINT "1. 404","2. 413","3. 414","4. 415"
2610 PRINT HEX(0C0C);
   : INPUT "SELECT PLOTTER ADDRESS",Q
2620 ON Q GOTO 2630,2640,2650,2660
2630 SELECT PLOT  404
   : F$="404"
   : RETURN
2640 SELECT PLOT  413
   : F$="413"
   : RETURN
2650 SELECT PLOT  414
   : F$="414"
   : RETURN
2660 SELECT PLOT  415
   : F$="415"
   : RETURN