image of READY prompt

Wang2200.org

Listing of file='@PSTAT' on disk='vmedia/731-8027.wvd.zip'

# Sector 300, program filename = '@PSTAT'
0010 REM ! Prog = @PSTAT  By PLS (TBO)   Date = 07/09/91
0015 REM ! (c) Copr. Wang Laboratories, Inc. 1985, 1986, 1989
0020 DIM S$16,S$(4)16,P$29,P1$2,P2$80,P4$50,P$(64)29,Q$1,R$2,C$1
   : P2$=ALL("-")
   : P$=$PSTAT(1)
   : P=0
0021 REM %0 S$ Curr.page parts,  S$(  Parts.per.page
0022 FOR A=1TO 64
   : C$=BIN(A)
   : STR(S$(),A)=C$
   : NEXT A
   : HEXUNPACKSTR(P$,10,1)TO P1$
   : CONVERT #PARTTO R$,(##)
0024 C$=STR(P$,9,1)
   : IF C$="V"THEN P4$="VP"
   : IF C$="M"THEN P4$="MVP"
   : IF C$="W"THEN P4$="CS 386"
   : IF C$="T"THEN P4$="CS/Turbo"
0025 IF C$="V"THEN C$="M"
   : IF C$="T"THEN C$="W"
0026 P4$=P4$&"  Release "&STR(P1$,1,1)&"."&STR(P1$,2,1)&"   Partition "&R$
0028 IF C$="M"THEN 29
   : CONVERT #CPUTO R$,(##)
   : P4$=P4$&"  CPU "&R$
0029 P4=60-(LEN(P4$))
0030 P=P+1
   : P$=$PSTAT(P)
   : ERRORP9=P-1
   : IF P>64THEN 38
   : FOR B=PTO 64
   : STR(S$(),B,1)=HEX(00)
   : NEXT B
   : GOTO 38
0035 GOTO 30
0038 S$=S$(1)
   : S=1
   : P0=POS(S$=HEX(00))-1
   : IF P0<1THEN P0=16
0040 PRINT HEX(03060E);"     ***** Partition Status - (c) Copr. Wang Laborator
     ies, Inc. 1991 *****"
0042 PRINT AT(1,P4);P4$
0044 IF C$="W"THEN PRINT "#PART  USER-MSG     SPACE K    PRGM #TERM    @NAME
       ERR    TEXT @P DATA    I/O"
   : ELSE PRINT "#PART  USER-MSG   Bank SpaceK  PRGM #TERM    @NAME    ERR
     TEXT @P DATA    I/O"
0046 PRINT P2$
   : PRINT AT(4+P0,0);P2$
0048 PRINT AT(22,0,80);"Press SF'0 to attach terminal to a different partition
     .";
   : B=1
0050 PRINT AT(23,0);"Press 'FN' or 'TAB' to return to menu.";
   : REM %.Get & show status of each partition
0060 PRINT AT(4,0);
   : FOR P=1TO P0
   : P$=$PSTAT(VAL(STR(S$,P)))
0070 PRINT "-";
   : IF P$=P$(P)THEN 130
0080 CONVERT VAL(STR(S$,P))TO P1$,(##)
   : UNPACK(##)STR(P$,15,1)TO T
0090 REM ELIMINATE UNPRINTABLE CHARACTERS
   : $TRAN(STR(P$,,8),"................")
   : $TRAN(STR(P$,17,8),"................")
0100 IF T=#TERMTHEN PRINT HEX(0E);
0110 PRINT P1$;"    ";STR(P$,,8);"     ";
0115 IF C$="W"THEN PRINT HEXOF(STR(P$,11,2));".";HEXOF(STR(P$,13,1));"      ";
   : ELSE PRINT HEXOF(STR(P$,11,1));"  ";HEXOF(STR(P$,12,1));".";HEXOF(STR(P$,
     13,1));"    ";
0120 PRINT STR(P$,14,1);"   ";HEXOF(STR(P$,15,1));"-";
   : IF T=#TERMOR T=0AND STR(P$,16,1)="W"THEN PRINT HEX(020404000E);
   : PRINT STR(P$,16,1);HEX(020402000F);
   : IF T=#TERMTHEN PRINT HEX(0E);
   : PRINT "   ";STR(P$,17,8);"   ";HEXOF(STR(P$,25,1));"     ";HEXOF(STR(P$,2
     6,1));"  ";HEXOF(STR(P$,27,1));"  ";HEXOF(STR(P$,28,1));"     ";HEXOF(STR
     (P$,29,1));
0130 $BREAK2
   : PRINT HEX(0D);" "
0140 P$(P)=P$
   : NEXT P
   : B=8
0150 REM %RELEASE?--
   : KEYIN Q$,60,160
   : GOTO 60
0160 $TRAN(Q$,HEX(7F7E0D420D520C430C53))R
   : ON POS(HEX(7F0C0D00)=Q$)+1GOTO 60,161,164,166
   : P$()=" "
   : GOTO 180
0161 DEFFN'126
0162 DEFFN'127
   : LOAD RUN
0164 S=S+1
   : IF S>4THEN S=1
   : IF POS(S$(S)=HEX(00))=1THEN 164
   : GOTO 168
0166 S=S-1
   : IF S<1THEN S=4
   : IF POS(S$(S)=HEX(00))=1THEN 166
0168 S$=S$(S)
   : P0=POS(S$=HEX(00))-1
   : IF P0<1THEN P0=16
   : INIT(20)P$()
   : GOTO 40
0170 P=ERR
   : PRINT AT(23,0);"CANNOT ATTACH TO PARTITION ";R$;" SINCE IT IS ASSIGNED TO
      ANOTHER TERMINAL.";
0180 REM %RELEASE TERMINAL
   : PRINT AT(22,0,79);
   : PRINT "Which partition is terminal";#TERM;"to be attached to (#PART)?";
   : R$=" "
   : LINPUT ?-R$
   : IF R$=" "THEN 40
   : CONVERT R$TO P
   : ERRORGOTO 180
0190 IF P<1OR P>P0OR INT(P)<>PTHEN 180
   : P$=$PSTAT(P)
   : ERRORGOTO 180
0200 UNPACK(##)STR(P$,15,1)TO T
   : IF T<>#TERMAND T<>0THEN 170
0210 REM %RELEASE PARTITION
   : PRINT AT(22,0,80);
   : PRINT "Do you want to release partition";#PART;"for another terminal (Y o
     r N)?";
   : Q$=" "
   : LINPUT ?-Q$
   : ON POS("YyNn"=Q$)GOTO 220,220,220,220
   : GOTO 210
0220 REM %RELEASE
   : PRINT HEX(0D03);
   : $RELEASETERMINALTO P
   : IF Q$="Y"OR Q$="y"THEN $RELEASEPART
   : LOAD T"START"
   : GOTO 40
   : REM LOAD T/xyz,"filename" should replace previous GOTO if you want to loa
     d a program into the released partition.