image of READY prompt

Wang2200.org

Listing of file='327PSTAT' on disk='vmedia/bsc_3271_rel_1.14.04.wvd.zip'

# Sector 971, program filename = '327PSTAT'
0010 REM 327PSTAT-- 12/10/85  Display status of each partition in configuratio
     n
0020 REM %VARIABLES--
   : DIM P$29,P1$2,P2$80,P$(16)29,Q$1,R$2
   : P2$=ALL("-")
   : P$=$PSTAT(1)
   : UNPACK(#.#)STR(P$,10,1) TO R
   : SELECT PRINT 005(80)
0025 $PSTAT="P.status"
0030 REM %DISPLAY TITLE--
   : PRINT HEX(0D03060E);"***** PARTITION STATUS *****        ";HEX(0F);
   : IF STR(P$,9,1)="M" THEN PRINT "M";
   : PRINT "VP Release";R;"     Partition";#PART
0040 PRINT "#PART  USER-MSG   BANK  SPACEK PRGM #TERM    @NAME    ERR    TEXT
     @P DATA    I/O"
   : PRINT P2$
0049 PRINT AT(22,0);"Press SF'0 to exit to START module"
0050 PRINT AT(23,0);"Press SF'1 to attach terminal to a different partition.";
     AT(1,0);
0060 REM %GET & DISPLAY STATUS OF EACH PARTITION--
   : PRINT AT(3,0);
   : B=1
   : FOR P=1 TO 16
   : P$=$PSTAT(P)
   : ERRORP=ERR
   : P=16
   : GOTO 140
0070 PRINT HEX(82);
   : IF P$=P$(P) THEN 130
0080 CONVERT P TO P1$,(##)
   : UNPACK(##) STR(P$,15,1) TO T
0090 REM ELIMINATE UNPRINTABLE CHARACTERS
   : $TRAN(STR(P$,,8),"................")
   : $TRAN(STR(P$,17,8),"................")
0100 IF T=#TERM THEN PRINT HEX(0E);
0110 PRINT P1$;"    ";STR(P$,,8);"   ";
   : IF VAL(STR(P$,11))<>B THEN PRINT BOX(0,3);
   : B=VAL(STR(P$,11))
   : PRINT " ";HEXOF(STR(P$,11,1));"    ";HEXOF(STR(P$,12,1));".";HEXOF(STR(P$
     ,13,1));"   ";
0120 PRINT STR(P$,14,1);"   ";HEXOF(STR(P$,15,1));"-";
   : IF T=#TERM OR T=0 AND STR(P$,16,1)="W" THEN PRINT HEX(020404000E);
   : PRINT STR(P$,16,1);HEX(020402000F);
   : IF T=#TERM THEN PRINT HEX(0E);
   : PRINT "   ";STR(P$,17,8);"   ";HEXOF(STR(P$,25,1));"     ";HEXOF(STR(P$,2
     6,1));"  ";HEXOF(STR(P$,27,1));"  ";HEXOF(STR(P$,28,1));"     ";HEXOF(STR
     (P$,29,1));
0130 $BREAK2
   : PRINT HEX(0D);" "
0140 P$(P)=P$
   : NEXT P
   : PRINT P2$
   : PRINT AT(20,0);"Device Table="
   : SELECT LIST  205(80)
   : LIST DT
   : SELECT LIST  005(80)
0141 B$=HEX(00)
   : P$=$PSTAT(1)
   : IF STR(P$,17,8)="3270UNIV"THEN OR (B$,80)
0142 P$=$PSTAT(2)
   : IF STR(P$,17,8)="3270 MCT"THEN IF STR(P$,29,1)<>HEX(01)THEN OR (B$,40)
0143 P$=$PSTAT(3)
   : IF STR(P$,17,8)="32NOPRNT"OR STR(P$,17,8)="3270PRNT"THEN IF STR(P$,25,1)=
     HEX(00)THEN IF STR(P$,29,1)<>HEX(01)THEN OR (B$,20)
0144 IF B$=HEX(E0)THEN PRINT AT(20,20);HEX(020402020E);"Wang 2200/3270 Emulato
     r system active";HEX(020400000F);
   : ELSE PRINT AT(20,20,60)
0150 REM %RELEASE?--
   : KEYIN Q$,60,155
   : GOTO 60
0155 PRINT HEX(05);
   : IF Q$<>HEX(00)THEN 160
   : LOAD DC T#0,N$(1)
0160 IF Q$<>HEX(01) THEN 60
   : P$()=" "
   : PRINT AT(22,0,);
   : GOTO 180
0170 P=ERR
   : PRINT AT(23,0);"CANNOT ATTACH TO PARTITION ";R$;" SINCE IT IS ASSIGNED TO
      ANOTHER TERMINAL.";
0180 REM %RELEASE TERMINAL
   : PRINT AT(22,0);
   : PRINT "Which partition is terminal";#TERM;"to be attached to (#PART)?";
   : R$=" "
   : LINPUT ?-R$
   : PRINT AT(23,0,80);
   : IF R$=" " THEN 30
   : CONVERT R$ TO P
   : ERRORGOTO 180
0190 IF P<1 OR P>16 OR INT(P)<>P THEN 180
   : P$=$PSTAT(P)
   : ERRORGOTO 180
0200 UNPACK(##) STR(P$,15,1) TO T
   : IF T<>#TERM AND T<>0 THEN 170
0210 REM %RELEASE PARTITION
   : PRINT AT(22,0,80);
   : PRINT "Do you want to release partition";#PART;"for another terminal (Y o
     r N)?";
   : Q$=" "
   : LINPUT ?-Q$
   : ON POS("YyNn"=Q$) GOTO 220,220,220,220
   : GOTO 210
0220 REM %RELEASE
   : PRINT HEX(0D03);
   : $RELEASE TERMINAL TO P
   : IF Q$="Y" OR Q$="y" THEN $RELEASE PART
   : GOTO 30
   : REM LOAD T/xyz,"filename" should replace previous GOTO if you want to loa
     d a program into the released partition.