image of READY prompt

Wang2200.org

Listing of file='CASINO8' on disk='vmedia/best_of_BD_fules.wvd.zip'

# Sector 100, program filename = 'CASINO8'
0010 W=2000
   : DIM A(13,4),S(7),S1(7),C1(7),C(7),O$64,R$(38)2
   : PRINT HEX(03)
   : INIT(0A)D$
   : INIT(09)O$
0020 C=A
   : INPUT "1) RED DOG, 2) BLACK JACK, 3) ROULETTE, 4) SLOT MACHINE",A
   : IF A=CTHEN 21
   : R=0
0021 ON AGOTO 30,200,300,500,20,20,20,20,20,20,20,20,20,20,22
   : GOTO 20
0022 R=RND(0)
   : GOTO 20
0030 REM ***** RED DOG *****
   : R=R+1
   : ON R-1GOTO 50,50,50,50
   : GOSUB 40
   : GOTO 50
0040 R=1
   : PRINT HEX(03);"SHUFFLING..."
   : FOR I=1TO 13
   : FOR U=1TO 4
   : A(I,U)=I
   : NEXT U
   : NEXT I
   : INIT(09)O$
   : RETURN
0050 PRINT HEX(03);" ";
   : FOR I=1TO 4
   : FOR U=1TO 14
   : PRINT "-";
   : NEXT U
   : PRINT " ";
   : NEXT I
   : PRINT
   : FOR I=1TO 7
   : FOR U=1TO 4
   : PRINT HEX(86);
   : FOR N=1TO 14
   : PRINT " ";
   : NEXT N
   : NEXT U
   : PRINT HEX(86)
   : NEXT I
   : PRINT " ";
   : FOR I=1TO 4
   : FOR U=1TO 14
   : PRINT "-";
   : NEXT U
   : PRINT " ";
   : NEXT I
   : PRINT
0060 C=INT(RND(1)*13)+1
   : S=INT(RND(1)*4)+1
   : IF A(C,S)=0THEN 60
   : T=T+1
   : RESTORE C
   : READ C$
   : RESTORE 13+S
   : READ S$
   : ON T-4GOTO 70,100
   : A(C,S)=0
   : GOSUB 160
   : GOTO 60
0070 PRINT
   : PRINT
   : PRINT
   : PRINT
   : PRINT
   : PRINT TAB(10);
   : INPUT "WHAT IS YOUR BET",B
   : IF B<10THEN 80
   : IF B>WTHEN 90
   : W=W-B
   : GOTO 60
0080 PRINT "MINIMUM BET IS $10!                   "
   : PRINT HEX(010A0A0A0A0A)
   : GOTO 70
0090 PRINT "YOU CAN'T BET MORE THAN YOU HAVE!"
   : PRINT HEX(010A0A0A0A0A)
   : GOTO 70
0100 A(C,S)=0
   : PRINT C$;" OF ";S$;"=DEALER             "
   : FOR I=1TO 4
   : IF S(I)=STHEN 110
   : NEXT I
   : REM *LOSER*
   : GOTO 130
0110 IF C(I)>CTHEN 120
   : NEXT I
   : REM *LOSER*
   : GOTO 130
0120 W=W+2*B
   : PRINT HEX(010A0A0A0A0A0A0A0A);STR(O$,1,15*I-10);"WINNER"
   : PRINT STR(O$,1,40);"TOTAL WINNINGS= $";W
   : I=4
   : NEXT I
   : PRINT
   : PRINT
   : GOTO 140
0130 PRINT STR(O$,1,30);HEX(0C0C0C);"YOU LOSE! TOTAL WINNINGS= $";W
   : PRINT
   : PRINT
0140 T,S,C,B=0
   : MAT S=ZER
   : MAT C=ZER
   : IF W<=0THEN 180
   : GOTO 20
0150 PRINT HEX(03);" ";
   : FOR I=1TO 4
   : FOR U=1TO 14
   : PRINT "-";
   : NEXT U
   : PRINT " ";
   : NEXT I
   : PRINT
   : FOR I=1TO 7
   : FOR U=1TO 4
   : PRINT HEX(86);
   : FOR N=1TO 14
   : PRINT " ";
   : NEXT N
   : NEXT U
   : PRINT HEX(86)
   : NEXT I
   : PRINT " ";
   : FOR I=1TO 4
   : FOR U=1TO 14
   : PRINT "-";
   : NEXT U
   : PRINT " ";
   : NEXT I
   : PRINT
