image of READY prompt

Wang2200.org

Listing of file='MIND' on disk='vmedia/games-droz01.wvd.zip'

# Sector 273, program filename = 'MIND'
0010 REM MIND - VP MASTER MIND PROGRAM REV 7/13/79 - D.ANGEL
0020 DIM I$1,G$16,G1$16,H$16,X$16,Y$16, S$63,F$80
   : F$=ALL(09)
   : G$="10"
   : I9$="5"
0030 PRINT HEX(03);TAB(32);"** MASTERMIND **"
0032 S$="0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz"
0034 LINPUT "HOW MANY DIFFERENT CHARACTERS TO TRY ",G$
   : CONVERT G$ TO I
   : ERRORGOTO 34
0036 IF I<3 OR I>LEN(S$)THEN 34
   : STR(S$,I+1)=" "
0040 PRINT "CHAR = ";S$
0050 PRINT " * = CORRECT CHARACTER IN CORRECT COLUMN"
0060 PRINT " o = CORRECT CHARACTER IN WRONG COLUMN"
0070 LINPUT "COLUMNS (2-15)? ",I9$
0076 CONVERT I9$ TO I9
   : ERRORGOTO 70
0080 IF I9<2 OR I9>15 THEN 70
   : Z=1
0130 FOR I=1 TO I9
   : STR(X$,I,1)=STR(S$,LEN(S$)*RND(1)+1,1)
   : NEXT I
0160 PRINT TAB(10+I9+I9);
0170 FOR I=1 TO I9
   : PRINT " -";
   : NEXT I
   : PRINT
0180 PRINT TAB(11+I9+I9);
0190 I=1
   : G$=" "
0200 KEYIN I$,,9900
   : ON POS(HEX(08200D)=I$) GOTO 230,210,240
0205 IF POS(S$=I$)=0 OR I>I9 THEN 200
   : PRINT I$;" ";
   : STR(G$,I,1)=I$
   : I=I+1
   : GOTO 200
0210 I=MIN(I+1,I9)
   : GOTO 235
0230 I=MAX(I-1,1)
0235 PRINT HEX(060D);TAB(9+I9+I9);STR(F$,,2*I);HEX(05);
   : GOTO 200
0240 IF G$=G1$ OR POS(G$=20)<I9 THEN 200
0250 H$=G$
   : Y$=X$
   : PRINT HEX(0D);TAB(5);
0260 G1$= H$ XOR Y$
   : I=POS(G1$=00)
   : IF H$=" " OR I>LEN(H$)THEN 290
0270 PRINT "* ";
   : STR(Y$,I)=STR(Y$,I+1)
   : STR(H$,I)=STR(H$,I+1)
   : GOTO 260
0290 IF Y$=" "THEN 380
   : I=0
0300 I=I+1
   : IF I>LEN(H$)THEN 370
0310 J=POS(Y$=STR(H$,I,1))
   : IF J=0 THEN 300
   : PRINT "o ";
   : STR(Y$,J,1)=" "
   : GOTO 300
0370 PRINT
   : Z=Z+1
   : G1$=G$
   : GOTO 180
0380 PRINT
   : PRINT "CODE BROKEN IN ";Z;" TRYS"
0390 STOP
9900 REM FAKE A HALT STEP