image of READY prompt

Wang2200.org

Listing of file='@DOSTYLP' on disk='vmedia/731-8028-A.wvd.zip'

# Sector 378, program filename = '@DOSTYLP'
0010 REM %^  @DOSTYLP Written by  Kirit Baxi E.A.M.E. R&D
0020 REM % Version 1.0 20 JUN 1991
0030 REM *******************************************************
0040 REM *                                                     *
0050 REM *                Type > LPT1 Command                  *
0060 REM *                                                     *
0070 REM *******************************************************
0080 REM % CLEAR SCREEN AND SET CURSOR FLASH ON
0100 DIM A$(32),A1$(16),B$(16)32,D$(16),B$3,C$2,D$4,F$11,H$8,K$1
   : A1$()=T$()
0110 REM % READJUST TRANSLATE TABLE FOR LOWER CASE
0120 A1$(7)=HEX(896162636465666768696A6B6C6D6E6F)
0130 A1$(8)=HEX(707172737475767778797A988699209B)
0140 PRINT HEX(02050F);
0150 REM % CHECK FOR DRIVE READY
   : DATA LOAD BA T#N,(0)D$()
   : ERRORE=ERR
   : IF E=98THEN DO
   : PRINT HEX(070E);"Please insert Diskette in Drive"
   : END DO
   : IF E=98THEN 310
0160 REM % Blank Filename
0170 IF LEN(I$)=1THEN PRINT HEX(0E);"   ^ Unknown Command"
   : IF LEN(I$)=1THEN 310
   : I=0
0180 REM % CALCULATE BYTES FOR THE FILE TO TYPE
0190 C$=ALL(00)
   : F$=ALL(20)
   : MAT SEARCHI$,="."TO C$
   : C=VAL(C$,2)
   : STR(F$,1,8)=STR(I$,1,C-1)
   : STR(F$,9,3)=STR(I$,C+1,3)
   : $TRAN(F$,HEX(2000))R
   : $TRAN(F$,HEX(2000))R
0200 GOSUB 8900
0210 REM % Open the file f$
0220 DATA LOAD ACOPEN T#N,I$
   : ERRORGOTO 320
0230 REM % Read file and display the data
0240 REM % Select printer with No LF
   : B$=SELECT #15
   : SELECT PRINT <B$>
   : $OPEN #15
0250 LIMITS T#N,A,B,C
   : IF B=CTHEN 310
   : DATA LOAD AC#N,A$()
0260 REM $TRAN(A$(),A1$())
0270 REM PRINT HEX(0A)
0280 FOR X=1TO 512
   : IF STR(A$(),X,1)>HEX(07)AND STR(A$(),X,1)<>HEX(FF)THEN PRINT STR(A$(),X,1
     );
0290 I1=I1+1
   : IF I1=A9-1THEN 310
   : NEXT X
0300 REM PRINT HEX(0D 0A)
   : GOTO 250
0310 REM % RET > CMD PROC
   : $CLOSE#15
   : SELECT PRINT 005
   : I4$="R"
   : PRINT HEX(0F0A)
   : LOAD T"@DOS"
0320 REM % RET > CMD PROC IF ERR
   : SELECT PRINT 005
   : PRINT HEX(070E);"File not found"
   : I4$="R"
   : PRINT HEX(0F0A)
   : LOAD T"@DOS"
8890 REM % CALCULATE OFFSET VALUES
8900 DATA LOAD BMT#N,(1440,L)A$()
   : ERRORE=ERR
   : IF E=98THEN Y=10
   : V=13
   : GOTO 8920
8910 DATA LOAD BMT#2,(4800,L)A$()
   : ERRORE=ERR
   : IF E=98THEN Y=30
   : V=27
   : GOTO 8920
8920 A1,B,C,D,D2=0
8930 REM % GET THE DIRECTORY INFORMATION AND CALCUTATE AND DISPLAY THE DATA
8940 FOR Z=YTO Y+VSTEP 2
8950 DATA LOAD BMT#N,(Z,L)B$()
8960 FOR X=1TO 16
   : IF STR(B$(X),1,11)=STR(F$,1,11)THEN 8970
   : ELSE GOTO 8980
8970 REM % CALCULATE BYTES USED
   : D$=ALL(00)
   : STR(D$,3,1)=STR(B$(X),30,1)
   : STR(D$,4,1)=STR(B$(X),29,1)
   : STR(D$,1,1)=STR(B$(X),32,1)
   : STR(D$,2,1)=STR(B$(X),31,1)
   : A9=VAL(D$,4)
   : GOTO 9000
8980 NEXT X
8990 NEXT Z
9000 IF Y=0THEN Y=10
   : IF Y=0THEN V=13
   : RETURN