image of READY prompt

Wang2200.org

Listing of file='@DOSDIRW' on disk='vmedia/731-8028-A.wvd.zip'

# Sector 256, program filename = '@DOSDIRW'
0010 REM %^ @DOSDIRW  UTILITY BY KIRIT BAXI EAME R&D
0020 REM %  Version 1.0 20 JUN 1991
0030 REM ***********************************************
0040 REM *                                             *
0050 REM *              DIR /W Program                 *
0060 REM *                                             *
0070 REM ***********************************************
0090 REM % DEFINE VARIABLES
0100 DIM A$(16)32,D$(16),B$4,C$16,D$3,E$2,F$2,G$2,H$8,I0$3,L$2,M$4,N$1,O$1,P$1
     ,Q$1
   : PRINT HEX(06)
0110 REM % FIND THE FLOPPY ADDRESS
0120 REM address setup by DOS programme
   : D$=SELECT #N
0130 REM % FIND DISK TYPE AND SET OFFSET SECTOR
0140 DATA LOAD BMT#N,(1440,L)A$()
   : ERRORE=ERR
   : IF E=98THEN Y=10
   : V=13
   : GOTO 160
0150 DATA LOAD BMT#N,(4800,L)A$()
   : ERRORE=ERR
   : IF E=98THEN Y=30
   : V=27
   : GOTO 160
0160 A1,B,C,D,D2=0
   : IF Y=0THEN DO
   : Y=10
   : V=13
   : END DO
0170 REM % CHECK IF VOLUME HAS A LABEL
0180 DATA LOAD BMT#N,(Y-1,L)A$()
   : ERRORE=ERR
   : IF E=98THEN DO
   : PRINT HEX(070E);"Please insert diskette in the drive"
   : END DO
   : IF E=98THEN 480
0190 IF STR(A$(9),12,1)=HEX(28)THEN C$="is "&STR(A$(9),1,11)
   : ELSE C$="has no label"
0200 REM % DISPLAY VOLUME DATA
0210 PRINT HEX(06)
0220 PRINTUSING 430;D$;C$
0230 PRINTUSING 440;D$
0240 PRINT HEX(0A)
0250 REM % GET THE DIRECTORY INFORMATION AND CALCUTATE AND DISPLAY THE DATA
0260 FOR Z=YTO Y+VSTEP 2
0270 DATA LOAD BMT#N,(Z,L)A$()
0280 FOR X=1TO 16
   : IF STR(A$(X),1,1)=HEX(00)OR STR(A$(X),1,1)=HEX(E5)OR STR(A$(X),12,1)=HEX(
     28)OR STR(A$(X),12,1)=HEX(03)OR STR(A$(X),12,1)>HEX(7F)THEN GOTO 370
   : IF STR(A$(X),12,1)=HEX(27)OR STR(A$(X),12,1)=HEX(02)OR STR(A$(X),12,1)=HE
     X(01)THEN 290
   : ELSE GOTO 300
0290 GOTO 370
0300 IF STR(A$(X),12,1)=HEX(10)THEN 360
0310 REM % CALCULATE BYTES USED
   : B$=HEX(0000)
   : STR(B$,3,1)=STR(A$(X),30,1)
   : STR(B$,4,1)=STR(A$(X),29,1)
   : STR(B$,1,1)=STR(A$(X),32,1)
   : STR(B$,2,1)=STR(A$(X),31,1)
   : A1=VAL(B$,4)
   : C=C+A1
0320 REM % DISPLAY THE INFORMATION
0330 $TRAN(STR(A$(X),1,11),HEX(A05F))R
   : PRINT STR(A$(X),1,8);" ";STR(A$(X),9,3),
   : D2=D2+1
   : B=B+1
0340 REM % CHECK LINE COUNT
   : IF D2=95THEN DO
   : PRINT HEX(0A0D);"Strike a key when Ready . . .";
   : KEYIN A$
   : IF POS(HEX(7E7FF0)=A$)<>0THEN 480
   : IF D2>=95THEN D2=0
   : PRINT HEX(0A)
   : END DO
0350 GOTO 370
0360 PRINT STR(A$(X),1,8);" ";"<DIR>",
0370 NEXT X
0380 NEXT Z
0390 REM
0400 PRINT
   : PRINT
   : PRINTUSING 420;B;C
0410 REM % DISPLAY LINE IMAGES
0420 %         ### File(s) ######### bytes used in Root Directory
0430 %    Volume in drive '###' ################
0440 %    Directory of '###':\
0450 %   ######## ###   #######  ########  ##:### ########
0460 %   ########     <DIR>      ########  ##:### ########
0470 GOTO 480
0480 REM % RETURN TO COMMAND PROC
   : PRINT
   : I4$="R"
   : LOAD T"@DOS"