Listing of file='P72D020A' on disk='vmedia/702-0079.wvd.zip'
# Sector 629, program filename = 'P72D020A'
0010 GOSUB 900
: PRINT HEX(03);"2200 HARDWARE DIAGNOSTICS - 2272-1 -----------------------
------"
0015 PRINT HEX(0A0A0A0A0A0A0A0A0A0A0A0A0A0A);"KEY H/S & SF31 FOR MENU";HEX(01)
: GOSUB 1900
: PRINT "SF' KEYS ARE COMMANDS"
: PRINT "KEY SF'0 DIAGNOSTIC EXERCISE"
: PRINT "KEY SF'1 CIRCLE"
0060 PRINT "KEY SF'2 SPIRAL"
: PRINT "KEY SF'3 FOR 15 DIFFERENT SIZE LETTERS"
: PRINT "KEY SF'4 FOR SQUARE PLOT"
: PRINT "KEY SF'5 FOR STANDARD SIZE LETTERS"
: PRINT "KEY SF'6 FOR DIAGONAL PLOT"
: PRINT "KEY SF'7 FOR RETRACTING DIAGONAL"
0110 STOP " KEY SF'"
: GOTO 10
0120 DEFFN'02
: PRINT "SPIRAL"
: SELECT R
: PLOT <,,R>
: Q=1
: INPUT "INC,RAD-MAX 500",D,R
: X0=R+500
: Y0=500
: PLOT <X0,Y0,U>
0170 FOR T=0TO 2*#PISTEP D
: R=R-Q*T*D
: IF R>0THEN 200
: PLOT <,,R>
: GOTO 10
0200 X=500+R*COS(T)
: Y=500+R*SIN(T)
: X1=X-X0
: Y1=Y-Y0
: PLOT <X1,Y1,D>
: X0=X
: Y0=Y
: NEXT T
: Q=Q+1
: GOTO 170
0205 DEFFN'0
: PRINT HEX(03);"2200 HARDWARE DIAGNOSTICS - 2272-1 -----------------------
------"
0261 PRINT HEX(0A0A0A0A0A0A0A0A0A0A0A0A0A0A);"KEY H/S & SF31 FOR MENU";HEX(01)
: PRINT "WANG 2272 DRUM PLOTTER EXERCISE"
: PLOT <,,HEX(E5)>
: PLOT <,,HEX(E0F9FF0000)>
: PLOT <,,HEX(E4)>
: PLOT <,,HEX(E00C800000)>
: PLOT <,,R>
: PRINT "SETTING SCALE"
: PRINT " X-AXIS"
0300 FOR I=1TO 10
: PLOT <100,,D>,<,10,D>,<,-10,D>
: NEXT I
: PLOT <,,R>
: PRINT " Y-AXIS"
: FOR I=1TO 10
: PLOT <,100,D>,<10,,D>,<-10,,D>
: NEXT I
: PLOT <,,R>
0370 PRINT "PLOTTING DIAGONAL"
: PLOT <,,HEX(E003E703E70F)>
0390 PRINT "RETRACING DIAGONAL USING REPETITION"
: PLOT 3<-111,-111,D>,<-10,,D>,<10,,D>,<,-10,D>,<,10,D>
: PLOT 3<-111,-111,D>,<,10,D>,<,-10,D>,<10,,D>,<-10,,D>
: PLOT 3<-111,-111,D>
0430 PRINT "DRAWING SQUARE"
: PLOT <,,HEX(E0014D014D0E)>,<333,,D>,<,333,D>,<,,HEX(E0FEB300000F)>,<,-333
,D>,<,,R>
: PRINT "RETRACING DIAGONAL"
: GOSUB 1800
: FOR I=0TO 900STEP 100
: PLOT <I,I,U>,<100,100,D>,<,,R>
: NEXT I
: PLOT <2,,C>,<22,,S>,<,800,U>
0500 PRINT "IN PRINT MODE TO PRINT STANDARD CHARACTER SET"
: PLOT <,,"ABCDEFGHIJKLMNOPQRSTUVWXYZ 0123456789():.,?=+-'/">
: PLOT <,,R>,<5,500,U>
0530 PRINT "DISPLAY OF 15 OPTIONAL CHARACTER SIZES"
: A$="ABCDEFGHIJKLMNO"
: FOR I=1TO 15
: PLOT <I,,C>,<I*11,,S>,<,,STR(A$,I,1)>
: NEXT I
0580 DEFFN'1
: PRINT " CIRCLE PLOT"
: SELECT R
: PLOT <,,R>
: D=.05
: R=499
: GOTO 620
: INPUT "INC,RAD-MAX 500",D,R
0620 X0=R+500
: Y0=500
: PLOT <X0,Y0,U>
: FOR T=0TO 2*#PI+DSTEP D
: X=500+R*COS(T)
: Y=500+R*SIN(T)
: X1=X-X0
: Y1=Y-Y0
: PLOT <X1,Y1,D>
: X0=X
: Y0=Y
: NEXT T
: PLOT <,,R>
: GOTO 110
0710 DEFFN'03
: GOTO 530
0730 DEFFN'04
: GOTO 430
0750 DEFFN'05
: GOTO 500
0770 DEFFN'06
: GOTO 370
0790 DEFFN'07
: GOTO 390
0800 DEFFN'31
: LOAD DC T"START"
0900 PRINT HEX(03);"2200 HARDWARE DIAGNOSTICS - 2272 -1 ----------------------
------"
: PRINT HEX(0A0A0A);"1. 404","2. 413","3. 414","4. 415"
: PRINT HEX(0C0C);
: INPUT "SELECT PLOTTER ADDRESS ",Q
: RETURN
1800 ON Q GOTO 1810,1820,1830,1840
1810 SELECT PLOT C04
: RETURN
1820 SELECT PLOT C13
: RETURN
1830 SELECT PLOT C14
: RETURN
1840 SELECT PLOT C15
: RETURN
1900 ON Q GOTO 1910,1920,1930,1940
1910 SELECT PLOT 404
: RETURN
1920 SELECT PLOT 413
: RETURN
1930 SELECT PLOT 414
: RETURN
1940 SELECT PLOT 415
: RETURN