image of READY prompt

Wang2200.org

Listing of file='3270BOOT' on disk='vmedia/bsc_3271_rel_1.14.04.wvd.zip'

# Sector 957, program filename = '3270BOOT'
0010 REM 3270BOOT 12/10/85, 3270  LOADER,COPYRIGHT WANG LABS, 1980
0060 COM A$64,B$1,C$1,A,B,C
0090 REM .Examine partition information
0100 A=0
0110 A$=$PSTAT(A+1)
   : ERRORGOTO 130
0120 A=A+1
   : IF A<16THEN 110
0130 IF A=1THEN 170
   : REM /.jump if 1 partition system
0132 A=#PART
   : REM /.A = This partition number
0134 A$=$PSTAT(A)
   : REM /.A$= Partition information
0136 C=VAL(STR(A$,12))
   : REM /.This partition memory
0137 E=ERR
   : SELECT @PART"3270UNIV"
   : ERRORE=ERR
   : GOTO 137
0140 ON A GOTO 142,144,154
   : INPUT "LOAD WHAT MODULE",A$
0141 LOAD DC T#0,A$
0142 STOP "Partition 1 reserved for 3270UNIVersal task"
0143 REM .Partition 2 is for MCT task
0144 IF C<6 THEN 200
0146 GOSUB 170
0148 LOAD DC T#0,"3270 MCT"
   : ERRORE=ERR
   : GOTO 148
0153 REM .Partition 3 is for Printer/disk task
0154 IF C<18 THEN 205
0156 GOSUB 170
0158 LOAD DC T#0,"3270PRN0"
   : ERRORE=ERR
   : GOTO 158
0160 REM .O.K.to load 3270 MCT
0170 A$,B$,C$=" "
0180 REM .Initialize critical variables
0182 REM .. "Waiting for Universal task"
0184 SELECT @PART"3270UNIV"
   : ERROR$BREAK
   : GOTO 184
0186 RETURN
0200 STOP "MCT Partition does not have sufficient memory"
0205 STOP "PRINTER/DISK partition does not have sufficient menory"
0210 REM %.Error conditions
0220 GOSUB 430
   : PRINT
0230 PRINT "Key  $ RELEASE TERMINAL TO ";C
0232 PRINT "Key  CLEAR "
0234 PRINT "Key  LOAD DC F ";HEX(22);"3270BOOT";HEX(22);" RETURN"
0235 PRINT "Key  RUN      RETURN"
0240 STOP "If you really wish to reload the MCT task follow above instructions
     "
0260 REM %^.Partition status Display
0270 DEFFN'15
0280 PRINT HEX(03),,"Active 2200 system configuration"
   : A=0
0290 PRINT ,". . . . . . . . 9 10 1 2 3 4 5 6 7 8 920 1 2 3 4 5 6 7 8 9"
0300 A$=$PSTAT(A+1)
   : ERRORGOTO 430
0310 PRINT "Partition ";A+1;" =",
   : HEXPRINT STR(A$,1,29)
0320 PRINT STR(A$,9,1);" BASIC Release ";HEXOF(STR(A$,10,1));" ";
0330 PRINT " Memory bank=";HEXOF(STR(A$,11,1));
0340 PRINT " Size = ";HEXOF(STR(A$,12,1));" K";
0350 PRINT " Prog=";STR(A$,14,1);
0360 PRINT " Term = ";HEXOF(STR(A$,15,1));
0370 PRINT " Status=";STR(A$,16,1);
0380 PRINT "Global name=";STR(A$,17,8);
0390 PRINT " Last error=";HEXOF(STR(A$,25,1))
0400 PRINT
0410 A=A+1
   : GOTO 300
0420 REM .Last partition should be MCT
0430 PRINT A;" Partitions configured";
0440 B=#PART
   : PRINT "  This is Partition";B,
0450 C=#TERM
   : PRINT "  Terminal ";C
   : PRINT
0460 PRINT "MCT task should load into Partition ";A;" which is now assigned"
0470 PRINT "Global name=";STR(A$,17,8);
0480 PRINT " Size = ";HEXOF(STR(A$,12,2));
0490 PRINT " Status=";STR(A$,16,1);
0500 PRINT " Term = ";HEXOF(STR(A$,15,1))
0510 RETURN