image of READY prompt

Wang2200.org

Listing of file='609Parch' on disk='vmedia/731-0067G.wvd.zip'

# Sector 2688, program filename = '609Parch'
0010 REM '609Parch' - PRINT A DOCUMENT FROM ARCHIVE 07/31/90 kkb 2.6.0
0035 COM U1$(8),V0$(1)2,C0$8,C2$5,C1$1,C2,U2$(8)4,J1$(256)1,J7$6
   : DIM D0$5,C3$1,C4$1
   : DIM C7$5,J$1,D$64,D0$(84)6,D1$3,D2$(256)1,D7$32
   : DIM D1$(1)2,D8$(1),D7$(1)1,D6$(1)1,D9$(1)1,D4$(1),D5$(1)1,J$(1)1,D(25)
   : DIM S5(1),S0(1),T5(1),S3(1)
   : DIM T1$(1)1,S1$(1)2
0080 DIM T1(5),S6(5),S1(5),T2$(5)80
   : DIM T2(2),S7(2),S2(2),S4(2),T5$(2)5
   : DIM S2$(6)2
   : DIM S1$5
   : DIM S2$1,T1$80,T2$2
0105 DIM S0,S4,S5,S6,S7,S9,T0,T2,T3,T5,C0,T7
   : A5$="609menu"
   : C2=6
   : C1$="A"
   : D7$=HEX(0000040108020C030104050509060D07020806090A0A0E0B030C070D0B0E0F0F)
   : D(9)=C2
   : LIMITS T#0,"609$TRAN",A,B,B,B
   : DATA LOAD BA T#0,(A+1)J1$()
   : PRINT HEX(03)
   : C3$=B6$
0160 RESTORE LINE770
   : GOSUB '61
0170 PRINT HEX(06);AT(11,0,80);AT(22,0,80);
   : T5$(1)=R5$
   : T5$(2)=C3$
0185 GOSUB '62
   : ON T5+1GOTO 650,210
   : GOSUB 700
   : GOTO 185
0210 R5$=T5$(1)
   : C3$=T5$(2)
   : IF VER(R5$,"####A")=5THEN 245
   : GOSUB 705
   : GOTO 170
0245 S7=POS(" ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz"=C3$)
   : IF S7>1THEN 270
   : IF S7=0THEN GOSUB 710
   : GOTO 170
0270 DATA LOAD DC OPEN T#0,"609@ARCH"
   : DBACKSPACE #0,BEG
   : DSKIP #0,S7-1S
   : DATA LOAD DC #0,A0$()
   : C4$=STR(A0$(),136,1)
   : IF C4$<>" "THEN 315
   : GOSUB 715
   : GOTO 170
0315 SELECT #D(9)<STR(A0$(),133,3)>
   : ERRORGOSUB 720
   : GOTO 170
0320 B6$=C3$
   : STR(D0$,5,1)=B6$
   : CONVERT C4$TO S7
   : ON S7GOTO 355,465
0355 RESTORE LINE815
   : GOSUB '61
   : T5$()="0000"&B6$
0370 GOSUB '62
   : ON T5+1GOTO 160,395
   : GOSUB 700
   : GOTO 370
0395 D0$=T5$()
   : IF VER(D0$,"####A")=5THEN 425
   : GOSUB 725
   : GOTO 370
0425 LIMITS T#D(9),D0$,D1,J,S0,C2
   : ERRORGOTO 435
0430 IF C2=2AND J-D1+1=1233THEN 450
0435 GOSUB 730
   : GOTO 370
0450 C0$=D0$
   : GOTO 490
0465 D1=0
   : C0$="WWPSDISK"
   : GOTO 490
0490 J$=HEX(0D)
   : GOSUB 735
0510 GOSUB '34(0)
   : PRINT AT(22,0,40);
   : IF J$=HEX(F0)THEN 105
   : DATA LOAD BA T#D(9),(D1+0)D2$()
   : ERRORGOTO 490
0540 D4$=STR(D2$(),4,5)
   : IF VER(D4$,"####A")=5THEN 565
   : GOSUB 740
   : GOSUB '34(1)
   : GOTO 490