0160 S(T)=S
   : C(T)=C
   : PRINT HEX(010A0A0A);STR(O$,1,T*15-11);C$;" OF"
   : PRINT HEX(010A0A0A0A);STR(O$,1,T*15-11);S$
   : RETURN
0170 DATA "DUECE","THREE","FOUR","FIVE","SIX","SEVEN","EIGHT","NINE","TEN","JA
     CK","QUEEN","KING","ACE","SPADES","HEARTS","DIAMONDS","CLUBS"
0180 PRINT "YOU'RE BROKE AND THEY KICKED YOU OUT OF THE CASINO!"
   : END
0190 DEFFN'0HEX(22);",";HEX(22)
0200 REM ***** BLACK JACK *****
0201 Y=2
   : D=1
   : R=R+1
   : ON R-1GOTO 210,210,210
   : GOSUB 40
0210 PRINT HEX(03);TAB(10);"DEALER";STR(O$,1,30);"PLAYER"
   : FOR I=1TO 14
   : PRINT STR(O$,1,31);HEX(86)
   : NEXT I
   : PRINT HEX(01)
0220 C=INT(RND(1)*13)+1
   : S=INT(RND(1)*4)+1
   : IF A(C,S)=0THEN 220
   : T=T+1
   : RESTORE C
   : READ C$
   : RESTORE 13+S
   : READ S$
   : A(C,S)=0
   : ON TGOTO 230,230,240,240
   : IF B1=1THEN 250
   : PRINT HEX(01);STR(D$,1,13);
0221 INPUT "WHAT IS YOUR BET",B
   : IF B<10THEN 222
   : IF B>WTHEN 223
   : W=W-B
   : B1=1
   : GOTO 250
0222 PRINT "MINIMUM BET IS $10!              "
   : PRINT HEX(0C0C)
   : GOTO 221
0223 PRINT "YOU CAN'T BET MORE THAN YOU HAVE!";HEX(0C0C)
   : GOTO 221
0230 REM PLAYERS HAND
   : C(T)=C
   : S(T)=S
   : Y=T
   : GOSUB 270
   : GOTO 220
0240 REM DEALERS HAND
   : C1(T-2)=C
   : S1(T-2)=S
   : ON T-2GOSUB 275
   : PRINT HEX(010A0A);STR(O$,1,(T-2)*11-9);"???";HEX(0A)
   : GOTO 220
0250 IF H$="N"THEN 260
   : PRINT HEX(01);STR(D$,1,13);
   : INPUT "WANNA HIT (YorN)",H$
   : IF H$="N"THEN 260
   : Y=Y+1
   : S(Y)=S
   : C(Y)=C
   : GOSUB 270
   : GOTO 220
0260 D=D+1
   : IF D>2THEN 261
   : T=4
   : RESTORE C1(2)
   : READ C$
   : RESTORE S1(2)+13
   : READ S$
   : GOSUB 275
   : GOTO 220
0261 FOR I=1TO D-1
   : IF C1(I)<10THEN 262
   : S2=S2+10
   : IF C1(I)<13THEN 263
   : S2=S2+1
   : GOTO 263
0262 S2=S2+C1(I)+1
0263 NEXT I
   : IF S2>16THEN 264
   : S2=0
   : S1(D)=S
   : C1(D)=C
   : GOSUB 271
   : GOTO 220
0264 FOR I=1TO Y
   : IF C(I)<10THEN 265
   : S1=S1+10
   : IF C(I)<13THEN 266
   : S1=S1+1
   : GOTO 266
0265 S1=S1+C(I)+1
0266 NEXT I
   : IF S2>21THEN 267
   : IF S1>21THEN 269
   : IF S1>S2THEN 267
   : PRINT HEX(01);STR(D$,1,12);"YOU LOSE YOUR BET         "
   : GOTO 268
0267 PRINT HEX(01);STR(D$,1,12);"YOU WIN YOUR BET OF $";B;"           "
   : W=W+2*B
