image of READY prompt

Wang2200.org

Listing of file='ASKAEMUL' on disk='vmedia/731-0110A.wvd.zip'

# Sector 152, program filename = 'ASKAEMUL'
0010 REM ASKAEMUL  EMULATE? 01/26/81
0020 DIM E$64
0025 A=1
   : RESTORE 2
   : READ E$
   : RESTORE
0028 IF E$=" "THEN 110
   : REM /Bypass display if only one emulation
0030 IF B$=" "THEN 40
0035 READ C$
   : IF C$=" "THEN 40
   : IF C$=B$THEN 110
   : A=A+1
   : GOTO 35
0040 PRINT HEX(030E);"    WHAT EMULATION?"
0045 PRINT "TO OPERATE -- Press S.F. KEY or DIGIT corresponding to name,"
0050 PRINT "or position # via RETURN, SPACE or BACKSPACE and key RUN"
0060 D=5
   : D1=2
   : A=1
0070 GOSUB 470
   : REM /SET DISPLAY
0080 ON I GOTO 110
0090 %   ' ## for ########################################
0100 GOSUB 200
   : REM /K.B./CRT INTERACTION
0110 RESTORE A
   : READ E$
   : W$=" "
0120 STR(W$,1,8)=STR(E$,2,8)
   : REM /SYSTEM NAME
0130 N$=STR(E$,20)
0140 C$,STR(Z$,31,1)=STR(E$,1,1)
   : C=VAL(C$)-48
   : REM /SET EMULATOR NUMBER
0150 N$(5)=STR(E$,11,8)
   : REM /Which ? file
0170 LOAD DC T#0,N$(4)
0180 DEFFN'0
   : W$=" "
   : LOAD DC T#0,N$(1)
0190 REM %^.K.B./CRT INTERACTION
0200 DIM A$(1)13,M$(1)2
0210 A$(1)=HEX(080D2082313233343536373839)
0220 REM ......CRBSRN.1.2.3.4.5.6.7.8.9
0230 A=1
   : GOTO 370
0240 KEYIN C$,260,410
   : GOTO 240
0250 REM LOWER PAD
0260 MAT SEARCHA$(),=C$TO M$()
   : C=VAL(STR(M$(1),2))
0270 IF C=0THEN 240
0280 PRINT STR(D8$,1,A+D-1);BOX(-1,-55);TAB(D1+1)
0290 ON CGOTO 360,340,340,440
0300 REM .....BS..CR..SP..RUN
0310 REM DIGIT
0320 AND (C$,0F)
   : GOTO 410
0330 REM CR CARRIAGE RETURN or SPACE
0340 A=A+1
   : IF A<=ITHEN 370
   : A=1
   : GOTO 370
0350 REM BS BACKSPACE
0360 A=A-1
   : IF A>0THEN 370
   : A=I
0370 PRINT STR(D8$,1,A+D-1);BOX(1,55);TAB(D1);"#";HEX(08);
0380 SELECT PRINT 005
0390 GOTO 240
0400 REM S.F.
0410 IF C$=HEX(00)THEN 180
0420 C=VAL(C$)
   : IF C>ITHEN 370
0430 PRINT STR(D8$,1,A+D-1);BOX(-1,-55);TAB(D1+1)
   : A=C
0440 PRINT STR(D8$,1,A+D-1);BOX(1,7);TAB(D1);"*";
0450 RETURN
0460 REM % **   SET DISPLAY  ***
0470 I=0
   : RESTORE
   : PRINT
0480 READ E$
   : IF E$<>" "THEN 490
   : RETURN
0490 A$=STR(E$,20)
   : I=I+1
   : PRINTUSING 90,I,A$
   : GOTO 480
9000 REM + ....!....1....!....2....!....3
9010 DATA "1TTY      ASK?TTY  Teletype Emulator"
9020 DATA "2TTT      ASK?2741 IBM 2741 (Selectric)"
9500 DATA " "