0565 GOSUB 745
   : GOSUB '34(0)
   : IF J$=HEX(F0)THEN 490
   : GOSUB '40
   : GOSUB '45(R5$)
   : IF D(12)>0THEN 606
   : GOSUB 750
   : GOTO 160
0606 J7$=B4$
   : IF POS(STR(D$,34,6)>20)=0THEN 615
0607 $TRAN(B4$,HEX(0020))R
   : IF STR(D$,34,6)=B4$THEN 615
   : $TRAN(B4$,HEX(2000))R
   : GOSUB '90
   : IF D5$<>HEX(F0)THEN 607
   : GOSUB 2515
   : GOTO 650
0615 $TRAN(B4$,HEX(2000))R
   : B4$=J7$
   : GOSUB 2520
   : PRINT AT(21,0,40);T1$;" ";STR(D$,7,25);
   : IF D(14)>1THEN 619
   : GOSUB '34(0)
0619 GOSUB 2525
   : IF J$=HEX(0D)THEN PRINT AT(23,0,40);T1$;
   : GOSUB '50
   : IF B2$=" "THEN 631
   : PRINT AT(23,0,);B2$;HEX(07);
   : GOTO 510
0631 C2$=R5$
   : C2=6
   : IF D1=0THEN C0$="WWPSDISK"
   : ELSE C0$=D0$
   : A5$()="609POPT0609POPTAPrime 62"
   : LOAD T<3>A5$()
0650 COM CLEAR C
   : LOAD T"609menu"
0660 DEFFN'31
   : COM CLEAR C
   : $CLOSE
   : LOAD T"609menu"
0700 T1$="Invalid Key"
   : GOTO 755
0705 T1$="Invalid Document ID"
   : GOTO 755
0710 T1$="Invalid Archive Location"
   : GOTO 755
0715 T1$="Archive Not Assigned"
   : GOTO 755
0720 T1$="Invalid Archive Device Assigned"
   : GOTO 755
0725 T1$="Invalid Archive Label"
   : GOTO 755
0730 T1$="Archive Does Not Exist"
   : GOTO 755
0735 T1$="Mount Formatted Archive"
   : GOTO 756
0740 T1$="Platter mounted is not an initialized archive"
   : GOTO 755
0745 T1$="Archive: "&D4$
   : GOTO 756
0750 T1$="Document Does Not Exist"
   : GOTO 755
0755 PRINT HEX(07);
0756 PRINT AT(23,0,);T1$;
   : RETURN
0770 DATA 4,0,0,"Print Document From Archive"
   : DATA 4,3,0,"Please Enter Data"
   : DATA 4,4,0,"Press EXECUTE to Continue"
   : DATA 4,7,26,"Document ID : "
   : DATA 2,7,48,5," "
   : DATA 4,9,26,"Archive Location : "
   : DATA 2,9,48,1," "
   : DATA 0
0815 DATA 4,0,0,"Print Document From Archive"
   : DATA 4,11,26,"Archive ID : "
   : DATA 2,11,48,5," "
   : DATA 0
   : DIM D(25)
0850 DEFFN'90
   : PRINT AT(23,0,);"Enter Document ";R5$;" Password ";HEX(858585858585);AT(2
     3,40);"Password Protected";HEX(07);AT(23,29);HEX(0509);
0870 KEYIN D5$,870,870
   : D(6)=0
   : B4$=" "
0900 KEYIN D5$,910,910
   : GOTO 900
0910 PRINT HEX(06);AT(23,40,);
   : ON POS(HEX(0D82F0)=D5$)GOTO 990,990,1010
   : IF VER(D5$,"N")=1THEN 960
   : GOSUB 2530
   : PRINT AT(23,40);T1$;HEX(07);
   : GOTO 900
0960 D(6)=D(6)+1
   : STR(B4$,D(6),1)=D5$
   : IF D(6)<6THEN 900
0990 PRINT AT(23,0,);
   : RETURN
1010 PRINT AT(23,0,);
   : B4$=" "
   : RETURN
2515 B2$="Incorrect Password"
   : RETURN
2520 T1$="Document Name :"
   : RETURN
2525 T1$="(In Progress)"
   : RETURN
2530 T1$="Invalid Character"
   : RETURN