0268 PRINT "TOTAL WINNINGS=";W;"       "
   : MAT C=ZER
   : MAT S=ZER
   : MAT C1=ZER
   : MAT S1=ZER
   : T=0
   : S1=0
   : S2=0
   : H$=" "
   : B1=0
   : IF W<=0THEN 180
   : GOTO 20
0269 S1=S1-10
   : FOR I=1TO Y
   : IF C(I)=13THEN 277
   : NEXT I
   : PRINT HEX(01);STR(D$,1,12);"YOU WENT OVER          "
   : GOTO 268
0270 PRINT HEX(01);STR(D$,1,(INT((Y-1)/2)+1)*2);STR(O$,1,((Y/2-INT(Y/2))*2+1)*
     11+30);C$;" OF"
   : PRINT STR(O$,1,((Y/2-INT(Y/2))*2+1)*11+30);S$
   : RETURN
0271 PRINT HEX(01);STR(D$,1,(INT((D-1)/2)+1)*2);STR(O$,1,((D/2-INT(D/2))*2+1)*
     11-9);C$;" OF"
   : PRINT STR(O$,1,((D/2-INT(D/2))*2+1)*11-9);S$
   : RETURN
0275 PRINT HEX(010A0A);STR(O$,1,(T-2)*11-9);C$;" OF"
   : PRINT STR(O$,1,(T-2)*11-9);S$
   : IF T=3THEN 276
   : RETURN
0276 RETURN CLEAR
   : GOTO 220
0277 I=Y
   : GOTO 266
0300 REM ***** ROULETTE *****
   : RESTORE 18
   : MAT READ R$
   : D=1
   : PRINT HEX(03)
0310 DATA "25","17","34","6","27","13","36","11","3","8","23","10","00","24","
     16","33","1","20","14","31","9","22","18","29","7","28","12","35","30","2
     6","5","0","32","15","19","4","21","2"
0319 FOR I=1TO 38
   : PRINT STR(R$(I),1,2);",";
   : NEXT I
   : PRINT HEX(0820)
0320 PRINT "WAYS TO BET:"
   : PRINT "1) ON ONE NUMBER  35:1"
   : PRINT "2) ON A SET OF FOUR NUMBERS IN THE ORDER ABOVE  8:1"
   : PRINT "3) ON ANY TWO NUMBERS (IN ORDER)  17:1"
   : PRINT "4) ON ANY THREE NUMBERS (IN ORDER)  11:1"
0321 PRINT "5) ON ANY SIX NUMBERS (IN ORDER)  5:1"
   : PRINT "6) ON EVEN OR ODD  1:1"
   : INPUT "YOUR CHOICE",E
0322 ON EGOTO 323,324,325,326,327,328
   : GOTO 300
0323 INPUT "NUMBER",A$
   : O=35
   : GOTO 330
0324 INPUT "STARTING NUMBER OF THE SEQUENCE",A$
   : O=8
   : GOTO 330
0325 INPUT "STARTING NUMBER OF THE SEQUENCE",A$
   : O=17
   : GOTO 330
0326 INPUT "STARTING NUMBER OF THE SEQUENCE",A$
   : O=11
   : GOTO 330
0327 INPUT "STARTING NUMBER OF THE SEQUENCE",A$
   : O=5
   : GOTO 330
0328 INPUT "1) EVEN OR 2) ODD",A$
   : O=1
   : GOTO 330
0330 INPUT "WHAT IS YOUR BET",B
   : IF B<10THEN 331
   : IF B>WTHEN 332
   : PRINT HEX(03);"ROUND AND ROUND SHE GOES, WHERE SHE STOPS, NOBODY KNOWS!"
   : GOTO 350
0331 PRINT "MINIMUM BET IS $10!              "
   : PRINT HEX(0C0C)
   : GOTO 330
0332 PRINT "YOU CAN'T BET MORE THAN YOU HAVE!";HEX(0C0C)
   : GOTO 330
0350 PRINT HEX(01060A0A);TAB(20);"^"
   : C=INT(RND(1)*30)+5
0360 D1=D1+INT(RND(1)*6)
   : FOR D2=1TO D1
   : NEXT D2
   : IF D1>100THEN 390
   : PRINT HEX(010A);STR(O$,1,10);STR(W1$,1,6-D);
   : FOR I=1TO 5
   : C=C+1
   : IF C<39THEN 370
   : C=C-38
0370 PRINT STR(R$(C),1,2);"    ";
   : NEXT I
   : C=C-5
   : IF C>0THEN 371
   : C=C+38
0371 PRINT
   : D=D+1
   : IF D>5THEN 380
   : GOTO 360
0380 D=1
   : C=C+1
   : GOTO 360
0390 PRINT HEX(05);R$(C+2);" IS THE NUMBER"
0400 ON EGOTO 410,420,430,440,450,460
0410 IF R$(C+2)<>A$THEN 480
   : W=W+36*B
   : GOTO 470
0420 FOR I=C-1TO C+2
   : IF I<1THEN 423
   : IF R$(I)=A$THEN 421
   : NEXT I
   : GOTO 480
0421 I=C+2
   : NEXT I
   : W=W+8*B
   : GOTO 470
0423 NEXT I
   : GOTO 480
0430 FOR I=C+1TO C+2
   : IF I<1THEN 423
   : IF R$(I)=A$THEN 431
   : NEXT I
   : GOTO 480
0431 I=C+2
   : NEXT I
   : W=W+17*B
   : GOTO 470
0440 FOR I=CTO C+1
   : IF I<1THEN 423
   : IF R$(I)=A$THEN 441
   : NEXT I
   : GOTO 480
0441 I=C+2
   : NEXT I
   : W=W+11*B
   : GOTO 470
0450 FOR I=C-2TO C+2
   : IF I<1THEN 423
   : IF R$(I)=A$THEN 451
   : NEXT I
   : GOTO 480
0451 I=C+2
   : NEXT I
   : W=W+5*B
   : GOTO 470
0460 CONVERT STR(R$(C+2),1,NUM(R$(C+2)))TO G1
   : IF G1=0THEN 480
   : W=W+B
   : IF (G1/2-INT(G1/2)+1)*(VAL(A$)-48)=1THEN 470
   : IF (G1/2-INT(G1/2))*2*(VAL(A$)-49)=1THEN 470
   : W=W-B
   : GOTO 480
0470 PRINT "YOU WON! TOTAL WINNINGS=";W
   : D1=0
   : IF W<=0THEN 180
   : GOTO 20
0480 W=W-B
   : PRINT "YOU LOST! TOTAL WINNINGS=";W
   : D1=0
   : IF W<=0THEN 180
   : GOTO 20
0500 PRINT HEX(03);"INSERT DOLLAR COIN (PRESS RETURN TO PULL LEVER)"
0501 DATA "ORANGE","CHERRY","\80NUT\80\80","\80PEAR\80"
0510 KEYIN A$,520,520
   : GOTO 510
0520 PRINT TAB(15);"--------- --------- ---------"
   : FOR I=1TO 3
   : PRINT TAB(14);HEX(86);STR(O$,1,9);HEX(86);STR(O$,1,9);HEX(86);STR(O$,1,9)
     ;HEX(86)
   : NEXT I
   : PRINT TAB(15);"--------- --------- ---------"
   : C=0
0530 C=C+1
   : IF C>4THEN 532
   : RESTORE C+55
   : READ A$
   : FOR I=T+1TO 3
   : GOSUB 531
   : NEXT I
   : IF 0=INT(RND(1)*5)THEN 540
   : GOTO 530
0531 PRINT HEX(01);STR(D$,1,3);STR(O$,1,(I*10)+6);A$
   : RETURN
0532 C=0
   : GOTO 530
0540 T=T+1
   : STR(B$,T,1)=STR(A$,4,1)
   : IF T<3THEN 530
   : PRINT
   : PRINT
   : PRINT
   : FOR I=1TO 3
   : C$=STR(B$,1,1)
   : IF STR(B$,I,1)<>C$THEN 550
   : NEXT I
   : J=INT(RND(1)*400)+100
   : PRINT "YOU HIT A JACKPOT OF $";J
   : W=W+J
   : GOTO 560
0550 I=3
   : NEXT I
   : PRINT "YOU LOST."
   : W=W-1
0560 PRINT "TOTAL WINNINGS=";W
   : T=0
   : B$,C$=" "
   : IF W<=0THEN 180
   : GOTO 20